+class Cathedrals extends SCPattern {
+
+ private final BasicParameter xpos = new BasicParameter("XPOS", 0.5);
+ private final BasicParameter wid = new BasicParameter("WID", 0.5);
+ private final BasicParameter arms = new BasicParameter("ARMS", 0.5);
+ private final BasicParameter sat = new BasicParameter("SAT", 0.5);
+ private GraphicEQ eq;
+
+ Cathedrals(LX lx) {
+ super(lx);
+ addParameter(xpos);
+ addParameter(wid);
+ addParameter(arms);
+ addParameter(sat);
+ }
+
+ void onActive() {
+ if (eq == null) {
+ eq = new GraphicEQ(lx, 16);
+ eq.slope.setValue(0.7);
+ eq.range.setValue(0.4);
+ eq.attack.setValue(0.4);
+ eq.release.setValue(0.4);
+ addParameter(eq.level);
+ addParameter(eq.range);
+ addParameter(eq.attack);
+ addParameter(eq.release);
+ addParameter(eq.slope);
+ }
+ }
+
+
+ public void run(double deltaMs) {
+ eq.run(deltaMs);
+ float bassLevel = eq.getAverageLevel(0, 4);
+ float trebleLevel = eq.getAverageLevel(8, 6);
+
+ float falloff = 100 / (2 + 14*wid.getValuef());
+ float cx = model.xMin + (model.xMax-model.xMin) * xpos.getValuef();
+ float barm = 12 + 60*arms.getValuef()*max(0, 2*(bassLevel-0.1));
+ float tarm = 12 + 60*arms.getValuef()*max(0, 2*(trebleLevel-0.1));
+
+ float arm = 0;
+ float middle = 0;
+
+ float sf = 100. / (70 - 69.9*sat.getValuef());
+
+ for (LXPoint p : model.points) {
+ float d = MAX_FLOAT;
+ if (p.y > model.cy) {
+ arm = tarm;
+ middle = model.yMax * 3/5.;
+ } else {
+ arm = barm;
+ middle = model.yMax * 1/5.;
+ }
+ if (abs(p.x - cx) < arm) {
+ d = min(abs(p.x - cx), abs(p.y - middle));
+ }
+ colors[p.index] = lx.hsb(
+ (lx.getBaseHuef() + .2*abs(p.y - model.cy)) % 360,
+ min(100, sf*dist(abs(p.x - cx), p.y, arm, middle)),
+ constrain(120 - d*falloff, 0, 100));
+ }
+ }
+}
+
+class MidiMusic extends SCPattern {
+
+ private final Stack<LXLayer> newLayers = new Stack<LXLayer>();
+
+ private final Map<Integer, LightUp> lightMap = new HashMap<Integer, LightUp>();
+ private final List<LightUp> lights = new ArrayList<LightUp>();
+ private final BasicParameter lightSize = new BasicParameter("SIZE", 0.5);
+
+ private final List<Sweep> sweeps = new ArrayList<Sweep>();
+
+ private final LinearEnvelope sparkle = new LinearEnvelope(0, 1, 500);
+ private boolean sparkleDirection = true;
+ private float sparkleBright = 100;
+
+ private final BasicParameter wave = new BasicParameter("WAVE", 0);
+
+ MidiMusic(LX lx) {
+ super(lx);
+ addParameter(lightSize);
+ addParameter(wave);
+ addModulator(sparkle).setValue(1);
+ }
+
+ void onReset() {
+ for (LightUp light : lights) {
+ light.noteOff(null);
+ }
+ }
+
+ class Sweep extends LXLayer {
+
+ final LinearEnvelope position = new LinearEnvelope(0, 1, 1000);
+ float bright = 100;
+ float falloff = 10;
+
+ Sweep() {
+ addModulator(position);
+ }
+
+ public void run(double deltaMs, color[] colors) {
+ if (!position.isRunning()) {
+ return;
+ }
+ float posf = position.getValuef();
+ for (LXPoint p : model.points) {
+ colors[p.index] = blendColor(colors[p.index], lx.hsb(
+ (lx.getBaseHuef() + .2*abs(p.x - model.cx) + .2*abs(p.y - model.cy)) % 360,
+ 100,
+ max(0, bright - posf*100 - falloff*abs(p.y - posf*model.yMax))
+ ), ADD);
+ }
+ }
+ }
+
+ class LightUp extends LXLayer {
+
+ private final LinearEnvelope brt = new LinearEnvelope(0, 0, 0);
+ private final Accelerator yPos = new Accelerator(0, 0, 0);
+ private float xPos;
+
+ LightUp() {
+ addModulator(brt);
+ addModulator(yPos);
+ }
+
+ boolean isAvailable() {
+ return brt.getValuef() <= 0;
+ }
+
+ void noteOn(Note note) {
+ xPos = lerp(0, model.xMax, constrain(0.5 + (note.getPitch() - 60) / 28., 0, 1));
+ yPos.setValue(lerp(20, model.yMax*.72, note.getVelocity() / 127.)).stop();
+ brt.setRangeFromHereTo(lerp(40, 100, note.getVelocity() / 127.), 20).start();
+ }
+
+ void noteOff(Note note) {
+ yPos.setVelocity(0).setAcceleration(-380).start();
+ brt.setRangeFromHereTo(0, 1000).start();
+ }
+
+ public void run(double deltaMs, color[] colors) {
+ float bVal = brt.getValuef();
+ if (bVal <= 0) {
+ return;
+ }
+ float yVal = yPos.getValuef();
+ for (LXPoint p : model.points) {
+ float falloff = 6 - 5*lightSize.getValuef();
+ float b = max(0, bVal - falloff*dist(p.x, p.y, xPos, yVal));
+ if (b > 0) {
+ colors[p.index] = blendColor(colors[p.index], lx.hsb(
+ (lx.getBaseHuef() + .2*abs(p.x - model.cx) + .2*abs(p.y - model.cy)) % 360,
+ 100,
+ b
+ ), ADD);
+ }
+ }
+ }
+ }
+
+ private LightUp getLight() {
+ for (LightUp light : lights) {
+ if (light.isAvailable()) {
+ return light;
+ }
+ }
+ LightUp newLight = new LightUp();
+ lights.add(newLight);
+ synchronized(newLayers) {
+ newLayers.push(newLight);
+ }
+ return newLight;
+ }
+
+ private Sweep getSweep() {
+ for (Sweep s : sweeps) {
+ if (!s.position.isRunning()) {
+ return s;
+ }
+ }
+ Sweep newSweep = new Sweep();
+ sweeps.add(newSweep);
+ synchronized(newLayers) {
+ newLayers.push(newSweep);
+ }
+ return newSweep;
+ }
+
+ public synchronized boolean noteOn(Note note) {
+ if (note.getChannel() == 0) {
+ LightUp light = getLight();
+ lightMap.put(note.getPitch(), light);
+ light.noteOn(note);
+ } else if (note.getChannel() == 1) {
+ } else if (note.getChannel() == 9) {
+ if (note.getVelocity() > 0) {
+ switch (note.getPitch()) {
+ case 36:
+ Sweep s = getSweep();
+ s.bright = 50 + note.getVelocity() / 127. * 50;
+ s.falloff = 20 - note.getVelocity() / 127. * 17;
+ s.position.trigger();
+ break;
+ case 37:
+ sparkleBright = note.getVelocity() / 127. * 100;
+ sparkleDirection = true;
+ sparkle.trigger();
+ break;
+ case 38:
+ sparkleBright = note.getVelocity() / 127. * 100;
+ sparkleDirection = false;
+ sparkle.trigger();
+ break;
+ case 39:
+ effects.boom.trigger();
+ break;
+ case 40:
+ effects.flash.trigger();
+ break;
+ }
+ }
+ }
+ return true;
+ }
+
+ public synchronized boolean noteOff(Note note) {
+ if (note.getChannel() == 0) {
+ LightUp light = lightMap.get(note.getPitch());
+ if (light != null) {
+ light.noteOff(note);
+ }
+ }
+ return true;
+ }
+
+ final float[] wval = new float[16];
+ float wavoff = 0;
+
+ public synchronized void run(double deltaMs) {
+ wavoff += deltaMs * .001;
+ for (int i = 0; i < wval.length; ++i) {
+ wval[i] = model.cy + 0.2 * model.yMax/2. * sin(wavoff + i / 1.9);
+ }
+ float sparklePos = (sparkleDirection ? sparkle.getValuef() : (1 - sparkle.getValuef())) * (Cube.POINTS_PER_STRIP)/2.;
+ float maxBright = sparkleBright * (1 - sparkle.getValuef());
+ for (Strip s : model.strips) {
+ int i = 0;
+ for (LXPoint p : s.points) {
+ int wavi = (int) constrain(p.x / model.xMax * wval.length, 0, wval.length-1);
+ float wavb = max(0, wave.getValuef()*100. - 8.*abs(p.y - wval[wavi]));
+ colors[p.index] = lx.hsb(
+ (lx.getBaseHuef() + .2*abs(p.x - model.cx) + .2*abs(p.y - model.cy)) % 360,
+ 100,
+ constrain(wavb + max(0, maxBright - 40.*abs(sparklePos - abs(i - (Cube.POINTS_PER_STRIP-1)/2.))), 0, 100)
+ );
+ ++i;
+ }
+ }
+
+ if (!newLayers.isEmpty()) {
+ synchronized(newLayers) {
+ while (!newLayers.isEmpty()) {
+ addLayer(newLayers.pop());
+ }
+ }
+ }
+ }
+}
+
+class Pulley extends SCPattern {
+
+ final int NUM_DIVISIONS = 16;
+ private final Accelerator[] gravity = new Accelerator[NUM_DIVISIONS];
+ private final Click[] delays = new Click[NUM_DIVISIONS];
+
+ private final Click reset = new Click(9000);
+ private boolean isRising = false;
+
+ private BasicParameter sz = new BasicParameter("SIZE", 0.5);
+ private BasicParameter beatAmount = new BasicParameter("BEAT", 0);
+
+ Pulley(LX lx) {
+ super(lx);
+ for (int i = 0; i < NUM_DIVISIONS; ++i) {
+ addModulator(gravity[i] = new Accelerator(0, 0, 0));
+ addModulator(delays[i] = new Click(0));
+ }
+ addModulator(reset).start();
+ addParameter(sz);
+ addParameter(beatAmount);
+ trigger();
+
+ }
+
+ private void trigger() {
+ isRising = !isRising;
+ int i = 0;
+ for (Accelerator g : gravity) {
+ if (isRising) {
+ g.setSpeed(random(20, 33), 0).start();
+ } else {
+ g.setVelocity(0).setAcceleration(-420);
+ delays[i].setDuration(random(0, 500)).trigger();
+ }
+ ++i;
+ }
+ }
+
+ public void run(double deltaMs) {
+ if (reset.click()) {
+ trigger();
+ }
+
+ if (isRising) {
+ // Fucking A, had to comment this all out because of that bizarre
+ // Processing bug where some simple loop takes an absurd amount of
+ // time, must be some pre-processor bug
+// for (Accelerator g : gravity) {
+// if (g.getValuef() > model.yMax) {
+// g.stop();
+// } else if (g.getValuef() > model.yMax*.55) {
+// if (g.getVelocityf() > 10) {
+// g.setAcceleration(-16);
+// } else {
+// g.setAcceleration(0);
+// }
+// }
+// }
+ } else {
+ int j = 0;
+ for (Click d : delays) {
+ if (d.click()) {
+ gravity[j].start();
+ d.stop();
+ }
+ ++j;
+ }
+ for (Accelerator g : gravity) {
+ if (g.getValuef() < 0) {
+ g.setValue(-g.getValuef());
+ g.setVelocity(-g.getVelocityf() * random(0.74, 0.84));
+ }
+ }
+ }
+
+ // A little silliness to test the grid API
+ if (midiEngine != null && midiEngine.getFocusedPattern() == this) {
+ for (int i = 0; i < 5; ++i) {
+ for (int j = 0; j < 8; ++j) {
+ int gi = (int) constrain(j * NUM_DIVISIONS / 8, 0, NUM_DIVISIONS-1);
+ float b = 1 - 4.*abs((6-i)/6. - gravity[gi].getValuef() / model.yMax);
+ midiEngine.grid.setState(i, j, (b < 0) ? 0 : 3);
+ }
+ }
+ }
+
+ float fPos = 1 - lx.tempo.rampf();
+ if (fPos < .2) {
+ fPos = .2 + 4 * (.2 - fPos);
+ }
+ float falloff = 100. / (3 + sz.getValuef() * 36 + fPos * beatAmount.getValuef()*48);
+ for (LXPoint p : model.points) {
+ int gi = (int) constrain((p.x - model.xMin) * NUM_DIVISIONS / (model.xMax - model.xMin), 0, NUM_DIVISIONS-1);
+ colors[p.index] = lx.hsb(
+ (lx.getBaseHuef() + abs(p.x - model.cx)*.8 + p.y*.4) % 360,
+ constrain(130 - p.y*.8, 0, 100),
+ max(0, 100 - abs(p.y - gravity[gi].getValuef())*falloff)
+ );
+ }
+ }
+}
+
+class ViolinWave extends SCPattern {
+
+ BasicParameter level = new BasicParameter("LVL", 0.45);
+ BasicParameter range = new BasicParameter("RNG", 0.5);
+ BasicParameter edge = new BasicParameter("EDG", 0.5);
+ BasicParameter release = new BasicParameter("RLS", 0.5);
+ BasicParameter speed = new BasicParameter("SPD", 0.5);
+ BasicParameter amp = new BasicParameter("AMP", 0.25);
+ BasicParameter period = new BasicParameter("WAVE", 0.5);
+ BasicParameter pSize = new BasicParameter("PSIZE", 0.5);
+ BasicParameter pSpeed = new BasicParameter("PSPD", 0.5);
+ BasicParameter pDensity = new BasicParameter("PDENS", 0.25);
+
+ LinearEnvelope dbValue = new LinearEnvelope(0, 0, 10);
+
+ ViolinWave(LX lx) {
+ super(lx);
+ addParameter(level);
+ addParameter(edge);
+ addParameter(range);
+ addParameter(release);
+ addParameter(speed);
+ addParameter(amp);
+ addParameter(period);
+ addParameter(pSize);
+ addParameter(pSpeed);
+ addParameter(pDensity);
+
+ addModulator(dbValue);
+ }
+
+ final List<Particle> particles = new ArrayList<Particle>();
+
+ class Particle {
+
+ LinearEnvelope x = new LinearEnvelope(0, 0, 0);
+ LinearEnvelope y = new LinearEnvelope(0, 0, 0);
+
+ Particle() {
+ addModulator(x);
+ addModulator(y);
+ }
+
+ Particle trigger(boolean direction) {
+ float xInit = random(model.xMin, model.xMax);
+ float time = 3000 - 2500*pSpeed.getValuef();
+ x.setRange(xInit, xInit + random(-40, 40), time).trigger();
+ y.setRange(model.cy + 10, direction ? model.yMax + 50 : model.yMin - 50, time).trigger();
+ return this;
+ }
+
+ boolean isActive() {
+ return x.isRunning() || y.isRunning();
+ }
+
+ public void run(double deltaMs) {
+ if (!isActive()) {
+ return;
+ }
+
+ float pFalloff = (30 - 27*pSize.getValuef());
+ for (LXPoint p : model.points) {
+ float b = 100 - pFalloff * (abs(p.x - x.getValuef()) + abs(p.y - y.getValuef()));
+ if (b > 0) {
+ colors[p.index] = blendColor(colors[p.index], lx.hsb(
+ lx.getBaseHuef(), 20, b
+ ), ADD);
+ }
+ }
+ }
+ }
+
+ float[] centers = new float[30];
+ double accum = 0;
+ boolean rising = true;
+
+ void fireParticle(boolean direction) {
+ boolean gotOne = false;
+ for (Particle p : particles) {
+ if (!p.isActive()) {
+ p.trigger(direction);
+ return;
+ }
+ }
+ particles.add(new Particle().trigger(direction));
+ }
+
+ public void run(double deltaMs) {
+ accum += deltaMs / (1000. - 900.*speed.getValuef());
+ for (int i = 0; i < centers.length; ++i) {
+ centers[i] = model.cy + 30*amp.getValuef()*sin((float) (accum + (i-centers.length/2.)/(1. + 9.*period.getValuef())));
+ }
+
+ float zeroDBReference = pow(10, (50 - 190*level.getValuef())/20.);
+ float dB = 20*GraphicEQ.log10(lx.audioInput().mix.level() / zeroDBReference);
+ if (dB > dbValue.getValuef()) {
+ rising = true;
+ dbValue.setRangeFromHereTo(dB, 10).trigger();
+ } else {
+ if (rising) {
+ for (int j = 0; j < pDensity.getValuef()*3; ++j) {
+ fireParticle(true);
+ fireParticle(false);
+ }
+ }
+ rising = false;
+ dbValue.setRangeFromHereTo(max(dB, -96), 50 + 1000*release.getValuef()).trigger();
+ }
+ float edg = 1 + edge.getValuef() * 40;
+ float rng = (78 - 64 * range.getValuef()) / (model.yMax - model.cy);
+ float val = max(2, dbValue.getValuef());
+
+ for (LXPoint p : model.points) {
+ int ci = (int) lerp(0, centers.length-1, (p.x - model.xMin) / (model.xMax - model.xMin));
+ float rFactor = 1.0 - 0.9 * abs(p.x - model.cx) / (model.xMax - model.cx);
+ colors[p.index] = lx.hsb(
+ (lx.getBaseHuef() + abs(p.x - model.cx)) % 360,
+ min(100, 20 + 8*abs(p.y - centers[ci])),
+ constrain(edg*(val*rFactor - rng * abs(p.y-centers[ci])), 0, 100)
+ );
+ }
+
+ for (Particle p : particles) {
+ p.run(deltaMs);
+ }
+ }
+}
+
+class BouncyBalls extends SCPattern {
+
+ static final int NUM_BALLS = 6;
+
+ class BouncyBall {
+
+ Accelerator yPos;
+ TriangleLFO xPos = new TriangleLFO(0, model.xMax, random(8000, 19000));
+ float zPos;
+
+ BouncyBall(int i) {
+ addModulator(xPos.setBasis(random(0, TWO_PI)).start());
+ addModulator(yPos = new Accelerator(0, 0, 0));
+ zPos = lerp(model.zMin, model.zMax, (i+2.) / (NUM_BALLS + 4.));
+ }
+
+ void bounce(float midiVel) {
+ float v = 100 + 8*midiVel;
+ yPos.setSpeed(v, getAccel(v, 60 / lx.tempo.bpmf())).start();
+ }
+
+ float getAccel(float v, float oneBeat) {
+ return -2*v / oneBeat;
+ }
+
+ void run(double deltaMs) {
+ float flrLevel = flr.getValuef() * model.xMax/2.;
+ if (yPos.getValuef() < flrLevel) {
+ if (yPos.getVelocity() < -50) {
+ yPos.setValue(2*flrLevel-yPos.getValuef());
+ float v = -yPos.getVelocityf() * bounce.getValuef();
+ yPos.setSpeed(v, getAccel(v, 60 / lx.tempo.bpmf()));
+ } else {
+ yPos.setValue(flrLevel).stop();
+ }
+ }
+ float falloff = 130.f / (12 + blobSize.getValuef() * 36);
+ float xv = xPos.getValuef();
+ float yv = yPos.getValuef();
+
+ for (LXPoint p : model.points) {
+ float d = sqrt((p.x-xv)*(p.x-xv) + (p.y-yv)*(p.y-yv) + .1*(p.z-zPos)*(p.z-zPos));
+ float b = constrain(130 - falloff*d, 0, 100);
+ if (b > 0) {
+ colors[p.index] = blendColor(colors[p.index], lx.hsb(
+ (lx.getBaseHuef() + p.y*.5 + abs(model.cx - p.x) * .5) % 360,
+ max(0, 100 - .45*(p.y - flrLevel)),
+ b
+ ), ADD);
+ }
+ }
+ }
+ }
+
+ final BouncyBall[] balls = new BouncyBall[NUM_BALLS];
+
+ final BasicParameter bounce = new BasicParameter("BNC", .8);
+ final BasicParameter flr = new BasicParameter("FLR", 0);
+ final BasicParameter blobSize = new BasicParameter("SIZE", 0.5);
+
+ BouncyBalls(LX lx) {
+ super(lx);
+ for (int i = 0; i < balls.length; ++i) {
+ balls[i] = new BouncyBall(i);
+ }
+ addParameter(bounce);
+ addParameter(flr);
+ addParameter(blobSize);
+ }
+
+ public void run(double deltaMs) {
+ setColors(#000000);
+ for (BouncyBall b : balls) {
+ b.run(deltaMs);
+ }
+ }
+
+ public boolean noteOn(Note note) {
+ int pitch = (note.getPitch() + note.getChannel()) % NUM_BALLS;
+ balls[pitch].bounce(note.getVelocity());
+ return true;
+ }
+}
+