TestPatterns.pde

   1 /**
   2  * Simplest demonstration of using the rotating master hue.
   3  * All pixels are full-on the same color.
   4  */
   5 class TestHuePattern extends SCPattern {
   6   public TestHuePattern(GLucose glucose) {
   7     super(glucose);
   8   }
   9
  10   public void run(int deltaMs) {
  11     // Access the core master hue via this method call
  12     float hv = lx.getBaseHuef();
  13     for (int i = 0; i < colors.length; ++i) {
  14       colors[i] = color(hv, 100, 100);
  15     }
  16   }
  17 }
  18
  19 /**
  20  * Test of a wave moving across the X axis.
  21  */
  22 class TestXPattern extends SCPattern {
  23   private final SinLFO xPos = new SinLFO(0, model.xMax, 4000);
  24   public TestXPattern(GLucose glucose) {
  25     super(glucose);
  26     addModulator(xPos).trigger();
  27   }
  28   public void run(int deltaMs) {
  29     float hv = lx.getBaseHuef();
  30     for (Point p : model.points) {
  31       // This is a common technique for modulating brightness.
  32       // You can use abs() to determine the distance between two
  33       // values. The further away this point is from an exact
  34       // point, the more we decrease its brightness
  35       float bv = max(0, 100 - abs(p.fx - xPos.getValuef()));
  36       colors[p.index] = color(hv, 100, bv);
  37     }
  38   }
  39 }
  40
  41 /**
  42  * Test of a wave on the Y axis.
  43  */
  44 class TestYPattern extends SCPattern {
  45   private final SinLFO yPos = new SinLFO(0, model.yMax, 4000);
  46   public TestYPattern(GLucose glucose) {
  47     super(glucose);
  48     addModulator(yPos).trigger();
  49   }
  50   public void run(int deltaMs) {
  51     float hv = lx.getBaseHuef();
  52     for (Point p : model.points) {
  53       float bv = max(0, 100 - abs(p.fy - yPos.getValuef()));
  54       colors[p.index] = color(hv, 100, bv);
  55     }
  56   }
  57 }
  58
  59 /**
  60  * Test of a wave on the Z axis.
  61  */
  62 class TestZPattern extends SCPattern {
  63   private final SinLFO zPos = new SinLFO(0, model.zMax, 4000);
  64   public TestZPattern(GLucose glucose) {
  65     super(glucose);
  66     addModulator(zPos).trigger();
  67   }
  68   public void run(int deltaMs) {
  69     float hv = lx.getBaseHuef();
  70     for (Point p : model.points) {
  71       float bv = max(0, 100 - abs(p.fz - zPos.getValuef()));
  72       colors[p.index] = color(hv, 100, bv);
  73     }
  74   }
  75 }
  76
  77 /**
  78  * This is a demonstration of how to use the projection library. A projection
  79  * creates a mutation of the coordinates of all the points in the model, creating
  80  * virtual x,y,z coordinates. In effect, this is like virtually rotating the entire
  81  * art car. However, since in reality the car does not move, the result is that
  82  * it appears that the object we are drawing on the car is actually moving.
  83  *
  84  * Keep in mind that what we are creating a projection of is the view coordinates.
  85  * Depending on your intuition, some operations may feel backwards. For instance,
  86  * if you translate the view to the right, it will make it seem that the object
  87  * you are drawing has moved to the left. If you scale the view up 2x, objects
  88  * drawn with the same absolute values will seem to be half the size.
  89  *
  90  * If this feels counterintuitive at first, don't worry. Just remember that you
  91  * are moving the pixels, not the structure. We're dealing with a finite set
  92  * of sparse, non-uniformly spaced pixels. Mutating the structure would move
  93  * things to a space where there are no pixels in 99% of the cases.
  94  */
  95 class TestProjectionPattern extends SCPattern {
  96
  97   private final Projection projection;
  98   private final SawLFO angle = new SawLFO(0, TWO_PI, 9000);
  99   private final SinLFO yPos = new SinLFO(-20, 40, 5000);
 100
 101   public TestProjectionPattern(GLucose glucose) {
 102     super(glucose);
 103     projection = new Projection(model);
 104     addModulator(angle).trigger();
 105     addModulator(yPos).trigger();
 106   }
 107
 108   public void run(int deltaMs) {
 109     // For the same reasons described above, it may logically feel to you that
 110     // some of these operations are in reverse order. Again, just keep in mind that
 111     // the car itself is what's moving, not the object
 112     projection.reset(model)
 113
 114       // Translate so the center of the car is the origin, offset by yPos
 115       .translateCenter(model, 0, yPos.getValuef(), 0)
 116
 117       // Rotate around the origin (now the center of the car) about an X-vector
 118       .rotate(angle.getValuef(), 1, 0, 0)
 119
 120       // Scale up the Y axis (objects will look smaller in that access)
 121       .scale(1, 1.5, 1);
 122
 123     float hv = lx.getBaseHuef();
 124     for (Coord c : projection) {
 125       float d = sqrt(c.x*c.x + c.y*c.y + c.z*c.z); // distance from origin
 126       // d = abs(d-60) + max(0, abs(c.z) - 20); // life saver / ring thing
 127       d = max(0, abs(c.y) - 10 + .3*abs(c.z) + .08*abs(c.x)); // plane / spear thing
 128       colors[c.index] = color(
 129         (hv + .6*abs(c.x) + abs(c.z)) % 360,
 130         100,
 131         constrain(140 - 10*d, 0, 100)
 132       );
 133     }
 134   }
 135 }
 136
 137 class TestCubePattern extends SCPattern {
 138
 139   private SawLFO index = new SawLFO(0, Cube.POINTS_PER_CUBE, Cube.POINTS_PER_CUBE*60);
 140
 141   TestCubePattern(GLucose glucose) {
 142     super(glucose);
 143     addModulator(index).start();
 144   }
 145
 146   public void run(int deltaMs) {
 147     for (Cube c : model.cubes) {
 148       int i = 0;
 149       for (Point p : c.points) {
 150         colors[p.index] = color(
 151           lx.getBaseHuef(),
 152           100,
 153           max(0, 100 - 80.*abs(i - index.getValuef()))
 154         );
 155         ++i;
 156       }
 157     }
 158   }
 159 }
 160
 161 class MappingTool extends SCPattern {
 162
 163   private int cubeIndex = 0;
 164   private int stripIndex = 0;
 165   private int channelIndex = 0;
 166
 167   public final int MAPPING_MODE_ALL = 0;
 168   public final int MAPPING_MODE_CHANNEL = 1;
 169   public final int MAPPING_MODE_SINGLE_CUBE = 2;
 170   public int mappingMode = MAPPING_MODE_ALL;
 171
 172   public final int CUBE_MODE_ALL = 0;
 173   public final int CUBE_MODE_SINGLE_STRIP = 1;
 174   public final int CUBE_MODE_STRIP_PATTERN = 2;
 175   public int cubeMode = CUBE_MODE_ALL;
 176
 177   public boolean channelModeRed = true;
 178   public boolean channelModeGreen = false;
 179   public boolean channelModeBlue = false;
 180
 181   private final int numChannels;
 182
 183   private final PandaMapping[] pandaMappings;
 184   private PandaMapping activeMapping;
 185   private int mappingChannelIndex;
 186
 187   MappingTool(GLucose glucose, PandaMapping[] pandaMappings) {
 188     super(glucose);
 189     this.pandaMappings = pandaMappings;
 190     int totalChannels = 0;
 191     for (PandaMapping pm : pandaMappings) {
 192        totalChannels += pm.channelList.length;
 193     }
 194     numChannels = totalChannels;
 195     setChannel();
 196   }
 197
 198   private void setChannel() {
 199     mappingChannelIndex = channelIndex;
 200     for (PandaMapping pm : pandaMappings) {
 201       if (mappingChannelIndex < pm.channelList.length) {
 202         activeMapping = pm;
 203         break;
 204       }
 205       mappingChannelIndex -= pm.channelList.length;
 206     }
 207   }
 208
 209   private int cubeInChannel(Cube c) {
 210     int i = 1;
 211     for (int index : activeMapping.channelList[mappingChannelIndex]) {
 212       if (c == model.getCubeByRawIndex(index)) {
 213         return i;
 214       }
 215       ++i;
 216     }
 217     return 0;
 218   }
 219
 220   private void printInfo() {
 221     println("Cube:" + cubeIndex + " Strip:" + (stripIndex+1));
 222   }
 223
 224   public void cube(int delta) {
 225     int len = model.cubes.size();
 226     cubeIndex = (len + cubeIndex + delta) % len;
 227     printInfo();
 228   }
 229
 230   public void strip(int delta) {
 231     int len = Cube.STRIPS_PER_CUBE;
 232     stripIndex = (len + stripIndex + delta) % len;
 233     printInfo();
 234   }
 235
 236   public void run(int deltaMs) {
 237     color off = color(0, 0, 0);
 238     color c = off;
 239     color r = #FF0000;
 240     color g = #00FF00;
 241     color b = #0000FF;
 242     if (channelModeRed) c |= r;
 243     if (channelModeGreen) c |= g;
 244     if (channelModeBlue) c |= b;
 245
 246     int ci = 0;
 247     for (Cube cube : model.cubes) {
 248       boolean cubeOn = false;
 249       int channelIndex = cubeInChannel(cube);
 250       switch (mappingMode) {
 251         case MAPPING_MODE_ALL: cubeOn = true; break;
 252         case MAPPING_MODE_SINGLE_CUBE: cubeOn = (cubeIndex == ci); break;
 253         case MAPPING_MODE_CHANNEL: cubeOn = (channelIndex > 0); break;
 254       }
 255       if (cubeOn) {
 256         if (mappingMode == MAPPING_MODE_CHANNEL) {
 257           color cc = off;
 258           switch (channelIndex) {
 259             case 1: cc = r; break;
 260             case 2: cc = r|g; break;
 261             case 3: cc = g; break;
 262             case 4: cc = b; break;
 263             case 5: cc = r|b; break;
 264           }
 265           setColor(cube, cc);
 266         } else if (cubeMode == CUBE_MODE_STRIP_PATTERN) {
 267           int si = 0;
 268           color sc = off;
 269           for (Strip strip : cube.strips) {
 270             int faceI = si / Face.STRIPS_PER_FACE;
 271             switch (faceI) {
 272               case 0: sc = r; break;
 273               case 1: sc = g; break;
 274               case 2: sc = b; break;
 275               case 3: sc = r|g|b; break;
 276             }
 277             if (si % Face.STRIPS_PER_FACE == 2) {
 278               sc = r|g;
 279             }
 280             setColor(strip, sc);
 281             ++si;
 282           }
 283         } else if (cubeMode == CUBE_MODE_SINGLE_STRIP) {
 284           setColor(cube, off);
 285           setColor(cube.strips.get(stripIndex), c);
 286         } else {
 287           setColor(cube, c);
 288         }
 289       } else {
 290         setColor(cube, off);
 291       }
 292       ++ci;
 293     }
 294
 295   }
 296
 297   public void incCube() {
 298     cubeIndex = (cubeIndex + 1) % model.cubes.size();
 299   }
 300
 301   public void decCube() {
 302     --cubeIndex;
 303     if (cubeIndex < 0) {
 304       cubeIndex += model.cubes.size();
 305     }
 306   }
 307
 308   public void incChannel() {
 309     channelIndex = (channelIndex + 1) % numChannels;
 310     setChannel();
 311   }
 312
 313   public void decChannel() {
 314     --channelIndex;
 315     if (channelIndex < 0) {
 316       channelIndex += numChannels;
 317     }
 318     setChannel();
 319   }
 320
 321   public void incStrip() {
 322     int stripsPerCube = Cube.FACES_PER_CUBE * Face.STRIPS_PER_FACE;
 323     stripIndex = (stripIndex + 1) % stripsPerCube;
 324   }
 325
 326   public void decStrip() {
 327     int stripsPerCube = Cube.FACES_PER_CUBE * Face.STRIPS_PER_FACE;
 328     --stripIndex;
 329     if (stripIndex < 0) {
 330       stripIndex += stripsPerCube;
 331     }
 332   }
 333
 334   public void keyPressed() {
 335     switch (keyCode) {
 336       case UP: if (mappingMode == MAPPING_MODE_CHANNEL) incChannel(); else incCube(); break;
 337       case DOWN: if (mappingMode == MAPPING_MODE_CHANNEL) decChannel(); else decCube(); break;
 338       case LEFT: decStrip(); break;
 339       case RIGHT: incStrip(); break;
 340     }
 341     switch (key) {
 342       case 'r': channelModeRed = !channelModeRed; break;
 343       case 'g': channelModeGreen = !channelModeGreen; break;
 344       case 'b': channelModeBlue = !channelModeBlue; break;
 345     }
 346   }
 347 }