MarkSlee.pde

   1 class Cathedrals extends SCPattern {
   2
   3   private final BasicParameter xpos = new BasicParameter("XPOS", 0.5);
   4   private final BasicParameter wid = new BasicParameter("WID", 0.5);
   5   private final BasicParameter arms = new BasicParameter("ARMS", 0.5);
   6   private final BasicParameter sat = new BasicParameter("SAT", 0.5);
   7   private GraphicEQ eq;
   8
   9   Cathedrals(GLucose glucose) {
  10     super(glucose);
  11     addParameter(xpos);
  12     addParameter(wid);
  13     addParameter(arms);
  14     addParameter(sat);
  15   }
  16
  17   protected void onActive() {
  18     if (eq == null) {
  19       eq = new GraphicEQ(lx, 16);
  20       eq.slope.setValue(0.7);
  21       eq.range.setValue(0.4);
  22       eq.attack.setValue(0.4);
  23       eq.release.setValue(0.4);
  24       addParameter(eq.level);
  25       addParameter(eq.range);
  26       addParameter(eq.attack);
  27       addParameter(eq.release);
  28       addParameter(eq.slope);
  29     }
  30   }
  31
  32
  33   public void run(double deltaMs) {
  34     eq.run(deltaMs);
  35     float bassLevel = eq.getAverageLevel(0, 4);
  36     float trebleLevel = eq.getAverageLevel(8, 6);
  37
  38     float falloff = 100 / (2 + 14*wid.getValuef());
  39     float cx = model.xMin + (model.xMax-model.xMin) * xpos.getValuef();
  40     float barm = 12 + 60*arms.getValuef()*max(0, 2*(bassLevel-0.1));
  41     float tarm = 12 + 60*arms.getValuef()*max(0, 2*(trebleLevel-0.1));
  42
  43     float arm = 0;
  44     float middle = 0;
  45
  46     float sf = 100. / (70 - 69.9*sat.getValuef());
  47
  48     for (LXPoint p : model.points) {
  49       float d = MAX_FLOAT;
  50       if (p.y > model.cy) {
  51         arm = tarm;
  52         middle = model.yMax * 3/5.;
  53       } else {
  54         arm = barm;
  55         middle = model.yMax * 1/5.;
  56       }
  57       if (abs(p.x - cx) < arm) {
  58         d = min(abs(p.x - cx), abs(p.y - middle));
  59       }
  60       colors[p.index] = lx.hsb(
  61         (lx.getBaseHuef() + .2*abs(p.y - model.cy)) % 360,
  62         min(100, sf*dist(abs(p.x - cx), p.y, arm, middle)),
  63         constrain(120 - d*falloff, 0, 100));
  64     }
  65   }
  66 }
  67
  68 class MidiMusic extends SCPattern {
  69
  70   private final Stack<LXLayer> newLayers = new Stack<LXLayer>();
  71
  72   private final Map<Integer, LightUp> lightMap = new HashMap<Integer, LightUp>();
  73   private final List<LightUp> lights = new ArrayList<LightUp>();
  74   private final BasicParameter lightSize = new BasicParameter("SIZE", 0.5);
  75
  76   private final List<Sweep> sweeps = new ArrayList<Sweep>();
  77
  78   private final LinearEnvelope sparkle = new LinearEnvelope(0, 1, 500);
  79   private boolean sparkleDirection = true;
  80   private float sparkleBright = 100;
  81
  82   private final BasicParameter wave = new BasicParameter("WAVE", 0);
  83
  84   MidiMusic(GLucose glucose) {
  85     super(glucose);
  86     addParameter(lightSize);
  87     addParameter(wave);
  88     addModulator(sparkle).setValue(1);
  89   }
  90
  91   void onReset() {
  92     for (LightUp light : lights) {
  93       light.noteOff(null);
  94     }
  95   }
  96
  97   class Sweep extends LXLayer {
  98
  99     final LinearEnvelope position = new LinearEnvelope(0, 1, 1000);
 100     float bright = 100;
 101     float falloff = 10;
 102
 103     Sweep() {
 104       addModulator(position);
 105     }
 106
 107     public void run(double deltaMs, color[] colors) {
 108       if (!position.isRunning()) {
 109         return;
 110       }
 111       float posf = position.getValuef();
 112       for (LXPoint p : model.points) {
 113         colors[p.index] = blendColor(colors[p.index], lx.hsb(
 114           (lx.getBaseHuef() + .2*abs(p.x - model.cx) + .2*abs(p.y - model.cy)) % 360,
 115           100,
 116           max(0, bright - posf*100 - falloff*abs(p.y - posf*model.yMax))
 117         ), ADD);
 118       }
 119     }
 120   }
 121
 122   class LightUp extends LXLayer {
 123
 124     private final LinearEnvelope brt = new LinearEnvelope(0, 0, 0);
 125     private final Accelerator yPos = new Accelerator(0, 0, 0);
 126     private float xPos;
 127
 128     LightUp() {
 129       addModulator(brt);
 130       addModulator(yPos);
 131     }
 132
 133     boolean isAvailable() {
 134       return brt.getValuef() <= 0;
 135     }
 136
 137     void noteOn(Note note) {
 138       xPos = lerp(0, model.xMax, constrain(0.5 + (note.getPitch() - 60) / 28., 0, 1));
 139       yPos.setValue(lerp(20, model.yMax*.72, note.getVelocity() / 127.)).stop();
 140       brt.setRangeFromHereTo(lerp(40, 100, note.getVelocity() / 127.), 20).start();
 141     }
 142
 143     void noteOff(Note note) {
 144       yPos.setVelocity(0).setAcceleration(-380).start();
 145       brt.setRangeFromHereTo(0, 1000).start();
 146     }
 147
 148     public void run(double deltaMs, color[] colors) {
 149       float bVal = brt.getValuef();
 150       if (bVal <= 0) {
 151         return;
 152       }
 153       float yVal = yPos.getValuef();
 154       for (LXPoint p : model.points) {
 155         float falloff = 6 - 5*lightSize.getValuef();
 156         float b = max(0, bVal - falloff*dist(p.x, p.y, xPos, yVal));
 157         if (b > 0) {
 158           colors[p.index] = blendColor(colors[p.index], lx.hsb(
 159             (lx.getBaseHuef() + .2*abs(p.x - model.cx) + .2*abs(p.y - model.cy)) % 360,
 160             100,
 161             b
 162           ), ADD);
 163         }
 164       }
 165     }
 166   }
 167
 168   private LightUp getLight() {
 169     for (LightUp light : lights) {
 170       if (light.isAvailable()) {
 171         return light;
 172       }
 173     }
 174     LightUp newLight = new LightUp();
 175     lights.add(newLight);
 176     synchronized(newLayers) {
 177       newLayers.push(newLight);
 178     }
 179     return newLight;
 180   }
 181
 182   private Sweep getSweep() {
 183     for (Sweep s : sweeps) {
 184       if (!s.position.isRunning()) {
 185         return s;
 186       }
 187     }
 188     Sweep newSweep = new Sweep();
 189     sweeps.add(newSweep);
 190     synchronized(newLayers) {
 191       newLayers.push(newSweep);
 192     }
 193     return newSweep;
 194   }
 195
 196   public synchronized boolean noteOn(Note note) {
 197     if (note.getChannel() == 0) {
 198       LightUp light = getLight();
 199       lightMap.put(note.getPitch(), light);
 200       light.noteOn(note);
 201     } else if (note.getChannel() == 1) {
 202     } else if (note.getChannel() == 9) {
 203       if (note.getVelocity() > 0) {
 204         switch (note.getPitch()) {
 205           case 36:
 206             Sweep s = getSweep();
 207             s.bright = 50 + note.getVelocity() / 127. * 50;
 208             s.falloff = 20 - note.getVelocity() / 127. * 17;
 209             s.position.trigger();
 210             break;
 211           case 37:
 212             sparkleBright = note.getVelocity() / 127. * 100;
 213             sparkleDirection = true;
 214             sparkle.trigger();
 215             break;
 216           case 38:
 217             sparkleBright = note.getVelocity() / 127. * 100;
 218             sparkleDirection = false;
 219             sparkle.trigger();
 220             break;
 221           case 39:
 222             effects.boom.trigger();
 223             break;
 224           case 40:
 225             effects.flash.trigger();
 226             break;
 227         }
 228       }
 229     }
 230     return true;
 231   }
 232
 233   public synchronized boolean noteOff(Note note) {
 234     if (note.getChannel() == 0) {
 235       LightUp light = lightMap.get(note.getPitch());
 236       if (light != null) {
 237         light.noteOff(note);
 238       }
 239     }
 240     return true;
 241   }
 242
 243   final float[] wval = new float[16];
 244   float wavoff = 0;
 245
 246   public synchronized void run(double deltaMs) {
 247     wavoff += deltaMs * .001;
 248     for (int i = 0; i < wval.length; ++i) {
 249       wval[i] = model.cy + 0.2 * model.yMax/2. * sin(wavoff + i / 1.9);
 250     }
 251     float sparklePos = (sparkleDirection ? sparkle.getValuef() : (1 - sparkle.getValuef())) * (Cube.POINTS_PER_STRIP)/2.;
 252     float maxBright = sparkleBright * (1 - sparkle.getValuef());
 253     for (Strip s : model.strips) {
 254       int i = 0;
 255       for (LXPoint p : s.points) {
 256         int wavi = (int) constrain(p.x / model.xMax * wval.length, 0, wval.length-1);
 257         float wavb = max(0, wave.getValuef()*100. - 8.*abs(p.y - wval[wavi]));
 258         colors[p.index] = lx.hsb(
 259           (lx.getBaseHuef() + .2*abs(p.x - model.cx) + .2*abs(p.y - model.cy)) % 360,
 260           100,
 261           constrain(wavb + max(0, maxBright - 40.*abs(sparklePos - abs(i - (Cube.POINTS_PER_STRIP-1)/2.))), 0, 100)
 262         );
 263         ++i;
 264       }
 265     }
 266
 267     if (!newLayers.isEmpty()) {
 268       synchronized(newLayers) {
 269         while (!newLayers.isEmpty()) {
 270           addLayer(newLayers.pop());
 271         }
 272       }
 273     }
 274   }
 275 }
 276
 277 class Pulley extends SCPattern {
 278
 279   final int NUM_DIVISIONS = 16;
 280   private final Accelerator[] gravity = new Accelerator[NUM_DIVISIONS];
 281   private final Click[] delays = new Click[NUM_DIVISIONS];
 282
 283   private final Click reset = new Click(9000);
 284   private boolean isRising = false;
 285
 286   private BasicParameter sz = new BasicParameter("SIZE", 0.5);
 287   private BasicParameter beatAmount = new BasicParameter("BEAT", 0);
 288
 289   Pulley(GLucose glucose) {
 290     super(glucose);
 291     for (int i = 0; i < NUM_DIVISIONS; ++i) {
 292       addModulator(gravity[i] = new Accelerator(0, 0, 0));
 293       addModulator(delays[i] = new Click(0));
 294     }
 295     addModulator(reset).start();
 296     addParameter(sz);
 297     addParameter(beatAmount);
 298     trigger();
 299
 300   }
 301
 302   private void trigger() {
 303     isRising = !isRising;
 304     int i = 0;
 305     for (Accelerator g : gravity) {
 306       if (isRising) {
 307         g.setSpeed(random(20, 33), 0).start();
 308       } else {
 309         g.setVelocity(0).setAcceleration(-420);
 310         delays[i].setDuration(random(0, 500)).trigger();
 311       }
 312       ++i;
 313     }
 314   }
 315
 316   public void run(double deltaMs) {
 317     if (reset.click()) {
 318       trigger();
 319     }
 320
 321     if (isRising) {
 322       // Fucking A, had to comment this all out because of that bizarre
 323       // Processing bug where some simple loop takes an absurd amount of
 324       // time, must be some pre-processor bug
 325 //      for (Accelerator g : gravity) {
 326 //        if (g.getValuef() > model.yMax) {
 327 //          g.stop();
 328 //        } else if (g.getValuef() > model.yMax*.55) {
 329 //          if (g.getVelocityf() > 10) {
 330 //            g.setAcceleration(-16);
 331 //          } else {
 332 //            g.setAcceleration(0);
 333 //          }
 334 //        }
 335 //      }
 336     } else {
 337       int j = 0;
 338       for (Click d : delays) {
 339         if (d.click()) {
 340           gravity[j].start();
 341           d.stop();
 342         }
 343         ++j;
 344       }
 345       for (Accelerator g : gravity) {
 346         if (g.getValuef() < 0) {
 347           g.setValue(-g.getValuef());
 348           g.setVelocity(-g.getVelocityf() * random(0.74, 0.84));
 349         }
 350       }
 351     }
 352
 353     // A little silliness to test the grid API
 354     if (midiEngine != null && midiEngine.getFocusedPattern() == this) {
 355             for (int i = 0; i < 5; ++i) {
 356         for (int j = 0; j < 8; ++j) {
 357           int gi = (int) constrain(j * NUM_DIVISIONS / 8, 0, NUM_DIVISIONS-1);
 358           float b = 1 - 4.*abs((6-i)/6. - gravity[gi].getValuef() / model.yMax);
 359           midiEngine.grid.setState(i, j, (b < 0) ? 0 : 3);
 360         }
 361       }
 362     }
 363
 364     float fPos = 1 - lx.tempo.rampf();
 365     if (fPos < .2) {
 366       fPos = .2 + 4 * (.2 - fPos);
 367     }
 368     float falloff = 100. / (3 + sz.getValuef() * 36 + fPos * beatAmount.getValuef()*48);
 369     for (LXPoint p : model.points) {
 370       int gi = (int) constrain((p.x - model.xMin) * NUM_DIVISIONS / (model.xMax - model.xMin), 0, NUM_DIVISIONS-1);
 371       colors[p.index] = lx.hsb(
 372         (lx.getBaseHuef() + abs(p.x - model.cx)*.8 + p.y*.4) % 360,
 373         constrain(130 - p.y*.8, 0, 100),
 374         max(0, 100 - abs(p.y - gravity[gi].getValuef())*falloff)
 375       );
 376     }
 377   }
 378 }
 379
 380 class ViolinWave extends SCPattern {
 381
 382   BasicParameter level = new BasicParameter("LVL", 0.45);
 383   BasicParameter range = new BasicParameter("RNG", 0.5);
 384   BasicParameter edge = new BasicParameter("EDG", 0.5);
 385   BasicParameter release = new BasicParameter("RLS", 0.5);
 386   BasicParameter speed = new BasicParameter("SPD", 0.5);
 387   BasicParameter amp = new BasicParameter("AMP", 0.25);
 388   BasicParameter period = new BasicParameter("WAVE", 0.5);
 389   BasicParameter pSize = new BasicParameter("PSIZE", 0.5);
 390   BasicParameter pSpeed = new BasicParameter("PSPD", 0.5);
 391   BasicParameter pDensity = new BasicParameter("PDENS", 0.25);
 392
 393   LinearEnvelope dbValue = new LinearEnvelope(0, 0, 10);
 394
 395   ViolinWave(GLucose glucose) {
 396     super(glucose);
 397     addParameter(level);
 398     addParameter(edge);
 399     addParameter(range);
 400     addParameter(release);
 401     addParameter(speed);
 402     addParameter(amp);
 403     addParameter(period);
 404     addParameter(pSize);
 405     addParameter(pSpeed);
 406     addParameter(pDensity);
 407
 408     addModulator(dbValue);
 409   }
 410
 411   final List<Particle> particles = new ArrayList<Particle>();
 412
 413   class Particle {
 414
 415     LinearEnvelope x = new LinearEnvelope(0, 0, 0);
 416     LinearEnvelope y = new LinearEnvelope(0, 0, 0);
 417
 418     Particle() {
 419       addModulator(x);
 420       addModulator(y);
 421     }
 422
 423     Particle trigger(boolean direction) {
 424       float xInit = random(model.xMin, model.xMax);
 425       float time = 3000 - 2500*pSpeed.getValuef();
 426       x.setRange(xInit, xInit + random(-40, 40), time).trigger();
 427       y.setRange(model.cy + 10, direction ? model.yMax + 50 : model.yMin - 50, time).trigger();
 428       return this;
 429     }
 430
 431     boolean isActive() {
 432       return x.isRunning() || y.isRunning();
 433     }
 434
 435     public void run(double deltaMs) {
 436       if (!isActive()) {
 437         return;
 438       }
 439
 440       float pFalloff = (30 - 27*pSize.getValuef());
 441       for (LXPoint p : model.points) {
 442         float b = 100 - pFalloff * (abs(p.x - x.getValuef()) + abs(p.y - y.getValuef()));
 443         if (b > 0) {
 444           colors[p.index] = blendColor(colors[p.index], lx.hsb(
 445             lx.getBaseHuef(), 20, b
 446           ), ADD);
 447         }
 448       }
 449     }
 450   }
 451
 452   float[] centers = new float[30];
 453   double accum = 0;
 454   boolean rising = true;
 455
 456   void fireParticle(boolean direction) {
 457     boolean gotOne = false;
 458     for (Particle p : particles) {
 459       if (!p.isActive()) {
 460        p.trigger(direction);
 461        return;
 462       }
 463     }
 464     particles.add(new Particle().trigger(direction));
 465   }
 466
 467   public void run(double deltaMs) {
 468     accum += deltaMs / (1000. - 900.*speed.getValuef());
 469     for (int i = 0; i < centers.length; ++i) {
 470       centers[i] = model.cy + 30*amp.getValuef()*sin((float) (accum + (i-centers.length/2.)/(1. + 9.*period.getValuef())));
 471     }
 472
 473     float zeroDBReference = pow(10, (50 - 190*level.getValuef())/20.);
 474     float dB = 20*GraphicEQ.log10(lx.audioInput().mix.level() / zeroDBReference);
 475     if (dB > dbValue.getValuef()) {
 476       rising = true;
 477       dbValue.setRangeFromHereTo(dB, 10).trigger();
 478     } else {
 479       if (rising) {
 480         for (int j = 0; j < pDensity.getValuef()*3; ++j) {
 481           fireParticle(true);
 482           fireParticle(false);
 483         }
 484       }
 485       rising = false;
 486       dbValue.setRangeFromHereTo(max(dB, -96), 50 + 1000*release.getValuef()).trigger();
 487     }
 488     float edg = 1 + edge.getValuef() * 40;
 489     float rng = (78 - 64 * range.getValuef()) / (model.yMax - model.cy);
 490     float val = max(2, dbValue.getValuef());
 491
 492     for (LXPoint p : model.points) {
 493       int ci = (int) lerp(0, centers.length-1, (p.x - model.xMin) / (model.xMax - model.xMin));
 494       float rFactor = 1.0 -  0.9 * abs(p.x - model.cx) / (model.xMax - model.cx);
 495       colors[p.index] = lx.hsb(
 496         (lx.getBaseHuef() + abs(p.x - model.cx)) % 360,
 497         min(100, 20 + 8*abs(p.y - centers[ci])),
 498         constrain(edg*(val*rFactor - rng * abs(p.y-centers[ci])), 0, 100)
 499       );
 500     }
 501
 502     for (Particle p : particles) {
 503       p.run(deltaMs);
 504     }
 505   }
 506 }
 507
 508 class BouncyBalls extends SCPattern {
 509
 510   static final int NUM_BALLS = 6;
 511
 512   class BouncyBall {
 513
 514     Accelerator yPos;
 515     TriangleLFO xPos = new TriangleLFO(0, model.xMax, random(8000, 19000));
 516     float zPos;
 517
 518     BouncyBall(int i) {
 519       addModulator(xPos.setBasis(random(0, TWO_PI)).start());
 520       addModulator(yPos = new Accelerator(0, 0, 0));
 521       zPos = lerp(model.zMin, model.zMax, (i+2.) / (NUM_BALLS + 4.));
 522     }
 523
 524     void bounce(float midiVel) {
 525       float v = 100 + 8*midiVel;
 526       yPos.setSpeed(v, getAccel(v, 60 / lx.tempo.bpmf())).start();
 527     }
 528
 529     float getAccel(float v, float oneBeat) {
 530       return -2*v / oneBeat;
 531     }
 532
 533     void run(double deltaMs) {
 534       float flrLevel = flr.getValuef() * model.xMax/2.;
 535       if (yPos.getValuef() < flrLevel) {
 536         if (yPos.getVelocity() < -50) {
 537           yPos.setValue(2*flrLevel-yPos.getValuef());
 538           float v = -yPos.getVelocityf() * bounce.getValuef();
 539           yPos.setSpeed(v, getAccel(v, 60 / lx.tempo.bpmf()));
 540         } else {
 541           yPos.setValue(flrLevel).stop();
 542         }
 543       }
 544       float falloff = 130.f / (12 + blobSize.getValuef() * 36);
 545       float xv = xPos.getValuef();
 546       float yv = yPos.getValuef();
 547
 548       for (LXPoint p : model.points) {
 549         float d = sqrt((p.x-xv)*(p.x-xv) + (p.y-yv)*(p.y-yv) + .1*(p.z-zPos)*(p.z-zPos));
 550         float b = constrain(130 - falloff*d, 0, 100);
 551         if (b > 0) {
 552           colors[p.index] = blendColor(colors[p.index], lx.hsb(
 553             (lx.getBaseHuef() + p.y*.5 + abs(model.cx - p.x) * .5) % 360,
 554             max(0, 100 - .45*(p.y - flrLevel)),
 555             b
 556           ), ADD);
 557         }
 558       }
 559     }
 560   }
 561
 562   final BouncyBall[] balls = new BouncyBall[NUM_BALLS];
 563
 564   final BasicParameter bounce = new BasicParameter("BNC", .8);
 565   final BasicParameter flr = new BasicParameter("FLR", 0);
 566   final BasicParameter blobSize = new BasicParameter("SIZE", 0.5);
 567
 568   BouncyBalls(GLucose glucose) {
 569     super(glucose);
 570     for (int i = 0; i < balls.length; ++i) {
 571       balls[i] = new BouncyBall(i);
 572     }
 573     addParameter(bounce);
 574     addParameter(flr);
 575     addParameter(blobSize);
 576   }
 577
 578   public void run(double deltaMs) {
 579     setColors(#000000);
 580     for (BouncyBall b : balls) {
 581       b.run(deltaMs);
 582     }
 583   }
 584
 585   public boolean noteOn(Note note) {
 586     int pitch = (note.getPitch() + note.getChannel()) % NUM_BALLS;
 587     balls[pitch].bounce(note.getVelocity());
 588     return true;
 589   }
 590 }
 591
 592 class SpaceTime extends SCPattern {
 593
 594   SinLFO pos = new SinLFO(0, 1, 3000);
 595   SinLFO rate = new SinLFO(1000, 9000, 13000);
 596   SinLFO falloff = new SinLFO(10, 70, 5000);
 597   float angle = 0;
 598
 599   BasicParameter rateParameter = new BasicParameter("RATE", 0.5);
 600   BasicParameter sizeParameter = new BasicParameter("SIZE", 0.5);
 601
 602
 603   public SpaceTime(GLucose glucose) {
 604     super(glucose);
 605
 606     addModulator(pos).trigger();
 607     addModulator(rate).trigger();
 608     addModulator(falloff).trigger();
 609     pos.modulateDurationBy(rate);
 610     addParameter(rateParameter);
 611     addParameter(sizeParameter);
 612   }
 613
 614   public void onParameterChanged(LXParameter parameter) {
 615     if (parameter == rateParameter) {
 616       rate.stop().setValue(9000 - 8000*parameter.getValuef());
 617     }  else if (parameter == sizeParameter) {
 618       falloff.stop().setValue(70 - 60*parameter.getValuef());
 619     }
 620   }
 621
 622   void run(double deltaMs) {
 623     angle += deltaMs * 0.0007;
 624     float sVal1 = model.strips.size() * (0.5 + 0.5*sin(angle));
 625     float sVal2 = model.strips.size() * (0.5 + 0.5*cos(angle));
 626
 627     float pVal = pos.getValuef();
 628     float fVal = falloff.getValuef();
 629
 630     int s = 0;
 631     for (Strip strip : model.strips) {
 632       int i = 0;
 633       for (LXPoint p : strip.points) {
 634         colors[p.index] = lx.hsb(
 635           (lx.getBaseHuef() + 360 - p.x*.2 + p.y * .3) % 360,
 636           constrain(.4 * min(abs(s - sVal1), abs(s - sVal2)), 20, 100),
 637           max(0, 100 - fVal*abs(i - pVal*(strip.metrics.numPoints - 1)))
 638         );
 639         ++i;
 640       }
 641       ++s;
 642     }
 643   }
 644 }
 645
 646 class Swarm extends SCPattern {
 647
 648   SawLFO offset = new SawLFO(0, 1, 1000);
 649   SinLFO rate = new SinLFO(350, 1200, 63000);
 650   SinLFO falloff = new SinLFO(15, 50, 17000);
 651   SinLFO fX = new SinLFO(model.xMin, model.xMax, 19000);
 652   SinLFO fY = new SinLFO(model.yMin, model.yMax, 11000);
 653   SinLFO hOffX = new SinLFO(model.xMin, model.xMax, 13000);
 654
 655   public Swarm(GLucose glucose) {
 656     super(glucose);
 657
 658     addModulator(offset).trigger();
 659     addModulator(rate).trigger();
 660     addModulator(falloff).trigger();
 661     addModulator(fX).trigger();
 662     addModulator(fY).trigger();
 663     addModulator(hOffX).trigger();
 664     offset.modulateDurationBy(rate);
 665   }
 666
 667   float modDist(float v1, float v2, float mod) {
 668     v1 = v1 % mod;
 669     v2 = v2 % mod;
 670     if (v2 > v1) {
 671       return min(v2-v1, v1+mod-v2);
 672     }
 673     else {
 674       return min(v1-v2, v2+mod-v1);
 675     }
 676   }
 677
 678   void run(double deltaMs) {
 679     float s = 0;
 680     for (Strip strip : model.strips) {
 681       int i = 0;
 682       for (LXPoint p : strip.points) {
 683         float fV = max(-1, 1 - dist(p.x/2., p.y, fX.getValuef()/2., fY.getValuef()) / 64.);
 684         colors[p.index] = lx.hsb(
 685         (lx.getBaseHuef() + 0.3 * abs(p.x - hOffX.getValuef())) % 360,
 686         constrain(80 + 40 * fV, 0, 100),
 687         constrain(100 - (30 - fV * falloff.getValuef()) * modDist(i + (s*63)%61, offset.getValuef() * strip.metrics.numPoints, strip.metrics.numPoints), 0, 100)
 688           );
 689         ++i;
 690       }
 691       ++s;
 692     }
 693   }
 694 }
 695
 696 class SwipeTransition extends SCTransition {
 697
 698   final BasicParameter bleed = new BasicParameter("WIDTH", 0.5);
 699
 700   SwipeTransition(GLucose glucose) {
 701     super(glucose);
 702     setDuration(5000);
 703     addParameter(bleed);
 704   }
 705
 706   void computeBlend(int[] c1, int[] c2, double progress) {
 707     float bleedf = 10 + bleed.getValuef() * 200.;
 708     float xPos = (float) (-bleedf + progress * (model.xMax + bleedf));
 709     for (LXPoint p : model.points) {
 710       float d = (p.x - xPos) / bleedf;
 711       if (d < 0) {
 712         colors[p.index] = c2[p.index];
 713       } else if (d > 1) {
 714         colors[p.index] = c1[p.index];
 715       } else {
 716         colors[p.index] = lerpColor(c2[p.index], c1[p.index], d, RGB);
 717       }
 718     }
 719   }
 720 }
 721
 722 abstract class BlendTransition extends SCTransition {
 723
 724   final int blendType;
 725
 726   BlendTransition(GLucose glucose, int blendType) {
 727     super(glucose);
 728     this.blendType = blendType;
 729   }
 730
 731   void computeBlend(int[] c1, int[] c2, double progress) {
 732     if (progress < 0.5) {
 733       for (int i = 0; i < c1.length; ++i) {
 734         colors[i] = lerpColor(
 735           c1[i],
 736           blendColor(c1[i], c2[i], blendType),
 737           (float) (2.*progress),
 738           RGB);
 739       }
 740     } else {
 741       for (int i = 0; i < c1.length; ++i) {
 742         colors[i] = lerpColor(
 743           c2[i],
 744           blendColor(c1[i], c2[i], blendType),
 745           (float) (2.*(1. - progress)),
 746           RGB);
 747       }
 748     }
 749   }
 750 }
 751
 752 class MultiplyTransition extends BlendTransition {
 753   MultiplyTransition(GLucose glucose) {
 754     super(glucose, MULTIPLY);
 755   }
 756 }
 757
 758 class ScreenTransition extends BlendTransition {
 759   ScreenTransition(GLucose glucose) {
 760     super(glucose, SCREEN);
 761   }
 762 }
 763
 764 class BurnTransition extends BlendTransition {
 765   BurnTransition(GLucose glucose) {
 766     super(glucose, BURN);
 767   }
 768 }
 769
 770 class DodgeTransition extends BlendTransition {
 771   DodgeTransition(GLucose glucose) {
 772     super(glucose, DODGE);
 773   }
 774 }
 775
 776 class OverlayTransition extends BlendTransition {
 777   OverlayTransition(GLucose glucose) {
 778     super(glucose, OVERLAY);
 779   }
 780 }
 781
 782 class AddTransition extends BlendTransition {
 783   AddTransition(GLucose glucose) {
 784     super(glucose, ADD);
 785   }
 786 }
 787
 788 class SubtractTransition extends BlendTransition {
 789   SubtractTransition(GLucose glucose) {
 790     super(glucose, SUBTRACT);
 791   }
 792 }
 793
 794 class SoftLightTransition extends BlendTransition {
 795   SoftLightTransition(GLucose glucose) {
 796     super(glucose, SOFT_LIGHT);
 797   }
 798 }
 799
 800 class BassPod extends SCPattern {
 801
 802   private GraphicEQ eq = null;
 803
 804   private final BasicParameter clr = new BasicParameter("CLR", 0.5);
 805
 806   public BassPod(GLucose glucose) {
 807     super(glucose);
 808     addParameter(clr);
 809   }
 810
 811   protected void onActive() {
 812     if (eq == null) {
 813       eq = new GraphicEQ(lx, 16);
 814       eq.range.setValue(0.4);
 815       eq.level.setValue(0.4);
 816       eq.slope.setValue(0.6);
 817       addParameter(eq.level);
 818       addParameter(eq.range);
 819       addParameter(eq.attack);
 820       addParameter(eq.release);
 821       addParameter(eq.slope);
 822     }
 823   }
 824
 825   public void run(double deltaMs) {
 826     eq.run(deltaMs);
 827
 828     float bassLevel = eq.getAverageLevel(0, 5);
 829
 830     float satBase = bassLevel*480*clr.getValuef();
 831
 832     for (LXPoint p : model.points) {
 833       int avgIndex = (int) constrain(1 + abs(p.x-model.cx)/(model.cx)*(eq.numBands-5), 0, eq.numBands-5);
 834       float value = 0;
 835       for (int i = avgIndex; i < avgIndex + 5; ++i) {
 836         value += eq.getLevel(i);
 837       }
 838       value /= 5.;
 839
 840       float b = constrain(8 * (value*model.yMax - abs(p.y-model.yMax/2.)), 0, 100);
 841       colors[p.index] = lx.hsb(
 842         (lx.getBaseHuef() + abs(p.y - model.cy) + abs(p.x - model.cx)) % 360,
 843         constrain(satBase - .6*dist(p.x, p.y, model.cx, model.cy), 0, 100),
 844         b
 845       );
 846     }
 847   }
 848 }
 849
 850
 851 class CubeEQ extends SCPattern {
 852
 853   private GraphicEQ eq = null;
 854
 855   private final BasicParameter edge = new BasicParameter("EDGE", 0.5);
 856   private final BasicParameter clr = new BasicParameter("CLR", 0.5);
 857   private final BasicParameter blockiness = new BasicParameter("BLK", 0.5);
 858
 859   public CubeEQ(GLucose glucose) {
 860     super(glucose);
 861   }
 862
 863   protected void onActive() {
 864     if (eq == null) {
 865       eq = new GraphicEQ(lx, 16);
 866       addParameter(eq.level);
 867       addParameter(eq.range);
 868       addParameter(eq.attack);
 869       addParameter(eq.release);
 870       addParameter(eq.slope);
 871       addParameter(edge);
 872       addParameter(clr);
 873       addParameter(blockiness);
 874     }
 875   }
 876
 877   public void run(double deltaMs) {
 878     eq.run(deltaMs);
 879
 880     float edgeConst = 2 + 30*edge.getValuef();
 881     float clrConst = 1.1 + clr.getValuef();
 882
 883     for (LXPoint p : model.points) {
 884       float avgIndex = constrain(2 + p.x / model.xMax * (eq.numBands-4), 0, eq.numBands-4);
 885       int avgFloor = (int) avgIndex;
 886
 887       float leftVal = eq.getLevel(avgFloor);
 888       float rightVal = eq.getLevel(avgFloor+1);
 889       float smoothValue = lerp(leftVal, rightVal, avgIndex-avgFloor);
 890
 891       float chunkyValue = (
 892         eq.getLevel(avgFloor/4*4) +
 893         eq.getLevel(avgFloor/4*4 + 1) +
 894         eq.getLevel(avgFloor/4*4 + 2) +
 895         eq.getLevel(avgFloor/4*4 + 3)
 896       ) / 4.;
 897
 898       float value = lerp(smoothValue, chunkyValue, blockiness.getValuef());
 899
 900       float b = constrain(edgeConst * (value*model.yMax - p.y), 0, 100);
 901       colors[p.index] = lx.hsb(
 902         (480 + lx.getBaseHuef() - min(clrConst*p.y, 120)) % 360,
 903         100,
 904         b
 905       );
 906     }
 907   }
 908 }
 909
 910 class BoomEffect extends SCEffect {
 911
 912   final BasicParameter falloff = new BasicParameter("WIDTH", 0.5);
 913   final BasicParameter speed = new BasicParameter("SPD", 0.5);
 914   final BasicParameter bright = new BasicParameter("BRT", 1.0);
 915   final BasicParameter sat = new BasicParameter("SAT", 0.2);
 916   List<Layer> layers = new ArrayList<Layer>();
 917   final float maxr = sqrt(model.xMax*model.xMax + model.yMax*model.yMax + model.zMax*model.zMax) + 10;
 918
 919   class Layer {
 920     LinearEnvelope boom = new LinearEnvelope(-40, 500, 1300);
 921
 922     Layer() {
 923       addModulator(boom);
 924       trigger();
 925     }
 926
 927     void trigger() {
 928       float falloffv = falloffv();
 929       boom.setRange(-100 / falloffv, maxr + 100/falloffv, 4000 - speed.getValuef() * 3300);
 930       boom.trigger();
 931     }
 932
 933     void apply(int[] colors) {
 934       float brightv = 100 * bright.getValuef();
 935       float falloffv = falloffv();
 936       float satv = sat.getValuef() * 100;
 937       float huev = lx.getBaseHuef();
 938       for (LXPoint p : model.points) {
 939         colors[p.index] = blendColor(
 940         colors[p.index],
 941         lx.hsb(huev, satv, constrain(brightv - falloffv*abs(boom.getValuef() - dist(p.x, 2*p.y, 3*p.z, model.xMax/2, model.yMax, model.zMax*1.5)), 0, 100)),
 942         ADD);
 943       }
 944     }
 945   }
 946
 947   BoomEffect(GLucose glucose) {
 948     super(glucose, true);
 949     addParameter(falloff);
 950     addParameter(speed);
 951     addParameter(bright);
 952     addParameter(sat);
 953   }
 954
 955   public void onEnable() {
 956     for (Layer l : layers) {
 957       if (!l.boom.isRunning()) {
 958         l.trigger();
 959         return;
 960       }
 961     }
 962     layers.add(new Layer());
 963   }
 964
 965   private float falloffv() {
 966     return 20 - 19 * falloff.getValuef();
 967   }
 968
 969   public void onTrigger() {
 970     onEnable();
 971   }
 972
 973   public void apply(int[] colors) {
 974     for (Layer l : layers) {
 975       if (l.boom.isRunning()) {
 976         l.apply(colors);
 977       }
 978     }
 979   }
 980 }
 981
 982 public class PianoKeyPattern extends SCPattern {
 983
 984   final LinearEnvelope[] cubeBrt;
 985   final SinLFO base[];
 986   final BasicParameter attack = new BasicParameter("ATK", 0.1);
 987   final BasicParameter release = new BasicParameter("REL", 0.5);
 988   final BasicParameter level = new BasicParameter("AMB", 0.6);
 989
 990   PianoKeyPattern(GLucose glucose) {
 991     super(glucose);
 992
 993     addParameter(attack);
 994     addParameter(release);
 995     addParameter(level);
 996     cubeBrt = new LinearEnvelope[model.cubes.size() / 4];
 997     for (int i = 0; i < cubeBrt.length; ++i) {
 998       addModulator(cubeBrt[i] = new LinearEnvelope(0, 0, 100));
 999     }
1000     base = new SinLFO[model.cubes.size() / 12];
1001     for (int i = 0; i < base.length; ++i) {
1002       addModulator(base[i] = new SinLFO(0, 1, 7000 + 1000*i)).trigger();
1003     }
1004   }
1005
1006   private float getAttackTime() {
1007     return 15 + attack.getValuef()*attack.getValuef() * 2000;
1008   }
1009
1010   private float getReleaseTime() {
1011     return 15 + release.getValuef() * 3000;
1012   }
1013
1014   private LinearEnvelope getEnvelope(int index) {
1015     return cubeBrt[index % cubeBrt.length];
1016   }
1017
1018   private SinLFO getBase(int index) {
1019     return base[index % base.length];
1020   }
1021
1022   public boolean noteOn(Note note) {
1023     LinearEnvelope env = getEnvelope(note.getPitch());
1024     env.setEndVal(min(1, env.getValuef() + (note.getVelocity() / 127.)), getAttackTime()).start();
1025     return true;
1026   }
1027
1028   public boolean noteOff(Note note) {
1029     getEnvelope(note.getPitch()).setEndVal(0, getReleaseTime()).start();
1030     return true;
1031   }
1032
1033   public void run(double deltaMs) {
1034     int i = 0;
1035     float huef = lx.getBaseHuef();
1036     float levelf = level.getValuef();
1037     for (Cube c : model.cubes) {
1038       float v = max(getBase(i).getValuef() * levelf/4., getEnvelope(i++).getValuef());
1039       setColor(c, lx.hsb(
1040         (huef + 20*v + abs(c.cx-model.xMax/2.)*.3 + c.cy) % 360,
1041         min(100, 120*v),
1042         100*v
1043       ));
1044     }
1045   }
1046 }
1047
1048 class CrossSections extends SCPattern {
1049
1050   final SinLFO x = new SinLFO(0, model.xMax, 5000);
1051   final SinLFO y = new SinLFO(0, model.yMax, 6000);
1052   final SinLFO z = new SinLFO(0, model.zMax, 7000);
1053
1054   final BasicParameter xw = new BasicParameter("XWID", 0.3);
1055   final BasicParameter yw = new BasicParameter("YWID", 0.3);
1056   final BasicParameter zw = new BasicParameter("ZWID", 0.3);
1057   final BasicParameter xr = new BasicParameter("XRAT", 0.7);
1058   final BasicParameter yr = new BasicParameter("YRAT", 0.6);
1059   final BasicParameter zr = new BasicParameter("ZRAT", 0.5);
1060   final BasicParameter xl = new BasicParameter("XLEV", 1);
1061   final BasicParameter yl = new BasicParameter("YLEV", 1);
1062   final BasicParameter zl = new BasicParameter("ZLEV", 0.5);
1063
1064
1065   CrossSections(GLucose glucose) {
1066     super(glucose);
1067     addModulator(x).trigger();
1068     addModulator(y).trigger();
1069     addModulator(z).trigger();
1070     addParams();
1071   }
1072
1073   protected void addParams() {
1074     addParameter(xr);
1075     addParameter(yr);
1076     addParameter(zr);
1077     addParameter(xw);
1078     addParameter(xl);
1079     addParameter(yl);
1080     addParameter(zl);
1081     addParameter(yw);
1082     addParameter(zw);
1083   }
1084
1085   void onParameterChanged(LXParameter p) {
1086     if (p == xr) {
1087       x.setDuration(10000 - 8800*p.getValuef());
1088     } else if (p == yr) {
1089       y.setDuration(10000 - 9000*p.getValuef());
1090     } else if (p == zr) {
1091       z.setDuration(10000 - 9000*p.getValuef());
1092     }
1093   }
1094
1095   float xv, yv, zv;
1096
1097   protected void updateXYZVals() {
1098     xv = x.getValuef();
1099     yv = y.getValuef();
1100     zv = z.getValuef();
1101   }
1102
1103   public void run(double deltaMs) {
1104     updateXYZVals();
1105
1106     float xlv = 100*xl.getValuef();
1107     float ylv = 100*yl.getValuef();
1108     float zlv = 100*zl.getValuef();
1109
1110     float xwv = 100. / (10 + 40*xw.getValuef());
1111     float ywv = 100. / (10 + 40*yw.getValuef());
1112     float zwv = 100. / (10 + 40*zw.getValuef());
1113
1114     for (LXPoint p : model.points) {
1115       color c = 0;
1116       c = blendColor(c, lx.hsb(
1117       (lx.getBaseHuef() + p.x/10 + p.y/3) % 360,
1118       constrain(140 - 1.1*abs(p.x - model.xMax/2.), 0, 100),
1119       max(0, xlv - xwv*abs(p.x - xv))
1120         ), ADD);
1121       c = blendColor(c, lx.hsb(
1122       (lx.getBaseHuef() + 80 + p.y/10) % 360,
1123       constrain(140 - 2.2*abs(p.y - model.yMax/2.), 0, 100),
1124       max(0, ylv - ywv*abs(p.y - yv))
1125         ), ADD);
1126       c = blendColor(c, lx.hsb(
1127       (lx.getBaseHuef() + 160 + p.z / 10 + p.y/2) % 360,
1128       constrain(140 - 2.2*abs(p.z - model.zMax/2.), 0, 100),
1129       max(0, zlv - zwv*abs(p.z - zv))
1130         ), ADD);
1131       colors[p.index] = c;
1132     }
1133   }
1134 }
1135
1136 class Blinders extends SCPattern {
1137
1138   final SinLFO[] m;
1139   final TriangleLFO r;
1140   final SinLFO s;
1141   final TriangleLFO hs;
1142
1143   public Blinders(GLucose glucose) {
1144     super(glucose);
1145     m = new SinLFO[12];
1146     for (int i = 0; i < m.length; ++i) {
1147       addModulator(m[i] = new SinLFO(0.5, 120, (120000. / (3+i)))).trigger();
1148     }
1149     addModulator(r = new TriangleLFO(9000, 15000, 29000)).trigger();
1150     addModulator(s = new SinLFO(-20, 275, 11000)).trigger();
1151     addModulator(hs = new TriangleLFO(0.1, 0.5, 15000)).trigger();
1152     s.modulateDurationBy(r);
1153   }
1154
1155   public void run(double deltaMs) {
1156     float hv = lx.getBaseHuef();
1157     int si = 0;
1158     for (Strip strip : model.strips) {
1159       int i = 0;
1160       float mv = m[si % m.length].getValuef();
1161       for (LXPoint p : strip.points) {
1162         colors[p.index] = lx.hsb(
1163           (hv + p.z + p.y*hs.getValuef()) % 360,
1164           min(100, abs(p.x - s.getValuef())/2.),
1165           max(0, 100 - mv/2. - mv * abs(i - (strip.metrics.length-1)/2.))
1166         );
1167         ++i;
1168       }
1169       ++si;
1170     }
1171   }
1172 }
1173
1174 class Psychedelia extends SCPattern {
1175
1176   final int NUM = 3;
1177   SinLFO m = new SinLFO(-0.5, NUM-0.5, 9000);
1178   SinLFO s = new SinLFO(-20, 147, 11000);
1179   TriangleLFO h = new TriangleLFO(0, 240, 19000);
1180   SinLFO c = new SinLFO(-.2, .8, 31000);
1181
1182   Psychedelia(GLucose glucose) {
1183     super(glucose);
1184     addModulator(m).trigger();
1185     addModulator(s).trigger();
1186     addModulator(h).trigger();
1187     addModulator(c).trigger();
1188   }
1189
1190   void run(double deltaMs) {
1191     float huev = h.getValuef();
1192     float cv = c.getValuef();
1193     float sv = s.getValuef();
1194     float mv = m.getValuef();
1195     int i = 0;
1196     for (Strip strip : model.strips) {
1197       for (LXPoint p : strip.points) {
1198         colors[p.index] = lx.hsb(
1199           (huev + i*constrain(cv, 0, 2) + p.z/2. + p.x/4.) % 360,
1200           min(100, abs(p.y-sv)),
1201           max(0, 100 - 50*abs((i%NUM) - mv))
1202         );
1203       }
1204       ++i;
1205     }
1206   }
1207 }
1208
1209 class AskewPlanes extends SCPattern {
1210
1211   class Plane {
1212     private final SinLFO a;
1213     private final SinLFO b;
1214     private final SinLFO c;
1215     float av = 1;
1216     float bv = 1;
1217     float cv = 1;
1218     float denom = 0.1;
1219
1220     Plane(int i) {
1221       addModulator(a = new SinLFO(-1, 1, 4000 + 1029*i)).trigger();
1222       addModulator(b = new SinLFO(-1, 1, 11000 - 1104*i)).trigger();
1223       addModulator(c = new SinLFO(-50, 50, 4000 + 1000*i * ((i % 2 == 0) ? 1 : -1))).trigger();
1224     }
1225
1226     void run(double deltaMs) {
1227       av = a.getValuef();
1228       bv = b.getValuef();
1229       cv = c.getValuef();
1230       denom = sqrt(av*av + bv*bv);
1231     }
1232   }
1233
1234   final Plane[] planes;
1235   final int NUM_PLANES = 3;
1236
1237   AskewPlanes(GLucose glucose) {
1238     super(glucose);
1239     planes = new Plane[NUM_PLANES];
1240     for (int i = 0; i < planes.length; ++i) {
1241       planes[i] = new Plane(i);
1242     }
1243   }
1244
1245   public void run(double deltaMs) {
1246     float huev = lx.getBaseHuef();
1247
1248     // This is super fucking bizarre. But if this is a for loop, the framerate
1249     // tanks to like 30FPS, instead of 60. Call them manually and it works fine.
1250     // Doesn't make ANY sense... there must be some weird side effect going on
1251     // with the Processing internals perhaps?
1252 //    for (Plane plane : planes) {
1253 //      plane.run(deltaMs);
1254 //    }
1255     planes[0].run(deltaMs);
1256     planes[1].run(deltaMs);
1257     planes[2].run(deltaMs);
1258
1259     for (LXPoint p : model.points) {
1260       float d = MAX_FLOAT;
1261       for (Plane plane : planes) {
1262         if (plane.denom != 0) {
1263           d = min(d, abs(plane.av*(p.x-model.cx) + plane.bv*(p.y-model.cy) + plane.cv) / plane.denom);
1264         }
1265       }
1266       colors[p.index] = lx.hsb(
1267         (huev + abs(p.x-model.cx)*.3 + p.y*.8) % 360,
1268         max(0, 100 - .8*abs(p.x - model.cx)),
1269         constrain(140 - 10.*d, 0, 100)
1270       );
1271     }
1272   }
1273 }
1274
1275 class ShiftingPlane extends SCPattern {
1276
1277   final SinLFO a = new SinLFO(-.2, .2, 5300);
1278   final SinLFO b = new SinLFO(1, -1, 13300);
1279   final SinLFO c = new SinLFO(-1.4, 1.4, 5700);
1280   final SinLFO d = new SinLFO(-10, 10, 9500);
1281
1282   ShiftingPlane(GLucose glucose) {
1283     super(glucose);
1284     addModulator(a).trigger();
1285     addModulator(b).trigger();
1286     addModulator(c).trigger();
1287     addModulator(d).trigger();
1288   }
1289
1290   public void run(double deltaMs) {
1291     float hv = lx.getBaseHuef();
1292     float av = a.getValuef();
1293     float bv = b.getValuef();
1294     float cv = c.getValuef();
1295     float dv = d.getValuef();
1296     float denom = sqrt(av*av + bv*bv + cv*cv);
1297     for (LXPoint p : model.points) {
1298       float d = abs(av*(p.x-model.cx) + bv*(p.y-model.cy) + cv*(p.z-model.cz) + dv) / denom;
1299       colors[p.index] = lx.hsb(
1300         (hv + abs(p.x-model.cx)*.6 + abs(p.y-model.cy)*.9 + abs(p.z - model.cz)) % 360,
1301         constrain(110 - d*6, 0, 100),
1302         constrain(130 - 7*d, 0, 100)
1303       );
1304     }
1305   }
1306 }
1307
1308 class Traktor extends SCPattern {
1309
1310   final int FRAME_WIDTH = 60;
1311
1312   final BasicParameter speed = new BasicParameter("SPD", 0.5);
1313
1314   private float[] bass = new float[FRAME_WIDTH];
1315   private float[] treble = new float[FRAME_WIDTH];
1316
1317   private int index = 0;
1318   private GraphicEQ eq = null;
1319
1320   public Traktor(GLucose glucose) {
1321     super(glucose);
1322     for (int i = 0; i < FRAME_WIDTH; ++i) {
1323       bass[i] = 0;
1324       treble[i] = 0;
1325     }
1326     addParameter(speed);
1327   }
1328
1329   public void onActive() {
1330     if (eq == null) {
1331       eq = new GraphicEQ(lx, 16);
1332       eq.slope.setValue(0.6);
1333       eq.level.setValue(0.65);
1334       eq.range.setValue(0.35);
1335       eq.release.setValue(0.4);
1336       addParameter(eq.level);
1337       addParameter(eq.range);
1338       addParameter(eq.attack);
1339       addParameter(eq.release);
1340       addParameter(eq.slope);
1341     }
1342   }
1343
1344   int counter = 0;
1345
1346   public void run(double deltaMs) {
1347     eq.run(deltaMs);
1348
1349     int stepThresh = (int) (40 - 39*speed.getValuef());
1350     counter += deltaMs;
1351     if (counter < stepThresh) {
1352       return;
1353     }
1354     counter = counter % stepThresh;
1355
1356     index = (index + 1) % FRAME_WIDTH;
1357
1358     float rawBass = eq.getAverageLevel(0, 4);
1359     float rawTreble = eq.getAverageLevel(eq.numBands-7, 7);
1360
1361     bass[index] = rawBass * rawBass * rawBass * rawBass;
1362     treble[index] = rawTreble * rawTreble;
1363
1364     for (LXPoint p : model.points) {
1365       int i = (int) constrain((model.xMax - p.x) / model.xMax * FRAME_WIDTH, 0, FRAME_WIDTH-1);
1366       int pos = (index + FRAME_WIDTH - i) % FRAME_WIDTH;
1367
1368       colors[p.index] = lx.hsb(
1369         (360 + lx.getBaseHuef() + .8*abs(p.x-model.cx)) % 360,
1370         100,
1371         constrain(9 * (bass[pos]*model.cy - abs(p.y - model.cy + 5)), 0, 100)
1372       );
1373       colors[p.index] = blendColor(colors[p.index], lx.hsb(
1374         (400 + lx.getBaseHuef() + .5*abs(p.x-model.cx)) % 360,
1375         60,
1376         constrain(5 * (treble[pos]*.6*model.cy - abs(p.y - model.cy)), 0, 100)
1377
1378       ), ADD);
1379     }
1380   }
1381 }
1382
1383 class ColorFuckerEffect extends SCEffect {
1384
1385   final BasicParameter level = new BasicParameter("BRT", 1);
1386   final BasicParameter desat = new BasicParameter("DSAT", 0);
1387   final BasicParameter hueShift = new BasicParameter("HSHFT", 0);
1388   final BasicParameter sharp = new BasicParameter("SHARP", 0);
1389   final BasicParameter soft = new BasicParameter("SOFT", 0);
1390   final BasicParameter mono = new BasicParameter("MONO", 0);
1391   final BasicParameter invert = new BasicParameter("INVERT", 0);
1392
1393
1394   float[] hsb = new float[3];
1395
1396   ColorFuckerEffect(GLucose glucose) {
1397     super(glucose);
1398     addParameter(level);
1399     addParameter(desat);
1400     addParameter(sharp);
1401     addParameter(hueShift);
1402     addParameter(soft);
1403     addParameter(mono);
1404     addParameter(invert);
1405   }
1406
1407   public void apply(int[] colors) {
1408     if (!enabled) {
1409       return;
1410     }
1411     float bMod = level.getValuef();
1412     float sMod = 1 - desat.getValuef();
1413     float hMod = hueShift.getValuef();
1414     float fSharp = sharp.getValuef();
1415     float fSoft = soft.getValuef();
1416     boolean mon = mono.getValuef() > 0.5;
1417     boolean ivt = invert.getValuef() > 0.5;
1418     if (bMod < 1 || sMod < 1 || hMod > 0 || fSharp > 0 || ivt || mon || fSoft > 0) {
1419       for (int i = 0; i < colors.length; ++i) {
1420         lx.RGBtoHSB(colors[i], hsb);
1421         if (mon) {
1422           hsb[0] = lx.getBaseHuef() / 360.;
1423         }
1424         if (ivt) {
1425           hsb[2] = 1 - hsb[2];
1426         }
1427         if (fSharp > 0) {
1428           fSharp = 1/(1-fSharp);
1429           if (hsb[2] < .5) {
1430             hsb[2] = pow(hsb[2],fSharp);
1431           } else {
1432             hsb[2] = 1-pow(1-hsb[2],fSharp);
1433           }
1434         }
1435         if (fSoft > 0) {
1436           if (hsb[2] > 0.5) {
1437             hsb[2] = lerp(hsb[2], 0.5 + 2 * (hsb[2]-0.5)*(hsb[2]-0.5), fSoft);
1438           } else {
1439             hsb[2] = lerp(hsb[2], 0.5 * sqrt(2*hsb[2]), fSoft);
1440           }
1441         }
1442         colors[i] = lx.hsb(
1443           (360. * hsb[0] + hMod*360.) % 360,
1444           100. * hsb[1] * sMod,
1445           100. * hsb[2] * bMod
1446         );
1447       }
1448     }
1449   }
1450 }
1451
1452 class QuantizeEffect extends SCEffect {
1453
1454   color[] quantizedFrame;
1455   float lastQuant;
1456   final BasicParameter amount = new BasicParameter("AMT", 0);
1457
1458   QuantizeEffect(GLucose glucose) {
1459     super(glucose);
1460     quantizedFrame = new color[glucose.lx.total];
1461     lastQuant = 0;
1462   }
1463
1464   public void apply(int[] colors) {
1465     float fQuant = amount.getValuef();
1466     if (fQuant > 0) {
1467       float tRamp = (lx.tempo.rampf() % (1./pow(2,floor((1-fQuant) * 4))));
1468       float f = lastQuant;
1469       lastQuant = tRamp;
1470       if (tRamp > f) {
1471         for (int i = 0; i < colors.length; ++i) {
1472           colors[i] = quantizedFrame[i];
1473         }
1474         return;
1475       }
1476     }
1477     for (int i = 0; i < colors.length; ++i) {
1478       quantizedFrame[i] = colors[i];
1479     }
1480   }
1481 }
1482
1483 class BlurEffect extends SCEffect {
1484
1485   final BasicParameter amount = new BasicParameter("AMT", 0);
1486   final int[] frame;
1487   final LinearEnvelope env = new LinearEnvelope(0, 1, 100);
1488
1489   BlurEffect(GLucose glucose) {
1490     super(glucose);
1491     addParameter(amount);
1492     addModulator(env);
1493     frame = new int[lx.total];
1494     for (int i = 0; i < frame.length; ++i) {
1495       frame[i] = #000000;
1496     }
1497   }
1498
1499   public void onEnable() {
1500     env.setRangeFromHereTo(1, 400).start();
1501     for (int i = 0; i < frame.length; ++i) {
1502       frame[i] = #000000;
1503     }
1504   }
1505
1506   public void onDisable() {
1507     env.setRangeFromHereTo(0, 1000).start();
1508   }
1509
1510   public void apply(int[] colors) {
1511     float amt = env.getValuef() * amount.getValuef();
1512     if (amt > 0) {
1513       amt = (1 - amt);
1514       amt = 1 - (amt*amt*amt);
1515       for (int i = 0; i < colors.length; ++i) {
1516         // frame[i] = colors[i] = blendColor(colors[i], lerpColor(#000000, frame[i], amt, RGB), SCREEN);
1517         frame[i] = colors[i] = lerpColor(colors[i], blendColor(colors[i], frame[i], SCREEN), amt, RGB);
1518       }
1519     }
1520
1521   }
1522 }
1523