_Internals.pde

   1 /**
   2  *     DOUBLE BLACK DIAMOND        DOUBLE BLACK DIAMOND
   3  *
   4  *         //\\   //\\                 //\\   //\\
   5  *        ///\\\ ///\\\               ///\\\ ///\\\
   6  *        \\\/// \\\///               \\\/// \\\///
   7  *         \\//   \\//                 \\//   \\//
   8  *
   9  *        EXPERTS ONLY!!              EXPERTS ONLY!!
  10  *
  11  * If you are an artist, you may ignore this file! It just sets
  12  * up the framework to run the patterns. Should not need modification
  13  * for general animation work.
  14  */
  15
  16 import glucose.*;
  17 import glucose.control.*;
  18 import glucose.effect.*;
  19 import glucose.model.*;
  20 import glucose.pattern.*;
  21 import glucose.transform.*;
  22 import glucose.transition.*;
  23 import heronarts.lx.*;
  24 import heronarts.lx.control.*;
  25 import heronarts.lx.effect.*;
  26 import heronarts.lx.modulator.*;
  27 import heronarts.lx.pattern.*;
  28 import heronarts.lx.transition.*;
  29 import ddf.minim.*;
  30 import ddf.minim.analysis.*;
  31 import processing.opengl.*;
  32 import rwmidi.*;
  33
  34 final int VIEWPORT_WIDTH = 900;
  35 final int VIEWPORT_HEIGHT = 700;
  36
  37 // The trailer is measured from the outside of the black metal (but not including the higher welded part on the front)
  38 final float TRAILER_WIDTH = 240;
  39 final float TRAILER_DEPTH = 97;
  40 final float TRAILER_HEIGHT = 33;
  41
  42 int targetFramerate = 60;
  43
  44 int startMillis, lastMillis;
  45 GLucose glucose;
  46 HeronLX lx;
  47 MappingTool mappingTool;
  48 LXPattern[] patterns;
  49 LXTransition[] transitions;
  50 LXEffect[] effects;
  51 OverlayUI ui;
  52 ControlUI controlUI;
  53 MappingUI mappingUI;
  54 PandaDriver[] pandaBoards;
  55 boolean mappingMode = false;
  56 boolean debugMode = false;
  57 DebugUI debugUI;
  58
  59 // Camera variables
  60 float eyeR, eyeA, eyeX, eyeY, eyeZ, midX, midY, midZ;
  61
  62 void setup() {
  63   startMillis = lastMillis = millis();
  64
  65   // Initialize the Processing graphics environment
  66   size(VIEWPORT_WIDTH, VIEWPORT_HEIGHT, OPENGL);
  67   frameRate(targetFramerate);
  68   noSmooth();
  69   // hint(ENABLE_OPENGL_4X_SMOOTH); // no discernable improvement?
  70   logTime("Created viewport");
  71
  72   // Create the GLucose engine to run the cubes
  73   glucose = new GLucose(this, buildModel());
  74   lx = glucose.lx;
  75   lx.enableKeyboardTempo();
  76   logTime("Built GLucose engine");
  77
  78   // Set the patterns
  79   glucose.lx.setPatterns(patterns = patterns(glucose));
  80   logTime("Built patterns");
  81   glucose.lx.addEffects(effects = effects(glucose));
  82   logTime("Built effects");
  83   glucose.setTransitions(transitions = transitions(glucose));
  84   logTime("Built transitions");
  85
  86   // Build output driver
  87   PandaMapping[] pandaMappings = buildPandaList();
  88   pandaBoards = new PandaDriver[pandaMappings.length];
  89   int pbi = 0;
  90   for (PandaMapping pm : pandaMappings) {
  91     pandaBoards[pbi++] = new PandaDriver(pm.ip, glucose.model, pm);
  92   }
  93   mappingTool = new MappingTool(glucose, pandaMappings);
  94   logTime("Built PandaDriver");
  95
  96   // Build overlay UI
  97   ui = controlUI = new ControlUI();
  98   mappingUI = new MappingUI(mappingTool);
  99   debugUI = new DebugUI(pandaMappings);
 100   logTime("Built overlay UI");
 101
 102   // MIDI devices
 103   for (MidiInputDevice d : RWMidi.getInputDevices()) {
 104     d.createInput(this);
 105   }
 106   SCMidiDevices.initializeStandardDevices(glucose);
 107   logTime("Setup MIDI devices");
 108
 109   // Setup camera
 110   midX = TRAILER_WIDTH/2. + 20;
 111   midY = glucose.model.yMax/2;
 112   midZ = TRAILER_DEPTH/2.;
 113   eyeR = -290;
 114   eyeA = .15;
 115   eyeY = midY + 20;
 116   eyeX = midX + eyeR*sin(eyeA);
 117   eyeZ = midZ + eyeR*cos(eyeA);
 118   addMouseWheelListener(new java.awt.event.MouseWheelListener() {
 119     public void mouseWheelMoved(java.awt.event.MouseWheelEvent mwe) {
 120       mouseWheel(mwe.getWheelRotation());
 121   }});
 122
 123   println("Total setup: " + (millis() - startMillis) + "ms");
 124   println("Hit the 'p' key to toggle Panda Board output");
 125 }
 126
 127
 128 void controllerChangeReceived(rwmidi.Controller cc) {
 129   if (debugMode) {
 130     println("CC: " + cc.toString());
 131   }
 132 }
 133
 134 void noteOnReceived(Note note) {
 135   if (debugMode) {
 136     println("Note On: " + note.toString());
 137   }
 138 }
 139
 140 void noteOffReceived(Note note) {
 141   if (debugMode) {
 142     println("Note Off: " + note.toString());
 143   }
 144 }
 145
 146 void logTime(String evt) {
 147   int now = millis();
 148   println(evt + ": " + (now - lastMillis) + "ms");
 149   lastMillis = now;
 150 }
 151
 152 void draw() {
 153   // Draws the simulation and the 2D UI overlay
 154   background(40);
 155   color[] colors = glucose.getColors();
 156   if (debugMode) {
 157     debugUI.maskColors(colors);
 158   }
 159
 160   camera(
 161     eyeX, eyeY, eyeZ,
 162     midX, midY, midZ,
 163     0, -1, 0
 164   );
 165
 166   noStroke();
 167   fill(#141414);
 168   drawBox(0, -TRAILER_HEIGHT, 0, 0, 0, 0, TRAILER_WIDTH, TRAILER_HEIGHT, TRAILER_DEPTH, TRAILER_HEIGHT/2.);
 169   fill(#070707);
 170   stroke(#222222);
 171   beginShape();
 172   vertex(0, 0, 0);
 173   vertex(TRAILER_WIDTH, 0, 0);
 174   vertex(TRAILER_WIDTH, 0, TRAILER_DEPTH);
 175   vertex(0, 0, TRAILER_DEPTH);
 176   endShape();
 177
 178   noStroke();
 179 //  drawBassBox(glucose.model.bassBox);
 180 //  for (Speaker s : glucose.model.speakers) {
 181 //    drawSpeaker(s);
 182 //  }
 183   for (Cube c : glucose.model.cubes) {
 184     drawCube(c);
 185   }
 186
 187   noFill();
 188   strokeWeight(2);
 189   beginShape(POINTS);
 190   // TODO(mcslee): restore when bassBox/speakers are right again
 191   // for (Point p : glucose.model.points) {
 192   for (Cube cube : glucose.model.cubes) {
 193     for (Point p : cube.points) {
 194       stroke(colors[p.index]);
 195       vertex(p.fx, p.fy, p.fz);
 196     }
 197   }
 198   endShape();
 199
 200   // 2D Overlay
 201   camera();
 202   javax.media.opengl.GL gl = ((PGraphicsOpenGL)g).beginGL();
 203   gl.glClear(javax.media.opengl.GL.GL_DEPTH_BUFFER_BIT);
 204   ((PGraphicsOpenGL)g).endGL();
 205   strokeWeight(1);
 206   drawUI();
 207
 208   if (debugMode) {
 209     debugUI.draw();
 210   }
 211
 212   // Gamma correction here. Apply a cubic to the brightness
 213   // for better representation of dynamic range
 214   for (int i = 0; i < colors.length; ++i) {
 215     float b = brightness(colors[i]) / 100.f;
 216     colors[i] = color(
 217       hue(colors[i]),
 218       saturation(colors[i]),
 219       (b*b*b) * 100.
 220     );
 221   }
 222
 223   // TODO(mcslee): move into GLucose engine
 224   for (PandaDriver p : pandaBoards) {
 225     p.send(colors);
 226   }
 227 }
 228
 229 void drawBassBox(BassBox b) {
 230   float in = .15;
 231
 232   noStroke();
 233   fill(#191919);
 234   pushMatrix();
 235   translate(b.x + BassBox.EDGE_WIDTH/2., b.y + BassBox.EDGE_HEIGHT/2, b.z + BassBox.EDGE_DEPTH/2.);
 236   box(BassBox.EDGE_WIDTH-20*in, BassBox.EDGE_HEIGHT-20*in, BassBox.EDGE_DEPTH-20*in);
 237   popMatrix();
 238
 239   noStroke();
 240   fill(#393939);
 241   drawBox(b.x+in, b.y+in, b.z+in, 0, 0, 0, BassBox.EDGE_WIDTH-in*2, BassBox.EDGE_HEIGHT-in*2, BassBox.EDGE_DEPTH-in*2, Cube.CHANNEL_WIDTH-in);
 242
 243   pushMatrix();
 244   translate(b.x+(Cube.CHANNEL_WIDTH-in)/2., b.y + BassBox.EDGE_HEIGHT-in, b.z + BassBox.EDGE_DEPTH/2.);
 245   float lastOffset = 0;
 246   for (float offset : BoothFloor.STRIP_OFFSETS) {
 247     translate(offset - lastOffset, 0, 0);
 248     box(Cube.CHANNEL_WIDTH-in, 0, BassBox.EDGE_DEPTH - 2*in);
 249     lastOffset = offset;
 250   }
 251   popMatrix();
 252
 253   pushMatrix();
 254   translate(b.x + (Cube.CHANNEL_WIDTH-in)/2., b.y + BassBox.EDGE_HEIGHT/2., b.z + in);
 255   for (int j = 0; j < 2; ++j) {
 256     pushMatrix();
 257     for (int i = 0; i < BassBox.NUM_FRONT_STRUTS; ++i) {
 258       translate(BassBox.FRONT_STRUT_SPACING, 0, 0);
 259       box(Cube.CHANNEL_WIDTH-in, BassBox.EDGE_HEIGHT - in*2, 0);
 260     }
 261     popMatrix();
 262     translate(0, 0, BassBox.EDGE_DEPTH - 2*in);
 263   }
 264   popMatrix();
 265
 266   pushMatrix();
 267   translate(b.x + in, b.y + BassBox.EDGE_HEIGHT/2., b.z + BassBox.SIDE_STRUT_SPACING + (Cube.CHANNEL_WIDTH-in)/2.);
 268   box(0, BassBox.EDGE_HEIGHT - in*2, Cube.CHANNEL_WIDTH-in);
 269   translate(BassBox.EDGE_WIDTH-2*in, 0, 0);
 270   box(0, BassBox.EDGE_HEIGHT - in*2, Cube.CHANNEL_WIDTH-in);
 271   popMatrix();
 272
 273 }
 274
 275 void drawCube(Cube c) {
 276   float in = .15;
 277   noStroke();
 278   fill(#393939);
 279   drawBox(c.x+in, c.y+in, c.z+in, c.rx, c.ry, c.rz, Cube.EDGE_WIDTH-in*2, Cube.EDGE_HEIGHT-in*2, Cube.EDGE_WIDTH-in*2, Cube.CHANNEL_WIDTH-in);
 280 }
 281
 282 void drawSpeaker(Speaker s) {
 283   float in = .15;
 284
 285   noStroke();
 286   fill(#191919);
 287   pushMatrix();
 288   translate(s.x, s.y, s.z);
 289   rotate(s.ry / 180. * PI, 0, -1, 0);
 290   translate(Speaker.EDGE_WIDTH/2., Speaker.EDGE_HEIGHT/2., Speaker.EDGE_DEPTH/2.);
 291   box(Speaker.EDGE_WIDTH-20*in, Speaker.EDGE_HEIGHT-20*in, Speaker.EDGE_DEPTH-20*in);
 292   translate(0, Speaker.EDGE_HEIGHT/2. + Speaker.EDGE_HEIGHT*.8/2, 0);
 293
 294   fill(#222222);
 295   box(Speaker.EDGE_WIDTH*.6, Speaker.EDGE_HEIGHT*.8, Speaker.EDGE_DEPTH*.75);
 296   popMatrix();
 297
 298   noStroke();
 299   fill(#393939);
 300   drawBox(s.x+in, s.y+in, s.z+in, 0, s.ry, 0, Speaker.EDGE_WIDTH-in*2, Speaker.EDGE_HEIGHT-in*2, Speaker.EDGE_DEPTH-in*2, Cube.CHANNEL_WIDTH-in);
 301 }
 302
 303 void drawBox(float x, float y, float z, float rx, float ry, float rz, float xd, float yd, float zd, float sw) {
 304   pushMatrix();
 305   translate(x, y, z);
 306   rotate(rx / 180. * PI, -1, 0, 0);
 307   rotate(ry / 180. * PI, 0, -1, 0);
 308   rotate(rz / 180. * PI, 0, 0, -1);
 309   for (int i = 0; i < 4; ++i) {
 310     float wid = (i % 2 == 0) ? xd : zd;
 311
 312     beginShape();
 313     vertex(0, 0);
 314     vertex(wid, 0);
 315     vertex(wid, yd);
 316     vertex(wid - sw, yd);
 317     vertex(wid - sw, sw);
 318     vertex(0, sw);
 319     endShape();
 320     beginShape();
 321     vertex(0, sw);
 322     vertex(0, yd);
 323     vertex(wid - sw, yd);
 324     vertex(wid - sw, yd - sw);
 325     vertex(sw, yd - sw);
 326     vertex(sw, sw);
 327     endShape();
 328
 329     translate(wid, 0, 0);
 330     rotate(HALF_PI, 0, -1, 0);
 331   }
 332   popMatrix();
 333 }
 334
 335 void drawUI() {
 336   if (uiOn) {
 337     ui.draw();
 338   } else {
 339     ui.drawHelpTip();
 340   }
 341   ui.drawFPS();
 342   ui.drawDanText();
 343 }
 344
 345 boolean uiOn = true;
 346 int restoreToIndex = -1;
 347
 348 boolean doDual = false;
 349
 350 void keyPressed() {
 351   if (mappingMode) {
 352     mappingTool.keyPressed();
 353   }
 354   switch (key) {
 355     case 'w':
 356        doDual = !doDual;
 357        break;
 358     case '-':
 359     case '_':
 360       frameRate(--targetFramerate);
 361       break;
 362     case '=':
 363     case '+':
 364       frameRate(++targetFramerate);
 365       break;
 366     case 'd':
 367       debugMode = !debugMode;
 368       println("Debug output: " + (debugMode ? "ON" : "OFF"));
 369       break;
 370     case 'm':
 371       mappingMode = !mappingMode;
 372       if (mappingMode) {
 373         LXPattern pattern = lx.getPattern();
 374         for (int i = 0; i < patterns.length; ++i) {
 375           if (pattern == patterns[i]) {
 376             restoreToIndex = i;
 377             break;
 378           }
 379         }
 380         ui = mappingUI;
 381         lx.setPatterns(new LXPattern[] { mappingTool });
 382       } else {
 383         ui = controlUI;
 384         lx.setPatterns(patterns);
 385         lx.goIndex(restoreToIndex);
 386       }
 387       break;
 388     case 'p':
 389       for (PandaDriver p : pandaBoards) {
 390         p.toggle();
 391       }
 392       break;
 393     case 'u':
 394       uiOn = !uiOn;
 395       break;
 396   }
 397 }
 398
 399 int mx, my;
 400 void mousePressed() {
 401   ui.mousePressed();
 402   if (mouseX < ui.leftPos) {
 403     if (debugMode) {
 404       debugUI.mousePressed();
 405     }
 406     mx = mouseX;
 407     my = mouseY;
 408   }
 409 }
 410
 411 void mouseDragged() {
 412   if (mouseX > ui.leftPos) {
 413     ui.mouseDragged();
 414   } else {
 415     int dx = mouseX - mx;
 416     int dy = mouseY - my;
 417     mx = mouseX;
 418     my = mouseY;
 419     eyeA += dx*.003;
 420     eyeX = midX + eyeR*sin(eyeA);
 421     eyeZ = midZ + eyeR*cos(eyeA);
 422     eyeY += dy;
 423   }
 424 }
 425
 426 void mouseReleased() {
 427   ui.mouseReleased();
 428 }
 429
 430 void mouseWheel(int delta) {
 431   if (mouseX > ui.leftPos) {
 432     ui.mouseWheel(delta);
 433   } else {
 434     eyeR = constrain(eyeR - delta, -500, -80);
 435     eyeX = midX + eyeR*sin(eyeA);
 436     eyeZ = midZ + eyeR*cos(eyeA);
 437   }
 438 }