_Internals.pde

   1 /**
   2  *     DOUBLE BLACK DIAMOND        DOUBLE BLACK DIAMOND
   3  *
   4  *         //\\   //\\                 //\\   //\\
   5  *        ///\\\ ///\\\               ///\\\ ///\\\
   6  *        \\\/// \\\///               \\\/// \\\///
   7  *         \\//   \\//                 \\//   \\//
   8  *
   9  *        EXPERTS ONLY!!              EXPERTS ONLY!!
  10  *
  11  * If you are an artist, you may ignore this file! It just sets
  12  * up the framework to run the patterns. Should not need modification
  13  * for general animation work.
  14  */
  15
  16 import glucose.*;
  17 import glucose.control.*;
  18 import glucose.effect.*;
  19 import glucose.model.*;
  20 import glucose.pattern.*;
  21 import glucose.transform.*;
  22 import glucose.transition.*;
  23 import heronarts.lx.*;
  24 import heronarts.lx.control.*;
  25 import heronarts.lx.effect.*;
  26 import heronarts.lx.modulator.*;
  27 import heronarts.lx.pattern.*;
  28 import heronarts.lx.transition.*;
  29 import ddf.minim.*;
  30 import ddf.minim.analysis.*;
  31 import processing.opengl.*;
  32 import rwmidi.*;
  33
  34 final int VIEWPORT_WIDTH = 900;
  35 final int VIEWPORT_HEIGHT = 700;
  36
  37 // The trailer is measured from the outside of the black metal (but not including the higher welded part on the front)
  38 final float TRAILER_WIDTH = 240;
  39 final float TRAILER_DEPTH = 97;
  40 final float TRAILER_HEIGHT = 33;
  41
  42 int targetFramerate = 60;
  43
  44 int startMillis, lastMillis;
  45 GLucose glucose;
  46 HeronLX lx;
  47 MappingTool mappingTool;
  48 LXPattern[] patterns;
  49 LXTransition[] transitions;
  50 LXEffect[] effects;
  51 OverlayUI ui;
  52 ControlUI controlUI;
  53 MappingUI mappingUI;
  54 PandaDriver[] pandaBoards;
  55 boolean mappingMode = false;
  56 boolean debugMode = false;
  57 DebugUI debugUI;
  58
  59 // Camera variables
  60 float eyeR, eyeA, eyeX, eyeY, eyeZ, midX, midY, midZ;
  61
  62 void setup() {
  63   startMillis = lastMillis = millis();
  64
  65   // Initialize the Processing graphics environment
  66   size(VIEWPORT_WIDTH, VIEWPORT_HEIGHT, OPENGL);
  67   frameRate(targetFramerate);
  68   noSmooth();
  69   // hint(ENABLE_OPENGL_4X_SMOOTH); // no discernable improvement?
  70   logTime("Created viewport");
  71
  72   // Create the GLucose engine to run the cubes
  73   glucose = new GLucose(this, buildModel());
  74   lx = glucose.lx;
  75   lx.enableKeyboardTempo();
  76   logTime("Built GLucose engine");
  77
  78   // Set the patterns
  79   glucose.lx.setPatterns(patterns = patterns(glucose));
  80   logTime("Built patterns");
  81   glucose.lx.addEffects(effects = effects(glucose));
  82   logTime("Built effects");
  83   glucose.setTransitions(transitions = transitions(glucose));
  84   logTime("Built transitions");
  85
  86   // Build output driver
  87   PandaMapping[] pandaMappings = buildPandaList();
  88   pandaBoards = new PandaDriver[pandaMappings.length];
  89   int pbi = 0;
  90   for (PandaMapping pm : pandaMappings) {
  91     pandaBoards[pbi++] = new PandaDriver(pm.ip, glucose.model, pm);
  92   }
  93   mappingTool = new MappingTool(glucose, pandaMappings);
  94   logTime("Built PandaDriver");
  95
  96   // Build overlay UI
  97   ui = controlUI = new ControlUI();
  98   mappingUI = new MappingUI(mappingTool);
  99   debugUI = new DebugUI(pandaMappings);
 100   logTime("Built overlay UI");
 101
 102   // MIDI devices
 103   for (MidiInputDevice d : RWMidi.getInputDevices()) {
 104     d.createInput(this);
 105   }
 106   SCMidiDevices.initializeStandardDevices(glucose);
 107   logTime("Setup MIDI devices");
 108
 109   // Setup camera
 110   midX = TRAILER_WIDTH/2. + 20;
 111   midY = glucose.model.yMax/2;
 112   midZ = TRAILER_DEPTH/2.;
 113   eyeR = -290;
 114   eyeA = .15;
 115   eyeY = midY + 20;
 116   eyeX = midX + eyeR*sin(eyeA);
 117   eyeZ = midZ + eyeR*cos(eyeA);
 118   addMouseWheelListener(new java.awt.event.MouseWheelListener() {
 119     public void mouseWheelMoved(java.awt.event.MouseWheelEvent mwe) {
 120       mouseWheel(mwe.getWheelRotation());
 121   }});
 122
 123   println("Total setup: " + (millis() - startMillis) + "ms");
 124   println("Hit the 'p' key to toggle Panda Board output");
 125 }
 126
 127 void controllerChangeReceived(rwmidi.Controller cc) {
 128   if (debugMode) {
 129     println("CC: " + cc.toString());
 130   }
 131 }
 132
 133 void noteOnReceived(Note note) {
 134   if (debugMode) {
 135     println("Note On: " + note.toString());
 136   }
 137 }
 138
 139 void noteOffReceived(Note note) {
 140   if (debugMode) {
 141     println("Note Off: " + note.toString());
 142   }
 143 }
 144
 145 void logTime(String evt) {
 146   int now = millis();
 147   println(evt + ": " + (now - lastMillis) + "ms");
 148   lastMillis = now;
 149 }
 150
 151 void draw() {
 152   // Draws the simulation and the 2D UI overlay
 153   background(40);
 154   color[] colors = glucose.getColors();
 155   if (debugMode) {
 156     debugUI.maskColors(colors);
 157   }
 158
 159   camera(
 160     eyeX, eyeY, eyeZ,
 161     midX, midY, midZ,
 162     0, -1, 0
 163   );
 164
 165   noStroke();
 166   fill(#141414);
 167   drawBox(0, -TRAILER_HEIGHT, 0, 0, 0, 0, TRAILER_WIDTH, TRAILER_HEIGHT, TRAILER_DEPTH, TRAILER_HEIGHT/2.);
 168   fill(#070707);
 169   stroke(#222222);
 170   beginShape();
 171   vertex(0, 0, 0);
 172   vertex(TRAILER_WIDTH, 0, 0);
 173   vertex(TRAILER_WIDTH, 0, TRAILER_DEPTH);
 174   vertex(0, 0, TRAILER_DEPTH);
 175   endShape();
 176
 177   noStroke();
 178   drawBassBox(glucose.model.bassBox);
 179   for (Speaker s : glucose.model.speakers) {
 180     drawSpeaker(s);
 181   }
 182   for (Cube c : glucose.model.cubes) {
 183     drawCube(c);
 184   }
 185
 186   noFill();
 187   strokeWeight(2);
 188   beginShape(POINTS);
 189   for (Point p : glucose.model.points) {
 190     stroke(colors[p.index]);
 191     vertex(p.fx, p.fy, p.fz);
 192   }
 193   endShape();
 194
 195   // 2D Overlay
 196   camera();
 197   javax.media.opengl.GL gl = ((PGraphicsOpenGL)g).beginGL();
 198   gl.glClear(javax.media.opengl.GL.GL_DEPTH_BUFFER_BIT);
 199   ((PGraphicsOpenGL)g).endGL();
 200   strokeWeight(1);
 201   drawUI();
 202
 203   if (debugMode) {
 204     debugUI.draw();
 205   }
 206
 207   // Gamma correction here. Apply a cubic to the brightness
 208   // for better representation of dynamic range
 209   for (int i = 0; i < colors.length; ++i) {
 210     float b = brightness(colors[i]) / 100.f;
 211     colors[i] = color(
 212       hue(colors[i]),
 213       saturation(colors[i]),
 214       (b*b*b) * 100.
 215     );
 216   }
 217
 218   // TODO(mcslee): move into GLucose engine
 219   for (PandaDriver p : pandaBoards) {
 220     p.send(colors);
 221   }
 222 }
 223
 224 void drawBassBox(BassBox b) {
 225   float in = .15;
 226
 227   noStroke();
 228   fill(#191919);
 229   pushMatrix();
 230   translate(b.x + BassBox.EDGE_WIDTH/2., b.y + BassBox.EDGE_HEIGHT/2, b.z + BassBox.EDGE_DEPTH/2.);
 231   box(BassBox.EDGE_WIDTH-20*in, BassBox.EDGE_HEIGHT-20*in, BassBox.EDGE_DEPTH-20*in);
 232   popMatrix();
 233
 234   noStroke();
 235   fill(#393939);
 236   drawBox(b.x+in, b.y+in, b.z+in, 0, 0, 0, BassBox.EDGE_WIDTH-in*2, BassBox.EDGE_HEIGHT-in*2, BassBox.EDGE_DEPTH-in*2, Cube.CHANNEL_WIDTH-in);
 237
 238   pushMatrix();
 239   translate(b.x+(Cube.CHANNEL_WIDTH-in)/2., b.y + BassBox.EDGE_HEIGHT-in, b.z + BassBox.EDGE_DEPTH/2.);
 240   float lastOffset = 0;
 241   for (float offset : BoothFloor.STRIP_OFFSETS) {
 242     translate(offset - lastOffset, 0, 0);
 243     box(Cube.CHANNEL_WIDTH-in, 0, BassBox.EDGE_DEPTH - 2*in);
 244     lastOffset = offset;
 245   }
 246   popMatrix();
 247
 248   pushMatrix();
 249   translate(b.x + (Cube.CHANNEL_WIDTH-in)/2., b.y + BassBox.EDGE_HEIGHT/2., b.z + in);
 250   for (int j = 0; j < 2; ++j) {
 251     pushMatrix();
 252     for (int i = 0; i < BassBox.NUM_FRONT_STRUTS; ++i) {
 253       translate(BassBox.FRONT_STRUT_SPACING, 0, 0);
 254       box(Cube.CHANNEL_WIDTH-in, BassBox.EDGE_HEIGHT - in*2, 0);
 255     }
 256     popMatrix();
 257     translate(0, 0, BassBox.EDGE_DEPTH - 2*in);
 258   }
 259   popMatrix();
 260
 261   pushMatrix();
 262   translate(b.x + in, b.y + BassBox.EDGE_HEIGHT/2., b.z + BassBox.SIDE_STRUT_SPACING + (Cube.CHANNEL_WIDTH-in)/2.);
 263   box(0, BassBox.EDGE_HEIGHT - in*2, Cube.CHANNEL_WIDTH-in);
 264   translate(BassBox.EDGE_WIDTH-2*in, 0, 0);
 265   box(0, BassBox.EDGE_HEIGHT - in*2, Cube.CHANNEL_WIDTH-in);
 266   popMatrix();
 267
 268 }
 269
 270 void drawCube(Cube c) {
 271   float in = .15;
 272   noStroke();
 273   fill(#393939);
 274   drawBox(c.x+in, c.y+in, c.z+in, c.rx, c.ry, c.rz, Cube.EDGE_WIDTH-in*2, Cube.EDGE_HEIGHT-in*2, Cube.EDGE_WIDTH-in*2, Cube.CHANNEL_WIDTH-in);
 275 }
 276
 277 void drawSpeaker(Speaker s) {
 278   float in = .15;
 279
 280   noStroke();
 281   fill(#191919);
 282   pushMatrix();
 283   translate(s.x, s.y, s.z);
 284   rotate(s.ry / 180. * PI, 0, -1, 0);
 285   translate(Speaker.EDGE_WIDTH/2., Speaker.EDGE_HEIGHT/2., Speaker.EDGE_DEPTH/2.);
 286   box(Speaker.EDGE_WIDTH-20*in, Speaker.EDGE_HEIGHT-20*in, Speaker.EDGE_DEPTH-20*in);
 287   translate(0, Speaker.EDGE_HEIGHT/2. + Speaker.EDGE_HEIGHT*.8/2, 0);
 288
 289   fill(#222222);
 290   box(Speaker.EDGE_WIDTH*.6, Speaker.EDGE_HEIGHT*.8, Speaker.EDGE_DEPTH*.75);
 291   popMatrix();
 292
 293   noStroke();
 294   fill(#393939);
 295   drawBox(s.x+in, s.y+in, s.z+in, 0, s.ry, 0, Speaker.EDGE_WIDTH-in*2, Speaker.EDGE_HEIGHT-in*2, Speaker.EDGE_DEPTH-in*2, Cube.CHANNEL_WIDTH-in);
 296 }
 297
 298
 299 void drawBox(float x, float y, float z, float rx, float ry, float rz, float xd, float yd, float zd, float sw) {
 300   pushMatrix();
 301   translate(x, y, z);
 302   rotate(rx / 180. * PI, -1, 0, 0);
 303   rotate(ry / 180. * PI, 0, -1, 0);
 304   rotate(rz / 180. * PI, 0, 0, -1);
 305   for (int i = 0; i < 4; ++i) {
 306     float wid = (i % 2 == 0) ? xd : zd;
 307
 308     beginShape();
 309     vertex(0, 0);
 310     vertex(wid, 0);
 311     vertex(wid, yd);
 312     vertex(wid - sw, yd);
 313     vertex(wid - sw, sw);
 314     vertex(0, sw);
 315     endShape();
 316     beginShape();
 317     vertex(0, sw);
 318     vertex(0, yd);
 319     vertex(wid - sw, yd);
 320     vertex(wid - sw, yd - sw);
 321     vertex(sw, yd - sw);
 322     vertex(sw, sw);
 323     endShape();
 324
 325     translate(wid, 0, 0);
 326     rotate(HALF_PI, 0, -1, 0);
 327   }
 328   popMatrix();
 329 }
 330
 331 void drawUI() {
 332   if (uiOn) {
 333     ui.draw();
 334   } else {
 335     ui.drawHelpTip();
 336   }
 337   ui.drawFPS();
 338 }
 339
 340 boolean uiOn = true;
 341 int restoreToIndex = -1;
 342
 343 void keyPressed() {
 344   if (mappingMode) {
 345     mappingTool.keyPressed();
 346   }
 347   switch (key) {
 348     case '-':
 349     case '_':
 350       frameRate(--targetFramerate);
 351       break;
 352     case '=':
 353     case '+':
 354       frameRate(++targetFramerate);
 355       break;
 356     case 'd':
 357       debugMode = !debugMode;
 358       println("Debug output: " + (debugMode ? "ON" : "OFF"));
 359       break;
 360     case 'm':
 361       mappingMode = !mappingMode;
 362       if (mappingMode) {
 363         LXPattern pattern = lx.getPattern();
 364         for (int i = 0; i < patterns.length; ++i) {
 365           if (pattern == patterns[i]) {
 366             restoreToIndex = i;
 367             break;
 368           }
 369         }
 370         ui = mappingUI;
 371         lx.setPatterns(new LXPattern[] { mappingTool });
 372       } else {
 373         ui = controlUI;
 374         lx.setPatterns(patterns);
 375         lx.goIndex(restoreToIndex);
 376       }
 377       break;
 378     case 'p':
 379       for (PandaDriver p : pandaBoards) {
 380         p.toggle();
 381       }
 382       break;
 383     case 'u':
 384       uiOn = !uiOn;
 385       break;
 386   }
 387 }
 388
 389 int mx, my;
 390 void mousePressed() {
 391   ui.mousePressed();
 392   if (mouseX < ui.leftPos) {
 393     if (debugMode) {
 394       debugUI.mousePressed();
 395     }
 396     mx = mouseX;
 397     my = mouseY;
 398   }
 399 }
 400
 401 void mouseDragged() {
 402   if (mouseX > ui.leftPos) {
 403     ui.mouseDragged();
 404   } else {
 405     int dx = mouseX - mx;
 406     int dy = mouseY - my;
 407     mx = mouseX;
 408     my = mouseY;
 409     eyeA += dx*.003;
 410     eyeX = midX + eyeR*sin(eyeA);
 411     eyeZ = midZ + eyeR*cos(eyeA);
 412     eyeY += dy;
 413   }
 414 }
 415
 416 void mouseReleased() {
 417   ui.mouseReleased();
 418 }
 419
 420 void mouseWheel(int delta) {
 421   if (mouseX > ui.leftPos) {
 422     ui.mouseWheel(delta);
 423   } else {
 424     eyeR = constrain(eyeR - delta, -500, -80);
 425     eyeX = midX + eyeR*sin(eyeA);
 426     eyeZ = midZ + eyeR*cos(eyeA);
 427   }
 428 }
 429