_Internals.pde

   1 /**
   2  *     DOUBLE BLACK DIAMOND        DOUBLE BLACK DIAMOND
   3  *
   4  *         //\\   //\\                 //\\   //\\
   5  *        ///\\\ ///\\\               ///\\\ ///\\\
   6  *        \\\/// \\\///               \\\/// \\\///
   7  *         \\//   \\//                 \\//   \\//
   8  *
   9  *        EXPERTS ONLY!!              EXPERTS ONLY!!
  10  *
  11  * If you are an artist, you may ignore this file! It just sets
  12  * up the framework to run the patterns. Should not need modification
  13  * for general animation work.
  14  */
  15
  16 import glucose.*;
  17 import glucose.control.*;
  18 import glucose.effect.*;
  19 import glucose.model.*;
  20 import glucose.pattern.*;
  21 import glucose.transform.*;
  22 import glucose.transition.*;
  23 import heronarts.lx.*;
  24 import heronarts.lx.control.*;
  25 import heronarts.lx.effect.*;
  26 import heronarts.lx.modulator.*;
  27 import heronarts.lx.pattern.*;
  28 import heronarts.lx.transition.*;
  29 import ddf.minim.*;
  30 import ddf.minim.analysis.*;
  31 import processing.opengl.*;
  32 import rwmidi.*;
  33
  34 final int VIEWPORT_WIDTH = 900;
  35 final int VIEWPORT_HEIGHT = 700;
  36
  37 // The trailer is measured from the outside of the black metal (but not including the higher welded part on the front)
  38 final float TRAILER_WIDTH = 240;
  39 final float TRAILER_DEPTH = 97;
  40 final float TRAILER_HEIGHT = 33;
  41
  42 int targetFramerate = 60;
  43
  44 int startMillis, lastMillis;
  45 GLucose glucose;
  46 HeronLX lx;
  47 MappingTool mappingTool;
  48 LXPattern[] patterns;
  49 LXTransition[] transitions;
  50 LXEffect[] effects;
  51 OverlayUI ui;
  52 ControlUI controlUI;
  53 MappingUI mappingUI;
  54 PandaDriver[] pandaBoards;
  55 boolean mappingMode = false;
  56 boolean debugMode = false;
  57 DebugUI debugUI;
  58
  59 // Camera variables
  60 float eyeR, eyeA, eyeX, eyeY, eyeZ, midX, midY, midZ;
  61
  62 void setup() {
  63   startMillis = lastMillis = millis();
  64
  65   // Initialize the Processing graphics environment
  66   size(VIEWPORT_WIDTH, VIEWPORT_HEIGHT, OPENGL);
  67   frameRate(targetFramerate);
  68   noSmooth();
  69   // hint(ENABLE_OPENGL_4X_SMOOTH); // no discernable improvement?
  70   logTime("Created viewport");
  71
  72   // Create the GLucose engine to run the cubes
  73   glucose = new GLucose(this, buildModel());
  74   lx = glucose.lx;
  75   lx.enableKeyboardTempo();
  76   logTime("Built GLucose engine");
  77
  78   // Set the patterns
  79   glucose.lx.setPatterns(patterns = patterns(glucose));
  80   logTime("Built patterns");
  81   glucose.lx.addEffects(effects = effects(glucose));
  82   logTime("Built effects");
  83   glucose.setTransitions(transitions = transitions(glucose));
  84   logTime("Built transitions");
  85
  86   // Build output driver
  87   PandaMapping[] pandaMappings = buildPandaList();
  88   pandaBoards = new PandaDriver[pandaMappings.length];
  89   int pbi = 0;
  90   for (PandaMapping pm : pandaMappings) {
  91     pandaBoards[pbi++] = new PandaDriver(pm.ip, glucose.model, pm);
  92   }
  93   mappingTool = new MappingTool(glucose, pandaMappings);
  94   logTime("Built PandaDriver");
  95
  96   // Build overlay UI
  97   ui = controlUI = new ControlUI();
  98   mappingUI = new MappingUI(mappingTool);
  99   debugUI = new DebugUI(pandaMappings);
 100   logTime("Built overlay UI");
 101
 102   // MIDI devices
 103   for (MidiInputDevice d : RWMidi.getInputDevices()) {
 104     d.createInput(this);
 105   }
 106   SCMidiDevices.initializeStandardDevices(glucose);
 107   logTime("Setup MIDI devices");
 108
 109   // Setup camera
 110   midX = TRAILER_WIDTH/2. + 20;
 111   midY = glucose.model.yMax/2;
 112   midZ = TRAILER_DEPTH/2.;
 113   eyeR = -290;
 114   eyeA = .15;
 115   eyeY = midY + 20;
 116   eyeX = midX + eyeR*sin(eyeA);
 117   eyeZ = midZ + eyeR*cos(eyeA);
 118   addMouseWheelListener(new java.awt.event.MouseWheelListener() {
 119     public void mouseWheelMoved(java.awt.event.MouseWheelEvent mwe) {
 120       mouseWheel(mwe.getWheelRotation());
 121   }});
 122
 123   println("Total setup: " + (millis() - startMillis) + "ms");
 124   println("Hit the 'p' key to toggle Panda Board output");
 125 }
 126
 127
 128 void controllerChangeReceived(rwmidi.Controller cc) {
 129   if (debugMode) {
 130     println("CC: " + cc.toString());
 131   }
 132 }
 133
 134 void noteOnReceived(Note note) {
 135   if (debugMode) {
 136     println("Note On: " + note.toString());
 137   }
 138 }
 139
 140 void noteOffReceived(Note note) {
 141   if (debugMode) {
 142     println("Note Off: " + note.toString());
 143   }
 144 }
 145
 146 void logTime(String evt) {
 147   int now = millis();
 148   println(evt + ": " + (now - lastMillis) + "ms");
 149   lastMillis = now;
 150 }
 151
 152 void draw() {
 153   // Draws the simulation and the 2D UI overlay
 154   background(40);
 155   color[] colors = glucose.getColors();
 156   if (debugMode) {
 157     debugUI.maskColors(colors);
 158   }
 159
 160   camera(
 161     eyeX, eyeY, eyeZ,
 162     midX, midY, midZ,
 163     0, -1, 0
 164   );
 165
 166   noStroke();
 167   fill(#141414);
 168   drawBox(0, -TRAILER_HEIGHT, 0, 0, 0, 0, TRAILER_WIDTH, TRAILER_HEIGHT, TRAILER_DEPTH, TRAILER_HEIGHT/2.);
 169   fill(#070707);
 170   stroke(#222222);
 171   beginShape();
 172   vertex(0, 0, 0);
 173   vertex(TRAILER_WIDTH, 0, 0);
 174   vertex(TRAILER_WIDTH, 0, TRAILER_DEPTH);
 175   vertex(0, 0, TRAILER_DEPTH);
 176   endShape();
 177
 178   noStroke();
 179 //  drawBassBox(glucose.model.bassBox);
 180 //  for (Speaker s : glucose.model.speakers) {
 181 //    drawSpeaker(s);
 182 //  }
 183   for (Cube c : glucose.model.cubes) {
 184     drawCube(c);
 185   }
 186
 187   noFill();
 188   strokeWeight(2);
 189   beginShape(POINTS);
 190   for (Point p : glucose.model.points) {
 191     stroke(colors[p.index]);
 192     vertex(p.fx, p.fy, p.fz);
 193   }
 194   endShape();
 195
 196   // 2D Overlay
 197   camera();
 198   javax.media.opengl.GL gl = ((PGraphicsOpenGL)g).beginGL();
 199   gl.glClear(javax.media.opengl.GL.GL_DEPTH_BUFFER_BIT);
 200   ((PGraphicsOpenGL)g).endGL();
 201   strokeWeight(1);
 202   drawUI();
 203
 204   if (debugMode) {
 205     debugUI.draw();
 206   }
 207
 208   // Gamma correction here. Apply a cubic to the brightness
 209   // for better representation of dynamic range
 210   for (int i = 0; i < colors.length; ++i) {
 211     float b = brightness(colors[i]) / 100.f;
 212     colors[i] = color(
 213       hue(colors[i]),
 214       saturation(colors[i]),
 215       (b*b*b) * 100.
 216     );
 217   }
 218
 219   // TODO(mcslee): move into GLucose engine
 220   for (PandaDriver p : pandaBoards) {
 221     p.send(colors);
 222   }
 223 }
 224
 225 void drawBassBox(BassBox b) {
 226   float in = .15;
 227
 228   noStroke();
 229   fill(#191919);
 230   pushMatrix();
 231   translate(b.x + BassBox.EDGE_WIDTH/2., b.y + BassBox.EDGE_HEIGHT/2, b.z + BassBox.EDGE_DEPTH/2.);
 232   box(BassBox.EDGE_WIDTH-20*in, BassBox.EDGE_HEIGHT-20*in, BassBox.EDGE_DEPTH-20*in);
 233   popMatrix();
 234
 235   noStroke();
 236   fill(#393939);
 237   drawBox(b.x+in, b.y+in, b.z+in, 0, 0, 0, BassBox.EDGE_WIDTH-in*2, BassBox.EDGE_HEIGHT-in*2, BassBox.EDGE_DEPTH-in*2, Cube.CHANNEL_WIDTH-in);
 238
 239   pushMatrix();
 240   translate(b.x+(Cube.CHANNEL_WIDTH-in)/2., b.y + BassBox.EDGE_HEIGHT-in, b.z + BassBox.EDGE_DEPTH/2.);
 241   float lastOffset = 0;
 242   for (float offset : BoothFloor.STRIP_OFFSETS) {
 243     translate(offset - lastOffset, 0, 0);
 244     box(Cube.CHANNEL_WIDTH-in, 0, BassBox.EDGE_DEPTH - 2*in);
 245     lastOffset = offset;
 246   }
 247   popMatrix();
 248
 249   pushMatrix();
 250   translate(b.x + (Cube.CHANNEL_WIDTH-in)/2., b.y + BassBox.EDGE_HEIGHT/2., b.z + in);
 251   for (int j = 0; j < 2; ++j) {
 252     pushMatrix();
 253     for (int i = 0; i < BassBox.NUM_FRONT_STRUTS; ++i) {
 254       translate(BassBox.FRONT_STRUT_SPACING, 0, 0);
 255       box(Cube.CHANNEL_WIDTH-in, BassBox.EDGE_HEIGHT - in*2, 0);
 256     }
 257     popMatrix();
 258     translate(0, 0, BassBox.EDGE_DEPTH - 2*in);
 259   }
 260   popMatrix();
 261
 262   pushMatrix();
 263   translate(b.x + in, b.y + BassBox.EDGE_HEIGHT/2., b.z + BassBox.SIDE_STRUT_SPACING + (Cube.CHANNEL_WIDTH-in)/2.);
 264   box(0, BassBox.EDGE_HEIGHT - in*2, Cube.CHANNEL_WIDTH-in);
 265   translate(BassBox.EDGE_WIDTH-2*in, 0, 0);
 266   box(0, BassBox.EDGE_HEIGHT - in*2, Cube.CHANNEL_WIDTH-in);
 267   popMatrix();
 268
 269 }
 270
 271 void drawCube(Cube c) {
 272   float in = .15;
 273   noStroke();
 274   fill(#393939);
 275   drawBox(c.x+in, c.y+in, c.z+in, c.rx, c.ry, c.rz, Cube.EDGE_WIDTH-in*2, Cube.EDGE_HEIGHT-in*2, Cube.EDGE_WIDTH-in*2, Cube.CHANNEL_WIDTH-in);
 276 }
 277
 278 void drawSpeaker(Speaker s) {
 279   float in = .15;
 280
 281   noStroke();
 282   fill(#191919);
 283   pushMatrix();
 284   translate(s.x, s.y, s.z);
 285   rotate(s.ry / 180. * PI, 0, -1, 0);
 286   translate(Speaker.EDGE_WIDTH/2., Speaker.EDGE_HEIGHT/2., Speaker.EDGE_DEPTH/2.);
 287   box(Speaker.EDGE_WIDTH-20*in, Speaker.EDGE_HEIGHT-20*in, Speaker.EDGE_DEPTH-20*in);
 288   translate(0, Speaker.EDGE_HEIGHT/2. + Speaker.EDGE_HEIGHT*.8/2, 0);
 289
 290   fill(#222222);
 291   box(Speaker.EDGE_WIDTH*.6, Speaker.EDGE_HEIGHT*.8, Speaker.EDGE_DEPTH*.75);
 292   popMatrix();
 293
 294   noStroke();
 295   fill(#393939);
 296   drawBox(s.x+in, s.y+in, s.z+in, 0, s.ry, 0, Speaker.EDGE_WIDTH-in*2, Speaker.EDGE_HEIGHT-in*2, Speaker.EDGE_DEPTH-in*2, Cube.CHANNEL_WIDTH-in);
 297 }
 298
 299 void drawBox(float x, float y, float z, float rx, float ry, float rz, float xd, float yd, float zd, float sw) {
 300   pushMatrix();
 301   translate(x, y, z);
 302   rotate(rx / 180. * PI, -1, 0, 0);
 303   rotate(ry / 180. * PI, 0, -1, 0);
 304   rotate(rz / 180. * PI, 0, 0, -1);
 305   for (int i = 0; i < 4; ++i) {
 306     float wid = (i % 2 == 0) ? xd : zd;
 307
 308     beginShape();
 309     vertex(0, 0);
 310     vertex(wid, 0);
 311     vertex(wid, yd);
 312     vertex(wid - sw, yd);
 313     vertex(wid - sw, sw);
 314     vertex(0, sw);
 315     endShape();
 316     beginShape();
 317     vertex(0, sw);
 318     vertex(0, yd);
 319     vertex(wid - sw, yd);
 320     vertex(wid - sw, yd - sw);
 321     vertex(sw, yd - sw);
 322     vertex(sw, sw);
 323     endShape();
 324
 325     translate(wid, 0, 0);
 326     rotate(HALF_PI, 0, -1, 0);
 327   }
 328   popMatrix();
 329 }
 330
 331 void drawUI() {
 332   if (uiOn) {
 333     ui.draw();
 334   } else {
 335     ui.drawHelpTip();
 336   }
 337   ui.drawFPS();
 338   ui.drawDanText();
 339 }
 340
 341 boolean uiOn = true;
 342 int restoreToIndex = -1;
 343
 344 boolean doDual = false;
 345
 346 void keyPressed() {
 347   if (mappingMode) {
 348     mappingTool.keyPressed();
 349   }
 350   switch (key) {
 351     case 'w':
 352        doDual = !doDual;
 353        break;
 354     case '-':
 355     case '_':
 356       frameRate(--targetFramerate);
 357       break;
 358     case '=':
 359     case '+':
 360       frameRate(++targetFramerate);
 361       break;
 362     case 'd':
 363       debugMode = !debugMode;
 364       println("Debug output: " + (debugMode ? "ON" : "OFF"));
 365       break;
 366     case 'm':
 367       mappingMode = !mappingMode;
 368       if (mappingMode) {
 369         LXPattern pattern = lx.getPattern();
 370         for (int i = 0; i < patterns.length; ++i) {
 371           if (pattern == patterns[i]) {
 372             restoreToIndex = i;
 373             break;
 374           }
 375         }
 376         ui = mappingUI;
 377         lx.setPatterns(new LXPattern[] { mappingTool });
 378       } else {
 379         ui = controlUI;
 380         lx.setPatterns(patterns);
 381         lx.goIndex(restoreToIndex);
 382       }
 383       break;
 384     case 'p':
 385       for (PandaDriver p : pandaBoards) {
 386         p.toggle();
 387       }
 388       break;
 389     case 'u':
 390       uiOn = !uiOn;
 391       break;
 392   }
 393 }
 394
 395 int mx, my;
 396 void mousePressed() {
 397   ui.mousePressed();
 398   if (mouseX < ui.leftPos) {
 399     if (debugMode) {
 400       debugUI.mousePressed();
 401     }
 402     mx = mouseX;
 403     my = mouseY;
 404   }
 405 }
 406
 407 void mouseDragged() {
 408   if (mouseX > ui.leftPos) {
 409     ui.mouseDragged();
 410   } else {
 411     int dx = mouseX - mx;
 412     int dy = mouseY - my;
 413     mx = mouseX;
 414     my = mouseY;
 415     eyeA += dx*.003;
 416     eyeX = midX + eyeR*sin(eyeA);
 417     eyeZ = midZ + eyeR*cos(eyeA);
 418     eyeY += dy;
 419   }
 420 }
 421
 422 void mouseReleased() {
 423   ui.mouseReleased();
 424 }
 425
 426 void mouseWheel(int delta) {
 427   if (mouseX > ui.leftPos) {
 428     ui.mouseWheel(delta);
 429   } else {
 430     eyeR = constrain(eyeR - delta, -500, -80);
 431     eyeX = midX + eyeR*sin(eyeA);
 432     eyeZ = midZ + eyeR*cos(eyeA);
 433   }
 434 }