MarkSlee.pde

   1 class SpaceTime extends SCPattern {
   2
   3   SinLFO pos = new SinLFO(0, 1, 3000);
   4   SinLFO rate = new SinLFO(1000, 9000, 13000);
   5   SinLFO falloff = new SinLFO(10, 70, 5000);
   6   float angle = 0;
   7
   8   BasicParameter rateParameter = new BasicParameter("RATE", 0.5);
   9   BasicParameter sizeParameter = new BasicParameter("SIZE", 0.5);
  10
  11
  12   public SpaceTime(GLucose glucose) {
  13     super(glucose);
  14
  15     addModulator(pos).trigger();
  16     addModulator(rate).trigger();
  17     addModulator(falloff).trigger();
  18     pos.modulateDurationBy(rate);
  19     addParameter(rateParameter);
  20     addParameter(sizeParameter);
  21   }
  22
  23   public void onParameterChanged(LXParameter parameter) {
  24     if (parameter == rateParameter) {
  25       rate.stop().setValue(9000 - 8000*parameter.getValuef());
  26     }  else if (parameter == sizeParameter) {
  27       falloff.stop().setValue(70 - 60*parameter.getValuef());
  28     }
  29   }
  30
  31   void run(int deltaMs) {
  32     angle += deltaMs * 0.0007;
  33     float sVal1 = model.strips.size() * (0.5 + 0.5*sin(angle));
  34     float sVal2 = model.strips.size() * (0.5 + 0.5*cos(angle));
  35
  36     float pVal = pos.getValuef();
  37     float fVal = falloff.getValuef();
  38
  39     int s = 0;
  40     for (Strip strip : model.strips) {
  41       int i = 0;
  42       for (Point p : strip.points) {
  43         colors[p.index] = color(
  44           (lx.getBaseHuef() + 360 - p.fx*.2 + p.fy * .3) % 360,
  45           constrain(.4 * min(abs(s - sVal1), abs(s - sVal2)), 20, 100),
  46           max(0, 100 - fVal*abs(i - pVal*(strip.metrics.numPoints - 1)))
  47         );
  48         ++i;
  49       }
  50       ++s;
  51     }
  52   }
  53 }
  54
  55 class Swarm extends SCPattern {
  56
  57   SawLFO offset = new SawLFO(0, 1, 1000);
  58   SinLFO rate = new SinLFO(350, 1200, 63000);
  59   SinLFO falloff = new SinLFO(15, 50, 17000);
  60   SinLFO fX = new SinLFO(0, model.xMax, 19000);
  61   SinLFO fY = new SinLFO(0, model.yMax, 11000);
  62   SinLFO hOffX = new SinLFO(0, model.xMax, 13000);
  63
  64   public Swarm(GLucose glucose) {
  65     super(glucose);
  66
  67     addModulator(offset).trigger();
  68     addModulator(rate).trigger();
  69     addModulator(falloff).trigger();
  70     addModulator(fX).trigger();
  71     addModulator(fY).trigger();
  72     addModulator(hOffX).trigger();
  73     offset.modulateDurationBy(rate);
  74   }
  75
  76   float modDist(float v1, float v2, float mod) {
  77     v1 = v1 % mod;
  78     v2 = v2 % mod;
  79     if (v2 > v1) {
  80       return min(v2-v1, v1+mod-v2);
  81     }
  82     else {
  83       return min(v1-v2, v2+mod-v1);
  84     }
  85   }
  86
  87   void run(int deltaMs) {
  88     float s = 0;
  89     for (Strip strip : model.strips  ) {
  90       int i = 0;
  91       for (Point p : strip.points) {
  92         float fV = max(-1, 1 - dist(p.fx/2., p.fy, fX.getValuef()/2., fY.getValuef()) / 64.);
  93         colors[p.index] = color(
  94         (lx.getBaseHuef() + 0.3 * abs(p.fx - hOffX.getValuef())) % 360,
  95         constrain(80 + 40 * fV, 0, 100),
  96         constrain(100 - (30 - fV * falloff.getValuef()) * modDist(i + (s*63)%61, (int) (offset.getValuef() * strip.metrics.numPoints), strip.metrics.numPoints), 0, 100)
  97           );
  98         ++i;
  99       }
 100       ++s;
 101     }
 102   }
 103 }
 104
 105 class SwipeTransition extends SCTransition {
 106
 107   final BasicParameter bleed = new BasicParameter("WIDTH", 0.5);
 108
 109   SwipeTransition(GLucose glucose) {
 110     super(glucose);
 111     setDuration(5000);
 112     addParameter(bleed);
 113   }
 114
 115   void computeBlend(int[] c1, int[] c2, double progress) {
 116     float bleedf = 10 + bleed.getValuef() * 200.;
 117     float xPos = (float) (-bleedf + progress * (model.xMax + bleedf));
 118     for (Point p : model.points) {
 119       float d = (p.fx - xPos) / bleedf;
 120       if (d < 0) {
 121         colors[p.index] = c2[p.index];
 122       } else if (d > 1) {
 123         colors[p.index] = c1[p.index];
 124       } else {
 125         colors[p.index] = lerpColor(c2[p.index], c1[p.index], d, RGB);
 126       }
 127     }
 128   }
 129 }
 130
 131 class CubeEQ extends SCPattern {
 132
 133   private FFT fft = null;
 134   private LinearEnvelope[] bandVals = null;
 135   private int avgSize;
 136
 137   private final BasicParameter thrsh = new BasicParameter("LVL", 0.35);
 138   private final BasicParameter range = new BasicParameter("RANG", 0.45);
 139   private final BasicParameter edge = new BasicParameter("EDGE", 0.5);
 140   private final BasicParameter speed = new BasicParameter("SPD", 0.5);
 141   private final BasicParameter tone = new BasicParameter("TONE", 0.5);
 142   private final BasicParameter clr = new BasicParameter("CLR", 0.5);
 143
 144   public CubeEQ(GLucose glucose) {
 145     super(glucose);
 146     addParameter(thrsh);
 147     addParameter(range);
 148     addParameter(edge);
 149     addParameter(speed);
 150     addParameter(tone);
 151     addParameter(clr);
 152   }
 153
 154   protected void onActive() {
 155     if (this.fft == null) {
 156       this.fft = new FFT(lx.audioInput().bufferSize(), lx.audioInput().sampleRate());
 157       this.fft.window(FFT.HAMMING);
 158       this.fft.logAverages(40, 1);
 159       this.avgSize = this.fft.avgSize();
 160       this.bandVals = new LinearEnvelope[this.avgSize];
 161       for (int i = 0; i < this.bandVals.length; ++i) {
 162         this.addModulator(this.bandVals[i] = (new LinearEnvelope(0, 0, 700+i*4))).trigger();
 163       }
 164     }
 165   }
 166
 167   public void run(int deltaMs) {
 168     this.fft.forward(this.lx.audioInput().mix);
 169     float toneConst = .35 + .4 * (tone.getValuef() - 0.5);
 170     float edgeConst = 2 + 30*(edge.getValuef()*edge.getValuef()*edge.getValuef());
 171
 172     for (int i = 0; i < avgSize; ++i) {
 173       float value = this.fft.getAvg(i);
 174       value = 20*log(1 + sqrt(value));
 175       float sqdist = avgSize - i;
 176       value -= toneConst*sqdist*sqdist + .5*sqdist;
 177       value *= 6;
 178       if (value > this.bandVals[i].getValue()) {
 179         this.bandVals[i].setEndVal(value, 40).trigger();
 180       }
 181       else {
 182         this.bandVals[i].setEndVal(value, 1000 - 900*speed.getValuef()).trigger();
 183       }
 184     }
 185
 186     float jBase = 120 - 360*thrsh.getValuef();
 187     float jConst = 300.*(1-range.getValuef());
 188     float clrConst = 1.1 + clr.getValuef();
 189
 190     for (Point p : model.points) {
 191       float avgIndex = constrain((p.fx / model.xMax * avgSize), 0, avgSize-2);
 192       int avgFloor = (int) avgIndex;
 193       float j = jBase + jConst * (p.fy / model.yMax);
 194       float value = lerp(
 195       this.bandVals[avgFloor].getValuef(),
 196       this.bandVals[avgFloor+1].getValuef(),
 197       avgIndex-avgFloor
 198         );
 199
 200       float b = constrain(edgeConst * (value - j), 0, 100);
 201       colors[p.index] = color(
 202       (480 + lx.getBaseHuef() - min(clrConst*p.fy, 120)) % 360,
 203       100,
 204       b);
 205     }
 206   }
 207 }
 208
 209 class BoomEffect extends SCEffect {
 210
 211   final BasicParameter falloff = new BasicParameter("WIDTH", 0.5);
 212   final BasicParameter speed = new BasicParameter("SPD", 0.5);
 213   final BasicParameter bright = new BasicParameter("BRT", 1.0);
 214   final BasicParameter sat = new BasicParameter("SAT", 0.2);
 215   List<Layer> layers = new ArrayList<Layer>();
 216   final float maxr = sqrt(model.xMax*model.xMax + model.yMax*model.yMax + model.zMax*model.zMax) + 10;
 217
 218   class Layer {
 219     LinearEnvelope boom = new LinearEnvelope(-40, 500, 1300);
 220
 221     Layer() {
 222       addModulator(boom);
 223       trigger();
 224     }
 225
 226     void trigger() {
 227       float falloffv = falloffv();
 228       boom.setRange(-100 / falloffv, maxr + 100/falloffv, 4000 - speed.getValuef() * 3300);
 229       boom.trigger();
 230     }
 231
 232     void doApply(int[] colors) {
 233       float brightv = 100 * bright.getValuef();
 234       float falloffv = falloffv();
 235       float satv = sat.getValuef() * 100;
 236       float huev = lx.getBaseHuef();
 237       for (Point p : model.points) {
 238         colors[p.index] = blendColor(
 239         colors[p.index],
 240         color(huev, satv, constrain(brightv - falloffv*abs(boom.getValuef() - dist(p.fx, 2*p.fy, 3*p.fz, model.xMax/2, model.yMax, model.zMax*1.5)), 0, 100)),
 241         ADD);
 242       }
 243     }
 244   }
 245
 246   BoomEffect(GLucose glucose) {
 247     super(glucose, true);
 248     addParameter(falloff);
 249     addParameter(speed);
 250     addParameter(bright);
 251     addParameter(sat);
 252   }
 253
 254   public void onEnable() {
 255     for (Layer l : layers) {
 256       if (!l.boom.isRunning()) {
 257         l.trigger();
 258         return;
 259       }
 260     }
 261     layers.add(new Layer());
 262   }
 263
 264   private float falloffv() {
 265     return 20 - 19 * falloff.getValuef();
 266   }
 267
 268   public void onTrigger() {
 269     onEnable();
 270   }
 271
 272   public void doApply(int[] colors) {
 273     for (Layer l : layers) {
 274       if (l.boom.isRunning()) {
 275         l.doApply(colors);
 276       }
 277     }
 278   }
 279 }
 280
 281 public class PianoKeyPattern extends SCPattern {
 282
 283   final LinearEnvelope[] cubeBrt;
 284   final SinLFO base[];
 285   final BasicParameter attack = new BasicParameter("ATK", 0.1);
 286   final BasicParameter release = new BasicParameter("REL", 0.5);
 287   final BasicParameter level = new BasicParameter("AMB", 0.6);
 288
 289   PianoKeyPattern(GLucose glucose) {
 290     super(glucose);
 291
 292     for (MidiInputDevice input : RWMidi.getInputDevices()) {
 293       input.createInput(this);
 294     }
 295
 296     addParameter(attack);
 297     addParameter(release);
 298     addParameter(level);
 299     cubeBrt = new LinearEnvelope[model.cubes.size() / 4];
 300     for (int i = 0; i < cubeBrt.length; ++i) {
 301       addModulator(cubeBrt[i] = new LinearEnvelope(0, 0, 100));
 302     }
 303     base = new SinLFO[model.cubes.size() / 12];
 304     for (int i = 0; i < base.length; ++i) {
 305       addModulator(base[i] = new SinLFO(0, 1, 7000 + 1000*i)).trigger();
 306     }
 307   }
 308
 309   private float getAttackTime() {
 310     return 15 + attack.getValuef()*attack.getValuef() * 2000;
 311   }
 312
 313   private float getReleaseTime() {
 314     return 15 + release.getValuef() * 3000;
 315   }
 316
 317   private LinearEnvelope getEnvelope(int index) {
 318     return cubeBrt[index % cubeBrt.length];
 319   }
 320
 321   private SinLFO getBase(int index) {
 322     return base[index % base.length];
 323   }
 324
 325   public void noteOnReceived(Note note) {
 326     LinearEnvelope env = getEnvelope(note.getPitch());
 327     env.setEndVal(min(1, env.getValuef() + (note.getVelocity() / 127.)), getAttackTime()).start();
 328   }
 329
 330   public void noteOffReceived(Note note) {
 331     getEnvelope(note.getPitch()).setEndVal(0, getReleaseTime()).start();
 332   }
 333
 334   public void run(int deltaMs) {
 335     int i = 0;
 336     float huef = lx.getBaseHuef();
 337     float levelf = level.getValuef();
 338     for (Cube c : model.cubes) {
 339       float v = max(getBase(i).getValuef() * levelf/4., getEnvelope(i++).getValuef());
 340       setColor(c, color(
 341         (huef + 20*v + abs(c.cx-model.xMax/2.)*.3 + c.cy) % 360,
 342         min(100, 120*v),
 343         100*v
 344       ));
 345     }
 346   }
 347 }
 348
 349 class CrossSections extends SCPattern {
 350
 351   final SinLFO x = new SinLFO(0, model.xMax, 5000);
 352   final SinLFO y = new SinLFO(0, model.yMax, 6000);
 353   final SinLFO z = new SinLFO(0, model.zMax, 7000);
 354
 355   final BasicParameter xw = new BasicParameter("XWID", 0.3);
 356   final BasicParameter yw = new BasicParameter("YWID", 0.3);
 357   final BasicParameter zw = new BasicParameter("ZWID", 0.3);
 358   final BasicParameter xr = new BasicParameter("XRAT", 0.7);
 359   final BasicParameter yr = new BasicParameter("YRAT", 0.6);
 360   final BasicParameter zr = new BasicParameter("ZRAT", 0.5);
 361   final BasicParameter xl = new BasicParameter("XLEV", 1);
 362   final BasicParameter yl = new BasicParameter("YLEV", 1);
 363   final BasicParameter zl = new BasicParameter("ZLEV", 0.5);
 364
 365
 366   CrossSections(GLucose glucose) {
 367     super(glucose);
 368     addModulator(x).trigger();
 369     addModulator(y).trigger();
 370     addModulator(z).trigger();
 371     addParameter(xr);
 372     addParameter(yr);
 373     addParameter(zr);
 374     addParameter(xw);
 375     addParameter(xl);
 376     addParameter(yl);
 377     addParameter(zl);
 378     addParameter(yw);
 379     addParameter(zw);
 380   }
 381
 382   void onParameterChanged(LXParameter p) {
 383     if (p == xr) {
 384       x.setDuration(10000 - 8800*p.getValuef());
 385     } else if (p == yr) {
 386       y.setDuration(10000 - 9000*p.getValuef());
 387     } else if (p == zr) {
 388       z.setDuration(10000 - 9000*p.getValuef());
 389     }
 390   }
 391
 392   public void run(int deltaMs) {
 393     float xv = x.getValuef();
 394     float yv = y.getValuef();
 395     float zv = z.getValuef();
 396     float xlv = 100*xl.getValuef();
 397     float ylv = 100*yl.getValuef();
 398     float zlv = 100*zl.getValuef();
 399
 400     float xwv = 100. / (10 + 40*xw.getValuef());
 401     float ywv = 100. / (10 + 40*yw.getValuef());
 402     float zwv = 100. / (10 + 40*zw.getValuef());
 403
 404     for (Point p : model.points) {
 405       color c = 0;
 406       c = blendColor(c, color(
 407       (lx.getBaseHuef() + p.fx/10 + p.fy/3) % 360,
 408       constrain(140 - 1.1*abs(p.fx - model.xMax/2.), 0, 100),
 409       max(0, xlv - xwv*abs(p.fx - xv))
 410         ), ADD);
 411       c = blendColor(c, color(
 412       (lx.getBaseHuef() + 80 + p.fy/10) % 360,
 413       constrain(140 - 2.2*abs(p.fy - model.yMax/2.), 0, 100),
 414       max(0, ylv - ywv*abs(p.fy - yv))
 415         ), ADD);
 416       c = blendColor(c, color(
 417       (lx.getBaseHuef() + 160 + p.fz / 10 + p.fy/2) % 360,
 418       constrain(140 - 2.2*abs(p.fz - model.zMax/2.), 0, 100),
 419       max(0, zlv - zwv*abs(p.fz - zv))
 420         ), ADD);
 421       colors[p.index] = c;
 422     }
 423   }
 424 }
 425
 426 class Blinders extends SCPattern {
 427
 428   final SinLFO[] m;
 429   final TriangleLFO r;
 430   final SinLFO s;
 431   final TriangleLFO hs;
 432
 433   public Blinders(GLucose glucose) {
 434     super(glucose);
 435     m = new SinLFO[12];
 436     for (int i = 0; i < m.length; ++i) {
 437       addModulator(m[i] = new SinLFO(0.5, 120, (120000. / (3+i)))).trigger();
 438     }
 439     addModulator(r = new TriangleLFO(9000, 15000, 29000)).trigger();
 440     addModulator(s = new SinLFO(-20, 275, 11000)).trigger();
 441     addModulator(hs = new TriangleLFO(0.1, 0.5, 15000)).trigger();
 442     s.modulateDurationBy(r);
 443   }
 444
 445   public void run(int deltaMs) {
 446     float hv = lx.getBaseHuef();
 447     int si = 0;
 448     for (Strip strip : model.strips) {
 449       int i = 0;
 450       float mv = m[si % m.length].getValuef();
 451       for (Point p : strip.points) {
 452         colors[p.index] = color(
 453           (hv + p.fz + p.fy*hs.getValuef()) % 360,
 454           min(100, abs(p.fx - s.getValuef())/2.),
 455           max(0, 100 - mv/2. - mv * abs(i - 7.5))
 456         );
 457         ++i;
 458       }
 459       ++si;
 460     }
 461   }
 462 }
 463
 464 class Psychedelia extends SCPattern {
 465
 466   final int NUM = 3;
 467   SinLFO m = new SinLFO(-0.5, NUM-0.5, 9000);
 468   SinLFO s = new SinLFO(-20, 147, 11000);
 469   TriangleLFO h = new TriangleLFO(0, 240, 19000);
 470   SinLFO c = new SinLFO(-.2, .8, 31000);
 471
 472   Psychedelia(GLucose glucose) {
 473     super(glucose);
 474     addModulator(m).trigger();
 475     addModulator(s).trigger();
 476     addModulator(h).trigger();
 477     addModulator(c).trigger();
 478   }
 479
 480   void run(int deltaMs) {
 481     float huev = h.getValuef();
 482     float cv = c.getValuef();
 483     float sv = s.getValuef();
 484     float mv = m.getValuef();
 485     int i = 0;
 486     for (Strip strip : model.strips) {
 487       for (Point p : strip.points) {
 488         colors[p.index] = color(
 489           (huev + i*constrain(cv, 0, 2) + p.fz/2. + p.fx/4.) % 360,
 490           min(100, abs(p.fy-sv)),
 491           max(0, 100 - 50*abs((i%NUM) - mv))
 492         );
 493       }
 494       ++i;
 495     }
 496   }
 497 }
 498
 499 class AskewPlanes extends SCPattern {
 500
 501   class Plane {
 502     private final SinLFO a;
 503     private final SinLFO b;
 504     private final SinLFO c;
 505     float av = 1;
 506     float bv = 1;
 507     float cv = 1;
 508     float denom = 0.1;
 509
 510     Plane(int i) {
 511       addModulator(a = new SinLFO(-1, 1, 4000 + 1029*i)).trigger();
 512       addModulator(b = new SinLFO(-1, 1, 11000 - 1104*i)).trigger();
 513       addModulator(c = new SinLFO(-50, 50, 4000 + 1000*i * ((i % 2 == 0) ? 1 : -1))).trigger();
 514     }
 515
 516     void run(int deltaMs) {
 517       av = a.getValuef();
 518       bv = b.getValuef();
 519       cv = c.getValuef();
 520       denom = sqrt(av*av + bv*bv);
 521     }
 522   }
 523
 524   final Plane[] planes;
 525   final int NUM_PLANES = 3;
 526
 527   AskewPlanes(GLucose glucose) {
 528     super(glucose);
 529     planes = new Plane[NUM_PLANES];
 530     for (int i = 0; i < planes.length; ++i) {
 531       planes[i] = new Plane(i);
 532     }
 533   }
 534
 535   public void run(int deltaMs) {
 536     float huev = lx.getBaseHuef();
 537
 538     // This is super fucking bizarre. But if this is a for loop, the framerate
 539     // tanks to like 30FPS, instead of 60. Call them manually and it works fine.
 540     // Doesn't make ANY sense... there must be some weird side effect going on
 541     // with the Processing internals perhaps?
 542 //    for (Plane plane : planes) {
 543 //      plane.run(deltaMs);
 544 //    }
 545     planes[0].run(deltaMs);
 546     planes[1].run(deltaMs);
 547     planes[2].run(deltaMs);
 548
 549     for (Point p : model.points) {
 550       float d = MAX_FLOAT;
 551       for (Plane plane : planes) {
 552         if (plane.denom != 0) {
 553           d = min(d, abs(plane.av*(p.fx-model.cx) + plane.bv*(p.fy-model.cy) + plane.cv) / plane.denom);
 554         }
 555       }
 556       colors[p.index] = color(
 557         (huev + abs(p.fx-model.cx)*.3 + p.fy*.8) % 360,
 558         max(0, 100 - .8*abs(p.fx - model.cx)),
 559         constrain(140 - 10.*d, 0, 100)
 560       );
 561     }
 562   }
 563 }
 564
 565 class ShiftingPlane extends SCPattern {
 566
 567   final SinLFO a = new SinLFO(-.2, .2, 5300);
 568   final SinLFO b = new SinLFO(1, -1, 13300);
 569   final SinLFO c = new SinLFO(-1.4, 1.4, 5700);
 570   final SinLFO d = new SinLFO(-10, 10, 9500);
 571
 572   ShiftingPlane(GLucose glucose) {
 573     super(glucose);
 574     addModulator(a).trigger();
 575     addModulator(b).trigger();
 576     addModulator(c).trigger();
 577     addModulator(d).trigger();
 578   }
 579
 580   public void run(int deltaMs) {
 581     float hv = lx.getBaseHuef();
 582     float av = a.getValuef();
 583     float bv = b.getValuef();
 584     float cv = c.getValuef();
 585     float dv = d.getValuef();
 586     float denom = sqrt(av*av + bv*bv + cv*cv);
 587     for (Point p : model.points) {
 588       float d = abs(av*(p.fx-model.cx) + bv*(p.fy-model.cy) + cv*(p.fz-model.cz) + dv) / denom;
 589       colors[p.index] = color(
 590         (hv + abs(p.fx-model.cx)*.6 + abs(p.fy-model.cy)*.9 + abs(p.fz - model.cz)) % 360,
 591         constrain(110 - d*6, 0, 100),
 592         constrain(130 - 7*d, 0, 100)
 593       );
 594     }
 595   }
 596 }
 597