X-Git-Url: https://git.piment-noir.org/?p=SugarCubes.git;a=blobdiff_plain;f=MicahScott.pde;fp=MicahScott.pde;h=a9a747e1c19ccd4ed57115f8b12f5105fb934201;hp=0000000000000000000000000000000000000000;hb=22cc0977d83b137ab1b57490dc1dec5e5ae24544;hpb=3194ee6b5c5f8bd87f1232c4fcf2e23bd6842516

diff --git a/MicahScott.pde b/MicahScott.pde
new file mode 100644
index 0000000..a9a747e
--- /dev/null
+++ b/MicahScott.pde
@@ -0,0 +1,83 @@
+// Port of a pattern from Fadecandy. Micah Elizabeth Scott, November 2013.
+class Rings extends SCPattern {
+
+    float dx, dy, dz;
+    float angleParam, hue, satParam, spacingParam;
+    float dzParam, centerParam;
+
+    BasicParameter pSpeed1 = new BasicParameter("SPD1", 0.15);
+    BasicParameter pSpeed2 = new BasicParameter("SPD2", 0.46);
+    BasicParameter pRGB = new BasicParameter("RGB", 0.73);
+    BasicParameter pScale = new BasicParameter("SCALE", 0.09);
+    BasicParameter pDepth = new BasicParameter("DEPTH", 0.40);
+    BasicParameter pBright = new BasicParameter("BRT", 0.66);    
+    BasicParameter pGamma = new BasicParameter("GAMMA", 0.12);    
+
+    public Rings(GLucose glucose) {
+        super(glucose);
+        addParameter(pSpeed1);
+        addParameter(pSpeed2);
+        addParameter(pScale);
+        addParameter(pDepth);
+        addParameter(pRGB);
+        addParameter(pBright);
+        addParameter(pGamma);
+    }
+
+    public void run(double deltaMs) {
+
+        float xyspeed = pSpeed1.getValuef() * 0.004;
+        float zspeed = pSpeed1.getValuef() * 0.08;
+        float scale = pScale.getValuef() * 20.0;
+
+        float angleSpeed = pSpeed1.getValuef() * 0.002;
+        angleParam = (float)((angleParam + angleSpeed * deltaMs) % (2*PI));
+        float angle = sin(angleParam);
+
+        hue += (deltaMs * pRGB.getValuef() * 0.3) % 360;
+        satParam += deltaMs * pRGB.getValuef() * 0.002;
+        spacingParam += deltaMs * pSpeed2.getValuef() * 0.0005;
+        dzParam += deltaMs * 0.000014;
+        centerParam += deltaMs * pSpeed2.getValuef() * 0.0005;
+
+        float saturation = 100 * constrain(pow(1.9 * noise(satParam), 2.5), 0, 1);
+        float spacing = noise(spacingParam) * 50;
+
+        dx += cos(angle) * xyspeed;
+        dy += sin(angle) * xyspeed;
+        dz += (pow(noise(dzParam), 1.8) - 0.5) * zspeed;
+
+        float centerx = map(noise(centerParam, 100), 0, 1, -0.1, 1.1);
+        float centery = map(noise(centerParam, 200), 0, 1, -0.1, 1.1);
+        float centerz = map(noise(centerParam, 300), 0, 1, -0.1, 1.1);
+
+        float coordMin = min(model.xMin, min(model.yMin, model.zMin));
+        float coordMax = max(model.xMax, max(model.yMax, model.zMax));
+
+        float br = pBright.getValuef() * 3.0;
+        float gamma = pGamma.getValuef() * 20.0;
+
+        for (LXPoint p : model.points) {
+
+            // Scale while preserving aspect ratio
+            float x = map(p.x, coordMin, coordMax, 0, 1);
+            float y = map(p.y, coordMin, coordMax, 0, 1);
+            float z = map(p.z, coordMin, coordMax, 0, 1);
+
+            float dist = sqrt(sq(x - centerx) + sq(y - centery) + sq(z - centerz));
+            float pulse = (sin(dz + dist * spacing) - 0.3) * 0.6;
+
+            noiseDetail(4);
+            float n = map(noise(dx + x*scale + pulse, dy + y*scale, dz + z*scale) - pDepth.getValuef(), 0, 1,
+                0, 2.0);
+            float m = map(noise(dx + x*scale, dy + y*scale, dz + z*scale), 0, 1, 0, 300);
+            noiseDetail(1);
+
+            colors[p.index] = lx.hsb(
+                (hue + m) % 360.0,
+                saturation,
+                100 * constrain(pow(br * n, gamma), 0, 1.0)
+                );
+        }
+    }
+};