+class CrossSections extends SCPattern {
+
+ final SinLFO x = new SinLFO(0, model.xMax, 5000);
+ final SinLFO y = new SinLFO(0, model.yMax, 6000);
+ final SinLFO z = new SinLFO(0, model.zMax, 7000);
+
+ final BasicParameter xw = new BasicParameter("XWID", 0.3);
+ final BasicParameter yw = new BasicParameter("YWID", 0.3);
+ final BasicParameter zw = new BasicParameter("ZWID", 0.3);
+ final BasicParameter xr = new BasicParameter("XRAT", 0.7);
+ final BasicParameter yr = new BasicParameter("YRAT", 0.6);
+ final BasicParameter zr = new BasicParameter("ZRAT", 0.5);
+ final BasicParameter xl = new BasicParameter("XLEV", 1);
+ final BasicParameter yl = new BasicParameter("YLEV", 1);
+ final BasicParameter zl = new BasicParameter("ZLEV", 0.5);
+
+
+ CrossSections(GLucose glucose) {
+ super(glucose);
+ addModulator(x).trigger();
+ addModulator(y).trigger();
+ addModulator(z).trigger();
+ addParameter(xr);
+ addParameter(yr);
+ addParameter(zr);
+ addParameter(xw);
+ addParameter(xl);
+ addParameter(yl);
+ addParameter(zl);
+ addParameter(yw);
+ addParameter(zw);
+ }
+
+ void onParameterChanged(LXParameter p) {
+ if (p == xr) {
+ x.setDuration(10000 - 8800*p.getValuef());
+ } else if (p == yr) {
+ y.setDuration(10000 - 9000*p.getValuef());
+ } else if (p == zr) {
+ z.setDuration(10000 - 9000*p.getValuef());
+ }
+ }
+
+ public void run(int deltaMs) {
+ float xv = x.getValuef();
+ float yv = y.getValuef();
+ float zv = z.getValuef();
+ float xlv = 100*xl.getValuef();
+ float ylv = 100*yl.getValuef();
+ float zlv = 100*zl.getValuef();
+
+ float xwv = 100. / (10 + 40*xw.getValuef());
+ float ywv = 100. / (10 + 40*yw.getValuef());
+ float zwv = 100. / (10 + 40*zw.getValuef());
+
+ for (Point p : model.points) {
+ color c = 0;
+ c = blendColor(c, color(
+ (lx.getBaseHuef() + p.fx/10 + p.fy/3) % 360,
+ constrain(140 - 1.1*abs(p.fx - model.xMax/2.), 0, 100),
+ max(0, xlv - xwv*abs(p.fx - xv))
+ ), ADD);
+ c = blendColor(c, color(
+ (lx.getBaseHuef() + 80 + p.fy/10) % 360,
+ constrain(140 - 2.2*abs(p.fy - model.yMax/2.), 0, 100),
+ max(0, ylv - ywv*abs(p.fy - yv))
+ ), ADD);
+ c = blendColor(c, color(
+ (lx.getBaseHuef() + 160 + p.fz / 10 + p.fy/2) % 360,
+ constrain(140 - 2.2*abs(p.fz - model.zMax/2.), 0, 100),
+ max(0, zlv - zwv*abs(p.fz - zv))
+ ), ADD);
+ colors[p.index] = c;
+ }
+ }
+}
+
+class Blinders extends SCPattern {
+
+ final SinLFO[] m;
+ final TriangleLFO r;
+ final SinLFO s;
+ final TriangleLFO hs;
+
+ public Blinders(GLucose glucose) {
+ super(glucose);
+ m = new SinLFO[12];
+ for (int i = 0; i < m.length; ++i) {
+ addModulator(m[i] = new SinLFO(0.5, 120, (120000. / (3+i)))).trigger();
+ }
+ addModulator(r = new TriangleLFO(9000, 15000, 29000)).trigger();
+ addModulator(s = new SinLFO(-20, 275, 11000)).trigger();
+ addModulator(hs = new TriangleLFO(0.1, 0.5, 15000)).trigger();
+ s.modulateDurationBy(r);
+ }
+
+ public void run(int deltaMs) {
+ float hv = lx.getBaseHuef();
+ int si = 0;
+ for (Strip strip : model.strips) {
+ int i = 0;
+ float mv = m[si % m.length].getValuef();
+ for (Point p : strip.points) {
+ colors[p.index] = color(
+ (hv + p.fz + p.fy*hs.getValuef()) % 360,
+ min(100, abs(p.fx - s.getValuef())/2.),
+ max(0, 100 - mv/2. - mv * abs(i - (strip.metrics.length-1)/2.))
+ );
+ ++i;
+ }
+ ++si;
+ }
+ }
+}
+
+class Psychedelia extends SCPattern {
+
+ final int NUM = 3;
+ SinLFO m = new SinLFO(-0.5, NUM-0.5, 9000);
+ SinLFO s = new SinLFO(-20, 147, 11000);
+ TriangleLFO h = new TriangleLFO(0, 240, 19000);
+ SinLFO c = new SinLFO(-.2, .8, 31000);
+
+ Psychedelia(GLucose glucose) {
+ super(glucose);
+ addModulator(m).trigger();
+ addModulator(s).trigger();
+ addModulator(h).trigger();
+ addModulator(c).trigger();
+ }
+
+ void run(int deltaMs) {
+ float huev = h.getValuef();
+ float cv = c.getValuef();
+ float sv = s.getValuef();
+ float mv = m.getValuef();
+ int i = 0;
+ for (Strip strip : model.strips) {
+ for (Point p : strip.points) {
+ colors[p.index] = color(
+ (huev + i*constrain(cv, 0, 2) + p.fz/2. + p.fx/4.) % 360,
+ min(100, abs(p.fy-sv)),
+ max(0, 100 - 50*abs((i%NUM) - mv))
+ );
+ }
+ ++i;
+ }
+ }
+}
+
+class AskewPlanes extends SCPattern {
+
+ class Plane {
+ private final SinLFO a;
+ private final SinLFO b;
+ private final SinLFO c;
+ float av = 1;
+ float bv = 1;
+ float cv = 1;
+ float denom = 0.1;
+
+ Plane(int i) {
+ addModulator(a = new SinLFO(-1, 1, 4000 + 1029*i)).trigger();
+ addModulator(b = new SinLFO(-1, 1, 11000 - 1104*i)).trigger();
+ addModulator(c = new SinLFO(-50, 50, 4000 + 1000*i * ((i % 2 == 0) ? 1 : -1))).trigger();
+ }
+
+ void run(int deltaMs) {
+ av = a.getValuef();
+ bv = b.getValuef();
+ cv = c.getValuef();
+ denom = sqrt(av*av + bv*bv);
+ }
+ }
+
+ final Plane[] planes;
+ final int NUM_PLANES = 3;
+
+ AskewPlanes(GLucose glucose) {
+ super(glucose);
+ planes = new Plane[NUM_PLANES];
+ for (int i = 0; i < planes.length; ++i) {
+ planes[i] = new Plane(i);
+ }
+ }
+
+ public void run(int deltaMs) {
+ float huev = lx.getBaseHuef();
+
+ // This is super fucking bizarre. But if this is a for loop, the framerate
+ // tanks to like 30FPS, instead of 60. Call them manually and it works fine.
+ // Doesn't make ANY sense... there must be some weird side effect going on
+ // with the Processing internals perhaps?
+// for (Plane plane : planes) {
+// plane.run(deltaMs);
+// }
+ planes[0].run(deltaMs);
+ planes[1].run(deltaMs);
+ planes[2].run(deltaMs);
+
+ for (Point p : model.points) {
+ float d = MAX_FLOAT;
+ for (Plane plane : planes) {
+ if (plane.denom != 0) {
+ d = min(d, abs(plane.av*(p.fx-model.cx) + plane.bv*(p.fy-model.cy) + plane.cv) / plane.denom);
+ }
+ }
+ colors[p.index] = color(
+ (huev + abs(p.fx-model.cx)*.3 + p.fy*.8) % 360,
+ max(0, 100 - .8*abs(p.fx - model.cx)),
+ constrain(140 - 10.*d, 0, 100)
+ );
+ }
+ }
+}
+
+class ShiftingPlane extends SCPattern {
+
+ final SinLFO a = new SinLFO(-.2, .2, 5300);
+ final SinLFO b = new SinLFO(1, -1, 13300);
+ final SinLFO c = new SinLFO(-1.4, 1.4, 5700);
+ final SinLFO d = new SinLFO(-10, 10, 9500);
+
+ ShiftingPlane(GLucose glucose) {
+ super(glucose);
+ addModulator(a).trigger();
+ addModulator(b).trigger();
+ addModulator(c).trigger();
+ addModulator(d).trigger();
+ }
+
+ public void run(int deltaMs) {
+ float hv = lx.getBaseHuef();
+ float av = a.getValuef();
+ float bv = b.getValuef();
+ float cv = c.getValuef();
+ float dv = d.getValuef();
+ float denom = sqrt(av*av + bv*bv + cv*cv);
+ for (Point p : model.points) {
+ float d = abs(av*(p.fx-model.cx) + bv*(p.fy-model.cy) + cv*(p.fz-model.cz) + dv) / denom;
+ colors[p.index] = color(
+ (hv + abs(p.fx-model.cx)*.6 + abs(p.fy-model.cy)*.9 + abs(p.fz - model.cz)) % 360,
+ constrain(110 - d*6, 0, 100),
+ constrain(130 - 7*d, 0, 100)
+ );
+ }
+ }
+}
+