MarkSlee.pde

   1 class SpaceTime extends SCPattern {
   2
   3   SinLFO pos = new SinLFO(0, 1, 3000);
   4   SinLFO rate = new SinLFO(1000, 9000, 13000);
   5   SinLFO falloff = new SinLFO(10, 70, 5000);
   6   float angle = 0;
   7
   8   BasicParameter rateParameter = new BasicParameter("RATE", 0.5);
   9   BasicParameter sizeParameter = new BasicParameter("SIZE", 0.5);
  10
  11
  12   public SpaceTime(GLucose glucose) {
  13     super(glucose);
  14
  15     addModulator(pos).trigger();
  16     addModulator(rate).trigger();
  17     addModulator(falloff).trigger();
  18     pos.modulateDurationBy(rate);
  19     addParameter(rateParameter);
  20     addParameter(sizeParameter);
  21   }
  22
  23   public void onParameterChanged(LXParameter parameter) {
  24     if (parameter == rateParameter) {
  25       rate.stop().setValue(9000 - 8000*parameter.getValuef());
  26     }  else if (parameter == sizeParameter) {
  27       falloff.stop().setValue(70 - 60*parameter.getValuef());
  28     }
  29   }
  30
  31   void run(int deltaMs) {
  32     angle += deltaMs * 0.0007;
  33     float sVal1 = model.strips.size() * (0.5 + 0.5*sin(angle));
  34     float sVal2 = model.strips.size() * (0.5 + 0.5*cos(angle));
  35
  36     float pVal = pos.getValuef();
  37     float fVal = falloff.getValuef();
  38
  39     int s = 0;
  40     for (Strip strip : model.strips) {
  41       int i = 0;
  42       for (Point p : strip.points) {
  43         colors[p.index] = color(
  44           (lx.getBaseHuef() + 360 - p.fx*.2 + p.fy * .3) % 360,
  45           constrain(.4 * min(abs(s - sVal1), abs(s - sVal2)), 20, 100),
  46           max(0, 100 - fVal*abs(i - pVal*(strip.metrics.numPoints - 1)))
  47         );
  48         ++i;
  49       }
  50       ++s;
  51     }
  52   }
  53 }
  54
  55 class Swarm extends SCPattern {
  56
  57   SawLFO offset = new SawLFO(0, 1, 1000);
  58   SinLFO rate = new SinLFO(350, 1200, 63000);
  59   SinLFO falloff = new SinLFO(15, 50, 17000);
  60   SinLFO fX = new SinLFO(0, model.xMax, 19000);
  61   SinLFO fY = new SinLFO(0, model.yMax, 11000);
  62   SinLFO hOffX = new SinLFO(0, model.xMax, 13000);
  63
  64   public Swarm(GLucose glucose) {
  65     super(glucose);
  66
  67     addModulator(offset).trigger();
  68     addModulator(rate).trigger();
  69     addModulator(falloff).trigger();
  70     addModulator(fX).trigger();
  71     addModulator(fY).trigger();
  72     addModulator(hOffX).trigger();
  73     offset.modulateDurationBy(rate);
  74   }
  75
  76   float modDist(float v1, float v2, float mod) {
  77     v1 = v1 % mod;
  78     v2 = v2 % mod;
  79     if (v2 > v1) {
  80       return min(v2-v1, v1+mod-v2);
  81     }
  82     else {
  83       return min(v1-v2, v2+mod-v1);
  84     }
  85   }
  86
  87   void run(int deltaMs) {
  88     float s = 0;
  89     for (Strip strip : model.strips  ) {
  90       int i = 0;
  91       for (Point p : strip.points) {
  92         float fV = max(-1, 1 - dist(p.fx/2., p.fy, fX.getValuef()/2., fY.getValuef()) / 64.);
  93         colors[p.index] = color(
  94         (lx.getBaseHuef() + 0.3 * abs(p.fx - hOffX.getValuef())) % 360,
  95         constrain(80 + 40 * fV, 0, 100),
  96         constrain(100 - (30 - fV * falloff.getValuef()) * modDist(i + (s*63)%61, (int) (offset.getValuef() * strip.metrics.numPoints), strip.metrics.numPoints), 0, 100)
  97           );
  98         ++i;
  99       }
 100       ++s;
 101     }
 102   }
 103 }
 104
 105 class SwipeTransition extends SCTransition {
 106
 107   final BasicParameter bleed = new BasicParameter("WIDTH", 0.5);
 108
 109   SwipeTransition(GLucose glucose) {
 110     super(glucose);
 111     setDuration(5000);
 112     addParameter(bleed);
 113   }
 114
 115   void computeBlend(int[] c1, int[] c2, double progress) {
 116     float bleedf = 10 + bleed.getValuef() * 200.;
 117     float xPos = (float) (-bleedf + progress * (model.xMax + bleedf));
 118     for (Point p : model.points) {
 119       float d = (p.fx - xPos) / bleedf;
 120       if (d < 0) {
 121         colors[p.index] = c2[p.index];
 122       } else if (d > 1) {
 123         colors[p.index] = c1[p.index];
 124       } else {
 125         colors[p.index] = lerpColor(c2[p.index], c1[p.index], d, RGB);
 126       }
 127     }
 128   }
 129 }
 130
 131 abstract class BlendTransition extends SCTransition {
 132
 133   final int blendType;
 134
 135   BlendTransition(GLucose glucose, int blendType) {
 136     super(glucose);
 137     this.blendType = blendType;
 138   }
 139
 140   void computeBlend(int[] c1, int[] c2, double progress) {
 141     if (progress < 0.5) {
 142       for (int i = 0; i < c1.length; ++i) {
 143         colors[i] = lerpColor(
 144           c1[i],
 145           blendColor(c1[i], c2[i], blendType),
 146           (float) (2.*progress),
 147           RGB);
 148       }
 149     } else {
 150       for (int i = 0; i < c1.length; ++i) {
 151         colors[i] = lerpColor(
 152           c2[i],
 153           blendColor(c1[i], c2[i], blendType),
 154           (float) (2.*(1. - progress)),
 155           RGB);
 156       }
 157     }
 158   }
 159 }
 160
 161 class MultiplyTransition extends BlendTransition {
 162   MultiplyTransition(GLucose glucose) {
 163     super(glucose, MULTIPLY);
 164   }
 165 }
 166
 167 class ScreenTransition extends BlendTransition {
 168   ScreenTransition(GLucose glucose) {
 169     super(glucose, SCREEN);
 170   }
 171 }
 172
 173 class BurnTransition extends BlendTransition {
 174   BurnTransition(GLucose glucose) {
 175     super(glucose, BURN);
 176   }
 177 }
 178
 179 class DodgeTransition extends BlendTransition {
 180   DodgeTransition(GLucose glucose) {
 181     super(glucose, DODGE);
 182   }
 183 }
 184
 185 class OverlayTransition extends BlendTransition {
 186   OverlayTransition(GLucose glucose) {
 187     super(glucose, OVERLAY);
 188   }
 189 }
 190
 191 class AddTransition extends BlendTransition {
 192   AddTransition(GLucose glucose) {
 193     super(glucose, ADD);
 194   }
 195 }
 196
 197 class SubtractTransition extends BlendTransition {
 198   SubtractTransition(GLucose glucose) {
 199     super(glucose, SUBTRACT);
 200   }
 201 }
 202
 203 class SoftLightTransition extends BlendTransition {
 204   SoftLightTransition(GLucose glucose) {
 205     super(glucose, SOFT_LIGHT);
 206   }
 207 }
 208
 209 class BassPod extends SCPattern {
 210
 211   private GraphicEQ eq = null;
 212
 213   public BassPod(GLucose glucose) {
 214     super(glucose);
 215   }
 216
 217   protected void onActive() {
 218     if (eq == null) {
 219       eq = new GraphicEQ(lx, 16);
 220       eq.slope.setValue(0.6);
 221       addParameter(eq.level);
 222       addParameter(eq.range);
 223       addParameter(eq.attack);
 224       addParameter(eq.release);
 225       addParameter(eq.slope);
 226     }
 227   }
 228
 229   public void run(int deltaMs) {
 230     eq.run(deltaMs);
 231
 232     float bassLevel = eq.getAverageLevel(0, 5);
 233
 234     for (Point p : model.points) {
 235       int avgIndex = (int) constrain(1 + abs(p.fx-model.xMax/2.)/(model.xMax/2.)*(eq.numBands-5), 0, eq.numBands-5);
 236       float value = 0;
 237       for (int i = avgIndex; i < avgIndex + 5; ++i) {
 238         value += eq.getLevel(i);
 239       }
 240       value /= 5.;
 241
 242       float b = constrain(8 * (value*model.yMax - abs(p.fy-model.yMax/2.)), 0, 100);
 243       colors[p.index] = color(
 244         (lx.getBaseHuef() + abs(p.fy - model.cy) + abs(p.fx - model.cx)) % 360,
 245         constrain(bassLevel*240 - .6*dist(p.fx, p.fy, model.cx, model.cy), 0, 100),
 246         b
 247       );
 248     }
 249   }
 250 }
 251
 252
 253 class CubeEQ extends SCPattern {
 254
 255   private GraphicEQ eq = null;
 256
 257   private final BasicParameter edge = new BasicParameter("EDGE", 0.5);
 258   private final BasicParameter clr = new BasicParameter("CLR", 0.5);
 259   private final BasicParameter blockiness = new BasicParameter("BLK", 0.5);
 260
 261   public CubeEQ(GLucose glucose) {
 262     super(glucose);
 263   }
 264
 265   protected void onActive() {
 266     if (eq == null) {
 267       eq = new GraphicEQ(lx, 16);
 268       addParameter(eq.level);
 269       addParameter(eq.range);
 270       addParameter(eq.attack);
 271       addParameter(eq.release);
 272       addParameter(eq.slope);
 273       addParameter(edge);
 274       addParameter(clr);
 275       addParameter(blockiness);
 276     }
 277   }
 278
 279   public void run(int deltaMs) {
 280     eq.run(deltaMs);
 281
 282     float edgeConst = 2 + 30*edge.getValuef();
 283     float clrConst = 1.1 + clr.getValuef();
 284
 285     for (Point p : model.points) {
 286       float avgIndex = constrain(2 + p.fx / model.xMax * (eq.numBands-4), 0, eq.numBands-4);
 287       int avgFloor = (int) avgIndex;
 288
 289       float leftVal = eq.getLevel(avgFloor);
 290       float rightVal = eq.getLevel(avgFloor+1);
 291       float smoothValue = lerp(leftVal, rightVal, avgIndex-avgFloor);
 292
 293       float chunkyValue = (
 294         eq.getLevel(avgFloor/4*4) +
 295         eq.getLevel(avgFloor/4*4 + 1) +
 296         eq.getLevel(avgFloor/4*4 + 2) +
 297         eq.getLevel(avgFloor/4*4 + 3)
 298       ) / 4.;
 299
 300       float value = lerp(smoothValue, chunkyValue, blockiness.getValuef());
 301
 302       float b = constrain(edgeConst * (value*model.yMax - p.fy), 0, 100);
 303       colors[p.index] = color(
 304         (480 + lx.getBaseHuef() - min(clrConst*p.fy, 120)) % 360,
 305         100,
 306         b
 307       );
 308     }
 309   }
 310 }
 311
 312 class BoomEffect extends SCEffect {
 313
 314   final BasicParameter falloff = new BasicParameter("WIDTH", 0.5);
 315   final BasicParameter speed = new BasicParameter("SPD", 0.5);
 316   final BasicParameter bright = new BasicParameter("BRT", 1.0);
 317   final BasicParameter sat = new BasicParameter("SAT", 0.2);
 318   List<Layer> layers = new ArrayList<Layer>();
 319   final float maxr = sqrt(model.xMax*model.xMax + model.yMax*model.yMax + model.zMax*model.zMax) + 10;
 320
 321   class Layer {
 322     LinearEnvelope boom = new LinearEnvelope(-40, 500, 1300);
 323
 324     Layer() {
 325       addModulator(boom);
 326       trigger();
 327     }
 328
 329     void trigger() {
 330       float falloffv = falloffv();
 331       boom.setRange(-100 / falloffv, maxr + 100/falloffv, 4000 - speed.getValuef() * 3300);
 332       boom.trigger();
 333     }
 334
 335     void doApply(int[] colors) {
 336       float brightv = 100 * bright.getValuef();
 337       float falloffv = falloffv();
 338       float satv = sat.getValuef() * 100;
 339       float huev = lx.getBaseHuef();
 340       for (Point p : model.points) {
 341         colors[p.index] = blendColor(
 342         colors[p.index],
 343         color(huev, satv, constrain(brightv - falloffv*abs(boom.getValuef() - dist(p.fx, 2*p.fy, 3*p.fz, model.xMax/2, model.yMax, model.zMax*1.5)), 0, 100)),
 344         ADD);
 345       }
 346     }
 347   }
 348
 349   BoomEffect(GLucose glucose) {
 350     super(glucose, true);
 351     addParameter(falloff);
 352     addParameter(speed);
 353     addParameter(bright);
 354     addParameter(sat);
 355   }
 356
 357   public void onEnable() {
 358     for (Layer l : layers) {
 359       if (!l.boom.isRunning()) {
 360         l.trigger();
 361         return;
 362       }
 363     }
 364     layers.add(new Layer());
 365   }
 366
 367   private float falloffv() {
 368     return 20 - 19 * falloff.getValuef();
 369   }
 370
 371   public void onTrigger() {
 372     onEnable();
 373   }
 374
 375   public void doApply(int[] colors) {
 376     for (Layer l : layers) {
 377       if (l.boom.isRunning()) {
 378         l.doApply(colors);
 379       }
 380     }
 381   }
 382 }
 383
 384 public class PianoKeyPattern extends SCPattern {
 385
 386   final LinearEnvelope[] cubeBrt;
 387   final SinLFO base[];
 388   final BasicParameter attack = new BasicParameter("ATK", 0.1);
 389   final BasicParameter release = new BasicParameter("REL", 0.5);
 390   final BasicParameter level = new BasicParameter("AMB", 0.6);
 391
 392   PianoKeyPattern(GLucose glucose) {
 393     super(glucose);
 394
 395     for (MidiInputDevice input : RWMidi.getInputDevices()) {
 396       input.createInput(this);
 397     }
 398
 399     addParameter(attack);
 400     addParameter(release);
 401     addParameter(level);
 402     cubeBrt = new LinearEnvelope[model.cubes.size() / 4];
 403     for (int i = 0; i < cubeBrt.length; ++i) {
 404       addModulator(cubeBrt[i] = new LinearEnvelope(0, 0, 100));
 405     }
 406     base = new SinLFO[model.cubes.size() / 12];
 407     for (int i = 0; i < base.length; ++i) {
 408       addModulator(base[i] = new SinLFO(0, 1, 7000 + 1000*i)).trigger();
 409     }
 410   }
 411
 412   private float getAttackTime() {
 413     return 15 + attack.getValuef()*attack.getValuef() * 2000;
 414   }
 415
 416   private float getReleaseTime() {
 417     return 15 + release.getValuef() * 3000;
 418   }
 419
 420   private LinearEnvelope getEnvelope(int index) {
 421     return cubeBrt[index % cubeBrt.length];
 422   }
 423
 424   private SinLFO getBase(int index) {
 425     return base[index % base.length];
 426   }
 427
 428   public void noteOnReceived(Note note) {
 429     LinearEnvelope env = getEnvelope(note.getPitch());
 430     env.setEndVal(min(1, env.getValuef() + (note.getVelocity() / 127.)), getAttackTime()).start();
 431   }
 432
 433   public void noteOffReceived(Note note) {
 434     getEnvelope(note.getPitch()).setEndVal(0, getReleaseTime()).start();
 435   }
 436
 437   public void run(int deltaMs) {
 438     int i = 0;
 439     float huef = lx.getBaseHuef();
 440     float levelf = level.getValuef();
 441     for (Cube c : model.cubes) {
 442       float v = max(getBase(i).getValuef() * levelf/4., getEnvelope(i++).getValuef());
 443       setColor(c, color(
 444         (huef + 20*v + abs(c.cx-model.xMax/2.)*.3 + c.cy) % 360,
 445         min(100, 120*v),
 446         100*v
 447       ));
 448     }
 449   }
 450 }
 451
 452 class CrossSections extends SCPattern {
 453
 454   final SinLFO x = new SinLFO(0, model.xMax, 5000);
 455   final SinLFO y = new SinLFO(0, model.yMax, 6000);
 456   final SinLFO z = new SinLFO(0, model.zMax, 7000);
 457
 458   final BasicParameter xw = new BasicParameter("XWID", 0.3);
 459   final BasicParameter yw = new BasicParameter("YWID", 0.3);
 460   final BasicParameter zw = new BasicParameter("ZWID", 0.3);
 461   final BasicParameter xr = new BasicParameter("XRAT", 0.7);
 462   final BasicParameter yr = new BasicParameter("YRAT", 0.6);
 463   final BasicParameter zr = new BasicParameter("ZRAT", 0.5);
 464   final BasicParameter xl = new BasicParameter("XLEV", 1);
 465   final BasicParameter yl = new BasicParameter("YLEV", 1);
 466   final BasicParameter zl = new BasicParameter("ZLEV", 0.5);
 467
 468
 469   CrossSections(GLucose glucose) {
 470     super(glucose);
 471     addModulator(x).trigger();
 472     addModulator(y).trigger();
 473     addModulator(z).trigger();
 474     addParams();
 475   }
 476
 477   protected void addParams() {
 478     addParameter(xr);
 479     addParameter(yr);
 480     addParameter(zr);
 481     addParameter(xw);
 482     addParameter(xl);
 483     addParameter(yl);
 484     addParameter(zl);
 485     addParameter(yw);
 486     addParameter(zw);
 487   }
 488
 489   void onParameterChanged(LXParameter p) {
 490     if (p == xr) {
 491       x.setDuration(10000 - 8800*p.getValuef());
 492     } else if (p == yr) {
 493       y.setDuration(10000 - 9000*p.getValuef());
 494     } else if (p == zr) {
 495       z.setDuration(10000 - 9000*p.getValuef());
 496     }
 497   }
 498
 499   float xv, yv, zv;
 500
 501   protected void updateXYZVals() {
 502     xv = x.getValuef();
 503     yv = y.getValuef();
 504     zv = z.getValuef();
 505   }
 506
 507   public void run(int deltaMs) {
 508     updateXYZVals();
 509
 510     float xlv = 100*xl.getValuef();
 511     float ylv = 100*yl.getValuef();
 512     float zlv = 100*zl.getValuef();
 513
 514     float xwv = 100. / (10 + 40*xw.getValuef());
 515     float ywv = 100. / (10 + 40*yw.getValuef());
 516     float zwv = 100. / (10 + 40*zw.getValuef());
 517
 518     for (Point p : model.points) {
 519       color c = 0;
 520       c = blendColor(c, color(
 521       (lx.getBaseHuef() + p.fx/10 + p.fy/3) % 360,
 522       constrain(140 - 1.1*abs(p.fx - model.xMax/2.), 0, 100),
 523       max(0, xlv - xwv*abs(p.fx - xv))
 524         ), ADD);
 525       c = blendColor(c, color(
 526       (lx.getBaseHuef() + 80 + p.fy/10) % 360,
 527       constrain(140 - 2.2*abs(p.fy - model.yMax/2.), 0, 100),
 528       max(0, ylv - ywv*abs(p.fy - yv))
 529         ), ADD);
 530       c = blendColor(c, color(
 531       (lx.getBaseHuef() + 160 + p.fz / 10 + p.fy/2) % 360,
 532       constrain(140 - 2.2*abs(p.fz - model.zMax/2.), 0, 100),
 533       max(0, zlv - zwv*abs(p.fz - zv))
 534         ), ADD);
 535       colors[p.index] = c;
 536     }
 537   }
 538 }
 539
 540 class Blinders extends SCPattern {
 541
 542   final SinLFO[] m;
 543   final TriangleLFO r;
 544   final SinLFO s;
 545   final TriangleLFO hs;
 546
 547   public Blinders(GLucose glucose) {
 548     super(glucose);
 549     m = new SinLFO[12];
 550     for (int i = 0; i < m.length; ++i) {
 551       addModulator(m[i] = new SinLFO(0.5, 120, (120000. / (3+i)))).trigger();
 552     }
 553     addModulator(r = new TriangleLFO(9000, 15000, 29000)).trigger();
 554     addModulator(s = new SinLFO(-20, 275, 11000)).trigger();
 555     addModulator(hs = new TriangleLFO(0.1, 0.5, 15000)).trigger();
 556     s.modulateDurationBy(r);
 557   }
 558
 559   public void run(int deltaMs) {
 560     float hv = lx.getBaseHuef();
 561     int si = 0;
 562     for (Strip strip : model.strips) {
 563       int i = 0;
 564       float mv = m[si % m.length].getValuef();
 565       for (Point p : strip.points) {
 566         colors[p.index] = color(
 567           (hv + p.fz + p.fy*hs.getValuef()) % 360,
 568           min(100, abs(p.fx - s.getValuef())/2.),
 569           max(0, 100 - mv/2. - mv * abs(i - (strip.metrics.length-1)/2.))
 570         );
 571         ++i;
 572       }
 573       ++si;
 574     }
 575   }
 576 }
 577
 578 class Psychedelia extends SCPattern {
 579
 580   final int NUM = 3;
 581   SinLFO m = new SinLFO(-0.5, NUM-0.5, 9000);
 582   SinLFO s = new SinLFO(-20, 147, 11000);
 583   TriangleLFO h = new TriangleLFO(0, 240, 19000);
 584   SinLFO c = new SinLFO(-.2, .8, 31000);
 585
 586   Psychedelia(GLucose glucose) {
 587     super(glucose);
 588     addModulator(m).trigger();
 589     addModulator(s).trigger();
 590     addModulator(h).trigger();
 591     addModulator(c).trigger();
 592   }
 593
 594   void run(int deltaMs) {
 595     float huev = h.getValuef();
 596     float cv = c.getValuef();
 597     float sv = s.getValuef();
 598     float mv = m.getValuef();
 599     int i = 0;
 600     for (Strip strip : model.strips) {
 601       for (Point p : strip.points) {
 602         colors[p.index] = color(
 603           (huev + i*constrain(cv, 0, 2) + p.fz/2. + p.fx/4.) % 360,
 604           min(100, abs(p.fy-sv)),
 605           max(0, 100 - 50*abs((i%NUM) - mv))
 606         );
 607       }
 608       ++i;
 609     }
 610   }
 611 }
 612
 613 class AskewPlanes extends SCPattern {
 614
 615   class Plane {
 616     private final SinLFO a;
 617     private final SinLFO b;
 618     private final SinLFO c;
 619     float av = 1;
 620     float bv = 1;
 621     float cv = 1;
 622     float denom = 0.1;
 623
 624     Plane(int i) {
 625       addModulator(a = new SinLFO(-1, 1, 4000 + 1029*i)).trigger();
 626       addModulator(b = new SinLFO(-1, 1, 11000 - 1104*i)).trigger();
 627       addModulator(c = new SinLFO(-50, 50, 4000 + 1000*i * ((i % 2 == 0) ? 1 : -1))).trigger();
 628     }
 629
 630     void run(int deltaMs) {
 631       av = a.getValuef();
 632       bv = b.getValuef();
 633       cv = c.getValuef();
 634       denom = sqrt(av*av + bv*bv);
 635     }
 636   }
 637
 638   final Plane[] planes;
 639   final int NUM_PLANES = 3;
 640
 641   AskewPlanes(GLucose glucose) {
 642     super(glucose);
 643     planes = new Plane[NUM_PLANES];
 644     for (int i = 0; i < planes.length; ++i) {
 645       planes[i] = new Plane(i);
 646     }
 647   }
 648
 649   public void run(int deltaMs) {
 650     float huev = lx.getBaseHuef();
 651
 652     // This is super fucking bizarre. But if this is a for loop, the framerate
 653     // tanks to like 30FPS, instead of 60. Call them manually and it works fine.
 654     // Doesn't make ANY sense... there must be some weird side effect going on
 655     // with the Processing internals perhaps?
 656 //    for (Plane plane : planes) {
 657 //      plane.run(deltaMs);
 658 //    }
 659     planes[0].run(deltaMs);
 660     planes[1].run(deltaMs);
 661     planes[2].run(deltaMs);
 662
 663     for (Point p : model.points) {
 664       float d = MAX_FLOAT;
 665       for (Plane plane : planes) {
 666         if (plane.denom != 0) {
 667           d = min(d, abs(plane.av*(p.fx-model.cx) + plane.bv*(p.fy-model.cy) + plane.cv) / plane.denom);
 668         }
 669       }
 670       colors[p.index] = color(
 671         (huev + abs(p.fx-model.cx)*.3 + p.fy*.8) % 360,
 672         max(0, 100 - .8*abs(p.fx - model.cx)),
 673         constrain(140 - 10.*d, 0, 100)
 674       );
 675     }
 676   }
 677 }
 678
 679 class ShiftingPlane extends SCPattern {
 680
 681   final SinLFO a = new SinLFO(-.2, .2, 5300);
 682   final SinLFO b = new SinLFO(1, -1, 13300);
 683   final SinLFO c = new SinLFO(-1.4, 1.4, 5700);
 684   final SinLFO d = new SinLFO(-10, 10, 9500);
 685
 686   ShiftingPlane(GLucose glucose) {
 687     super(glucose);
 688     addModulator(a).trigger();
 689     addModulator(b).trigger();
 690     addModulator(c).trigger();
 691     addModulator(d).trigger();
 692   }
 693
 694   public void run(int deltaMs) {
 695     float hv = lx.getBaseHuef();
 696     float av = a.getValuef();
 697     float bv = b.getValuef();
 698     float cv = c.getValuef();
 699     float dv = d.getValuef();
 700     float denom = sqrt(av*av + bv*bv + cv*cv);
 701     for (Point p : model.points) {
 702       float d = abs(av*(p.fx-model.cx) + bv*(p.fy-model.cy) + cv*(p.fz-model.cz) + dv) / denom;
 703       colors[p.index] = color(
 704         (hv + abs(p.fx-model.cx)*.6 + abs(p.fy-model.cy)*.9 + abs(p.fz - model.cz)) % 360,
 705         constrain(110 - d*6, 0, 100),
 706         constrain(130 - 7*d, 0, 100)
 707       );
 708     }
 709   }
 710 }
 711
 712 class Traktor extends SCPattern {
 713
 714   final int FRAME_WIDTH = 60;
 715
 716   final BasicParameter speed = new BasicParameter("SPD", 0.5);
 717
 718   private float[] bass = new float[FRAME_WIDTH];
 719   private float[] treble = new float[FRAME_WIDTH];
 720
 721   private int index = 0;
 722   private GraphicEQ eq = null;
 723
 724   public Traktor(GLucose glucose) {
 725     super(glucose);
 726     for (int i = 0; i < FRAME_WIDTH; ++i) {
 727       bass[i] = 0;
 728       treble[i] = 0;
 729     }
 730     addParameter(speed);
 731   }
 732
 733   public void onActive() {
 734     if (eq == null) {
 735       eq = new GraphicEQ(lx, 16);
 736       eq.slope.setValue(0.6);
 737       eq.level.setValue(0.65);
 738       eq.range.setValue(0.35);
 739       eq.release.setValue(0.4);
 740       addParameter(eq.level);
 741       addParameter(eq.range);
 742       addParameter(eq.attack);
 743       addParameter(eq.release);
 744       addParameter(eq.slope);
 745     }
 746   }
 747
 748   int counter = 0;
 749
 750   public void run(int deltaMs) {
 751     eq.run(deltaMs);
 752
 753     int stepThresh = (int) (40 - 39*speed.getValuef());
 754     counter += deltaMs;
 755     if (counter < stepThresh) {
 756       return;
 757     }
 758     counter = counter % stepThresh;
 759
 760     index = (index + 1) % FRAME_WIDTH;
 761
 762     float rawBass = eq.getAverageLevel(0, 4);
 763     float rawTreble = eq.getAverageLevel(eq.numBands-7, 7);
 764
 765     bass[index] = rawBass * rawBass * rawBass * rawBass;
 766     treble[index] = rawTreble * rawTreble;
 767
 768     for (Point p : model.points) {
 769       int i = (int) constrain((model.xMax - p.x) / model.xMax * FRAME_WIDTH, 0, FRAME_WIDTH-1);
 770       int pos = (index + FRAME_WIDTH - i) % FRAME_WIDTH;
 771
 772       colors[p.index] = color(
 773         (360 + lx.getBaseHuef() + .8*abs(p.x-model.cx)) % 360,
 774         100,
 775         constrain(9 * (bass[pos]*model.cy - abs(p.fy - model.cy)), 0, 100)
 776       );
 777       colors[p.index] = blendColor(colors[p.index], color(
 778         (400 + lx.getBaseHuef() + .5*abs(p.x-model.cx)) % 360,
 779         60,
 780         constrain(5 * (treble[pos]*.6*model.cy - abs(p.fy - model.cy)), 0, 100)
 781
 782       ), ADD);
 783     }
 784   }
 785 }
 786
 787 class ColorFuckerEffect extends SCEffect {
 788
 789   BasicParameter hueShift = new BasicParameter("HSHFT", 0);
 790   BasicParameter sat = new BasicParameter("SAT", 1);
 791   BasicParameter bright = new BasicParameter("BRT", 1);
 792
 793   ColorFuckerEffect(GLucose glucose) {
 794     super(glucose);
 795     addParameter(hueShift);
 796     addParameter(bright);
 797     addParameter(sat);
 798   }
 799
 800   public void doApply(int[] colors) {
 801     if (!enabled) {
 802       return;
 803     }
 804     float bMod = bright.getValuef();
 805     float sMod = sat.getValuef();
 806     float hMod = hueShift.getValuef();
 807     if (bMod < 1 || sMod < 1 || hMod > 0) {
 808       for (int i = 0; i < colors.length; ++i) {
 809         colors[i] = color(
 810           (hue(colors[i]) + hueShift.getValuef()*360.) % 360,
 811           saturation(colors[i]) * sat.getValuef(),
 812           brightness(colors[i]) * bright.getValuef()
 813         );
 814       }
 815     }
 816   }
 817 }