_MIDI.pde

   1 /**
   2  *     DOUBLE BLACK DIAMOND        DOUBLE BLACK DIAMOND
   3  *
   4  *         //\\   //\\                 //\\   //\\
   5  *        ///\\\ ///\\\               ///\\\ ///\\\
   6  *        \\\/// \\\///               \\\/// \\\///
   7  *         \\//   \\//                 \\//   \\//
   8  *
   9  *        EXPERTS ONLY!!              EXPERTS ONLY!!
  10  *
  11  * This file defines the MIDI mapping interfaces. This shouldn't
  12  * need editing unless you're adding top level support for a
  13  * specific MIDI device of some sort. Generally, all MIDI devices
  14  * will just work with the default configuration, and you can
  15  * set your SCPattern class to respond to the controllers that you
  16  * care about.
  17  */
  18
  19 interface MidiEngineListener {
  20   public void onFocusedDeck(int deckIndex);
  21 }
  22
  23 class MidiEngine {
  24
  25   public final GridController grid;
  26   private final List<MidiEngineListener> listeners = new ArrayList<MidiEngineListener>();
  27   private final List<SCMidiInput> midiControllers = new ArrayList<SCMidiInput>();
  28
  29   public MidiEngine addListener(MidiEngineListener l) {
  30     listeners.add(l);
  31     return this;
  32   }
  33
  34   public MidiEngine removeListener(MidiEngineListener l) {
  35     listeners.remove(l);
  36     return this;
  37   }
  38
  39   private SCMidiInput midiQwertyKeys;
  40   private SCMidiInput midiQwertyAPC;
  41
  42   private int activeDeckIndex = 0;
  43
  44   public MidiEngine() {
  45     grid = new GridController(this);
  46     midiControllers.add(midiQwertyKeys = new VirtualKeyMidiInput(this, VirtualKeyMidiInput.KEYS));
  47     midiControllers.add(midiQwertyAPC = new VirtualKeyMidiInput(this, VirtualKeyMidiInput.APC));
  48     int apcCount = 0;
  49     for (MidiInputDevice device : RWMidi.getInputDevices()) {
  50       if (device.getName().contains("APC")) {
  51         ++apcCount;
  52       }
  53     }
  54
  55     int apcIndex = 0;
  56     for (MidiInputDevice device : RWMidi.getInputDevices()) {
  57       if (device.getName().contains("APC")) {
  58         int apcDeck = -1;
  59         if (apcCount > 1 && apcIndex < 2) {
  60           apcDeck = apcIndex++;
  61         }
  62         midiControllers.add(new APC40MidiInput(this, device, apcDeck).setEnabled(true));
  63       } else if (device.getName().contains("SLIDER/KNOB KORG")) {
  64         midiControllers.add(new KorgNanoKontrolMidiInput(this, device).setEnabled(true));
  65       } else if (device.getName().contains("Arturia MINILAB")) {
  66         midiControllers.add(new ArturiaMinilabMidiInput(this, device).setEnabled(true));
  67       } else {
  68         boolean enabled =
  69           device.getName().contains("KEYBOARD KORG") ||
  70           device.getName().contains("Bus 1 Apple");
  71         midiControllers.add(new GenericDeviceMidiInput(this, device).setEnabled(enabled));
  72       }
  73     }
  74
  75     apcIndex = 0;
  76     for (MidiOutputDevice device : RWMidi.getOutputDevices()) {
  77       if (device.getName().contains("APC")) {
  78         int apcDeck = -1;
  79         if (apcCount > 1 && apcIndex < 2) {
  80           apcDeck = apcIndex++;
  81         }
  82         new APC40MidiOutput(this, device, apcDeck);
  83       }
  84     }
  85   }
  86
  87   public List<SCMidiInput> getControllers() {
  88     return this.midiControllers;
  89   }
  90
  91   public LXDeck getFocusedDeck() {
  92     return lx.engine.getDeck(activeDeckIndex);
  93   }
  94
  95   public SCPattern getFocusedPattern() {
  96     return (SCPattern) getFocusedDeck().getActivePattern();
  97   }
  98
  99   public MidiEngine setFocusedDeck(int deckIndex) {
 100     if (this.activeDeckIndex != deckIndex) {
 101       this.activeDeckIndex = deckIndex;
 102       for (MidiEngineListener listener : listeners) {
 103         listener.onFocusedDeck(deckIndex);
 104       }
 105     }
 106     return this;
 107   }
 108
 109   public boolean isQwertyEnabled() {
 110     return midiQwertyKeys.isEnabled() || midiQwertyAPC.isEnabled();
 111   }
 112 }
 113
 114 public interface SCMidiInputListener {
 115   public void onEnabled(SCMidiInput controller, boolean enabled);
 116 }
 117
 118 public abstract class SCMidiInput extends AbstractScrollItem {
 119
 120   protected boolean enabled = false;
 121   private final String name;
 122
 123   protected final MidiEngine midiEngine;
 124
 125   final List<SCMidiInputListener> listeners = new ArrayList<SCMidiInputListener>();
 126
 127   protected SCMidiInput(MidiEngine midiEngine, String name) {
 128     this.midiEngine = midiEngine;
 129     this.name = name;
 130   }
 131
 132   public SCMidiInput addListener(SCMidiInputListener l) {
 133     listeners.add(l);
 134     return this;
 135   }
 136
 137   public SCMidiInput removeListener(SCMidiInputListener l) {
 138     listeners.remove(l);
 139     return this;
 140   }
 141
 142   public String getLabel() {
 143     return name;
 144   }
 145
 146   public boolean isEnabled() {
 147     return enabled;
 148   }
 149
 150   public boolean isSelected() {
 151     return enabled;
 152   }
 153
 154   public void onMousePressed() {
 155     setEnabled(!enabled);
 156   }
 157
 158   public SCMidiInput setEnabled(boolean enabled) {
 159     if (enabled != this.enabled) {
 160       this.enabled = enabled;
 161       for (SCMidiInputListener l : listeners) {
 162         l.onEnabled(this, enabled);
 163       }
 164     }
 165     return this;
 166   }
 167
 168   private boolean logMidi() {
 169     return (uiMidi != null) && uiMidi.logMidi();
 170   }
 171
 172   protected SCPattern getTargetPattern() {
 173     return midiEngine.getFocusedPattern();
 174   }
 175
 176   final void programChangeReceived(ProgramChange pc) {
 177     if (!enabled) {
 178       return;
 179     }
 180     if (logMidi()) {
 181       println(getLabel() + " :: Program Change :: " + pc.getNumber());
 182     }
 183     handleProgramChange(pc);
 184   }
 185
 186   final void controllerChangeReceived(rwmidi.Controller cc) {
 187     if (!enabled) {
 188       return;
 189     }
 190     if (logMidi()) {
 191       println(getLabel() + " :: Controller :: " + cc.getChannel() + " :: " + cc.getCC() + ":" + cc.getValue());
 192     }
 193     if (!handleControllerChange(cc)) {
 194       getTargetPattern().controllerChange(cc);
 195     }
 196   }
 197
 198   final void noteOnReceived(Note note) {
 199     if (!enabled) {
 200       return;
 201     }
 202     if (logMidi()) {
 203       println(getLabel() + " :: Note On  :: " + note.getChannel() + ":" + note.getPitch() + ":" + note.getVelocity());
 204     }
 205     if (!handleNoteOn(note)) {
 206       getTargetPattern().noteOn(note);
 207     }
 208   }
 209
 210   final void noteOffReceived(Note note) {
 211     if (!enabled) {
 212       return;
 213     }
 214     if (logMidi()) {
 215       println(getLabel() + " :: Note Off :: " + note.getChannel() + ":" + note.getPitch() + ":" + note.getVelocity());
 216     }
 217     if (!handleNoteOff(note)) {
 218       getTargetPattern().noteOff(note);
 219     }
 220   }
 221
 222   // Subclasses may implement these to map top-level functionality
 223   protected boolean handleProgramChange(ProgramChange pc) { return false; }
 224   protected boolean handleControllerChange(rwmidi.Controller cc) { return false; }
 225   protected boolean handleNoteOn(Note note) { return false; }
 226   protected boolean handleNoteOff(Note note) { return false; }
 227 }
 228
 229 public class VirtualKeyMidiInput extends SCMidiInput {
 230
 231   public static final int KEYS = 1;
 232   public static final int APC = 2;
 233
 234   private final int mode;
 235
 236   private int octaveShift = 0;
 237
 238   class NoteMeta {
 239     int channel;
 240     int number;
 241     NoteMeta(int channel, int number) {
 242       this.channel = channel;
 243       this.number = number;
 244     }
 245   }
 246
 247   final Map<Character, NoteMeta> keyToNote = new HashMap<Character, NoteMeta>();
 248
 249   VirtualKeyMidiInput(MidiEngine midiEngine, int mode) {
 250     super(midiEngine, "QWERTY (" + (mode == APC ? "APC" : "Key") + "  Mode)");
 251     this.mode = mode;
 252     if (mode == APC) {
 253       mapAPC();
 254     } else {
 255       mapKeys();
 256     }
 257     registerKeyEvent(this);
 258   }
 259
 260   private void mapAPC() {
 261     mapNote('1', 0, 53);
 262     mapNote('2', 1, 53);
 263     mapNote('3', 2, 53);
 264     mapNote('4', 3, 53);
 265     mapNote('5', 4, 53);
 266     mapNote('6', 5, 53);
 267     mapNote('q', 0, 54);
 268     mapNote('w', 1, 54);
 269     mapNote('e', 2, 54);
 270     mapNote('r', 3, 54);
 271     mapNote('t', 4, 54);
 272     mapNote('y', 5, 54);
 273     mapNote('a', 0, 55);
 274     mapNote('s', 1, 55);
 275     mapNote('d', 2, 55);
 276     mapNote('f', 3, 55);
 277     mapNote('g', 4, 55);
 278     mapNote('h', 5, 55);
 279     mapNote('z', 0, 56);
 280     mapNote('x', 1, 56);
 281     mapNote('c', 2, 56);
 282     mapNote('v', 3, 56);
 283     mapNote('b', 4, 56);
 284     mapNote('n', 5, 56);
 285   }
 286
 287   private void mapKeys() {
 288     int note = 48;
 289     mapNote('a', 1, note++);
 290     mapNote('w', 1, note++);
 291     mapNote('s', 1, note++);
 292     mapNote('e', 1, note++);
 293     mapNote('d', 1, note++);
 294     mapNote('f', 1, note++);
 295     mapNote('t', 1, note++);
 296     mapNote('g', 1, note++);
 297     mapNote('y', 1, note++);
 298     mapNote('h', 1, note++);
 299     mapNote('u', 1, note++);
 300     mapNote('j', 1, note++);
 301     mapNote('k', 1, note++);
 302     mapNote('o', 1, note++);
 303     mapNote('l', 1, note++);
 304   }
 305
 306   void mapNote(char ch, int channel, int number) {
 307     keyToNote.put(ch, new NoteMeta(channel, number));
 308   }
 309
 310   public void keyEvent(KeyEvent e) {
 311     if (!enabled) {
 312       return;
 313     }
 314     char c = Character.toLowerCase(e.getKeyChar());
 315     NoteMeta nm = keyToNote.get(c);
 316     if (nm != null) {
 317       switch (e.getID()) {
 318       case KeyEvent.KEY_PRESSED:
 319         noteOnReceived(new Note(Note.NOTE_ON, nm.channel, nm.number + octaveShift*12, 127));
 320         break;
 321       case KeyEvent.KEY_RELEASED:
 322         noteOffReceived(new Note(Note.NOTE_OFF, nm.channel, nm.number + octaveShift*12, 0));
 323         break;
 324       }
 325     }
 326     if ((mode == KEYS) && (e.getID() == KeyEvent.KEY_PRESSED)) {
 327       switch (c) {
 328       case 'z':
 329         octaveShift = constrain(octaveShift-1, -4, 4);
 330         break;
 331       case 'x':
 332         octaveShift = constrain(octaveShift+1, -4, 4);
 333         break;
 334       }
 335     }
 336   }
 337 }
 338
 339 public class GenericDeviceMidiInput extends SCMidiInput {
 340   GenericDeviceMidiInput(MidiEngine midiEngine, MidiInputDevice d) {
 341     super(midiEngine, d.getName().replace("Unknown vendor",""));
 342     d.createInput(this);
 343   }
 344 }
 345
 346 public class APC40MidiInput extends GenericDeviceMidiInput {
 347
 348   private boolean shiftOn = false;
 349   private LXEffect releaseEffect = null;
 350   final private LXDeck targetDeck;
 351
 352   APC40MidiInput(MidiEngine midiEngine, MidiInputDevice d) {
 353     this(midiEngine, d, -1);
 354   }
 355
 356   APC40MidiInput(MidiEngine midiEngine, MidiInputDevice d, int deckIndex) {
 357     super(midiEngine, d);
 358     targetDeck = (deckIndex < 0) ? null : lx.engine.getDecks().get(deckIndex);
 359   }
 360
 361   protected LXDeck getTargetDeck() {
 362     return (targetDeck != null) ? targetDeck : midiEngine.getFocusedDeck();
 363   }
 364
 365   protected SCPattern getTargetPattern() {
 366     if (targetDeck != null) {
 367       return (SCPattern) (targetDeck.getActivePattern());
 368     }
 369     return super.getTargetPattern();
 370   }
 371
 372   private class GridPosition {
 373     public final int row, col;
 374     GridPosition(int r, int c) {
 375       row = r;
 376       col = c;
 377     }
 378   }
 379
 380   private GridPosition getGridPosition(Note note) {
 381     int channel = note.getChannel();
 382     int pitch = note.getPitch();
 383     if (channel < 8) {
 384       if (pitch >= 53 && pitch <=57) return new GridPosition(pitch-53, channel);
 385     }
 386     return null;
 387   }
 388
 389   private boolean handleGridNoteOn(Note note) {
 390     GridPosition p = getGridPosition(note);
 391     if (p != null) {
 392       return midiEngine.grid.gridPressed(p.row, p.col);
 393     }
 394     return false;
 395   }
 396
 397   private boolean handleGridNoteOff(Note note) {
 398     GridPosition p = getGridPosition(note);
 399     if (p != null) {
 400       return midiEngine.grid.gridReleased(p.row, p.col);
 401     }
 402     return false;
 403   }
 404
 405   protected boolean handleControllerChange(rwmidi.Controller cc) {
 406     int channel = cc.getChannel();
 407     int number = cc.getCC();
 408     float value = cc.getValue() / 127.;
 409     switch (number) {
 410
 411     case 7:
 412      switch (channel) {
 413        case 0:
 414          effects.colorFucker.hueShift.setValue(value);
 415          return true;
 416        case 1:
 417          effects.colorFucker.desat.setValue(value);
 418          return true;
 419        case 2:
 420          effects.colorFucker.sharp.setValue(value);
 421          return true;
 422        case 3:
 423          effects.blur.amount.setValue(value);
 424          return true;
 425        case 4:
 426          effects.quantize.amount.setValue(value);
 427          return true;
 428      }
 429      break;
 430
 431     // Master bright
 432     case 14:
 433       effects.colorFucker.level.setValue(value);
 434       return true;
 435
 436     // Crossfader
 437     case 15:
 438       lx.engine.getDeck(GLucose.RIGHT_DECK).getFader().setValue(value);
 439       return true;
 440     }
 441
 442     int parameterIndex = -1;
 443     if (number >= 48 && number <= 55) {
 444       parameterIndex = number - 48;
 445     } else if (number >= 16 && number <= 19) {
 446       parameterIndex = 8 + (number-16);
 447     }
 448     if (parameterIndex >= 0) {
 449       List<LXParameter> parameters = getTargetPattern().getParameters();
 450       if (parameterIndex < parameters.size()) {
 451         parameters.get(parameterIndex).setValue(value);
 452         return true;
 453       }
 454     }
 455
 456     if (number >= 20 && number <= 23) {
 457       int effectIndex = number - 20;
 458       List<LXParameter> parameters = glucose.getSelectedEffect().getParameters();
 459       if (effectIndex < parameters.size()) {
 460         parameters.get(effectIndex).setValue(value);
 461         return true;
 462       }
 463     }
 464
 465     return false;
 466   }
 467
 468   private long tap1 = 0;
 469
 470   private boolean lbtwn(long a, long b, long c) {
 471     return a >= b && a <= c;
 472   }
 473
 474   protected boolean handleNoteOn(Note note) {
 475     if (handleGridNoteOn(note)) {
 476       return true;
 477     }
 478
 479     int nPitch = note.getPitch();
 480     int nChan = note.getChannel();
 481     switch (nPitch) {
 482
 483     case 49: // SOLO/CUE
 484       switch (nChan) {
 485         case 4:
 486           effects.colorFucker.mono.setValue(1);
 487           return true;
 488         case 5:
 489           effects.colorFucker.invert.setValue(1);
 490           return true;
 491         case 6:
 492           lx.cycleBaseHue(60000);
 493           return true;
 494       }
 495       break;
 496
 497     case 82: // scene 1
 498       effects.boom.trigger();
 499       return true;
 500
 501     case 83: // scene 2
 502       effects.flash.trigger();
 503       return true;
 504
 505     case 84: // scene 3
 506       getTargetPattern().reset();
 507       return true;
 508
 509     case 90:
 510       // dan's dirty tapping mechanism
 511       lx.tempo.trigger();
 512       tap1 = millis();
 513       return true;
 514
 515     case 91: // play
 516       if (shiftOn) {
 517         midiEngine.setFocusedDeck(GLucose.LEFT_DECK);
 518       } else {
 519         uiCrossfader.setDisplayMode("A");
 520       }
 521       return true;
 522
 523     case 92: // stop
 524       uiCrossfader.setDisplayMode("COMP");
 525       return true;
 526
 527     case 93: // rec
 528       if (shiftOn) {
 529         midiEngine.setFocusedDeck(GLucose.RIGHT_DECK);
 530       } else {
 531         uiCrossfader.setDisplayMode("B");
 532       }
 533       return true;
 534
 535     case 94: // up bank
 536       if (shiftOn) {
 537         glucose.incrementSelectedEffectBy(-1);
 538       } else {
 539         getTargetDeck().goPrev();
 540       }
 541       return true;
 542
 543     case 95: // down bank
 544       if (shiftOn) {
 545         glucose.incrementSelectedEffectBy(1);
 546       } else {
 547         getTargetDeck().goNext();
 548       }
 549       return true;
 550
 551     case 98: // shift
 552       shiftOn = true;
 553       return true;
 554
 555     case 99: // tap tempo
 556       lx.tempo.tap();
 557       return true;
 558
 559     case 100: // nudge+
 560       lx.tempo.setBpm(lx.tempo.bpm() + (shiftOn ? 1 : .1));
 561       return true;
 562
 563     case 101: // nudge-
 564       lx.tempo.setBpm(lx.tempo.bpm() - (shiftOn ? 1 : .1));
 565       return true;
 566
 567     case 62: // Detail View / red 5
 568       releaseEffect = glucose.getSelectedEffect();
 569       if (releaseEffect.isMomentary()) {
 570         releaseEffect.enable();
 571       } else {
 572         releaseEffect.toggle();
 573       }
 574       return true;
 575
 576     case 63: // rec quantize / red 6
 577       glucose.getSelectedEffect().disable();
 578       return true;
 579     }
 580
 581     return false;
 582   }
 583
 584   protected boolean handleNoteOff(Note note) {
 585     if (handleGridNoteOff(note)) {
 586       return true;
 587     }
 588
 589     int nPitch = note.getPitch();
 590     int nChan = note.getChannel();
 591
 592     switch (nPitch) {
 593
 594     case 49: // SOLO/CUE
 595       switch (nChan) {
 596         case 4:
 597           effects.colorFucker.mono.setValue(0);
 598           return true;
 599         case 5:
 600           effects.colorFucker.invert.setValue(0);
 601           return true;
 602         case 6:
 603           lx.setBaseHue(lx.getBaseHue());
 604           return true;
 605       }
 606       break;
 607
 608     case 52: // CLIP STOP
 609       if (nChan < PresetManager.NUM_PRESETS) {
 610         if (shiftOn) {
 611           presetManager.store(getTargetDeck(), nChan);
 612         } else {
 613           presetManager.select(getTargetDeck(), nChan);
 614         }
 615       }
 616       return true;
 617
 618     case 90: // SEND C
 619       long tapDelta = millis() - tap1;
 620       if (lbtwn(tapDelta,5000,300*1000)) {      // hackish tapping mechanism
 621         double bpm = 32.*60000./(tapDelta);
 622         while (bpm < 20) bpm*=2;
 623         while (bpm > 40) bpm/=2;
 624         lx.tempo.setBpm(bpm);
 625         lx.tempo.trigger();
 626         tap1 = 0;
 627         println("Tap Set - " + bpm + " bpm");
 628       }
 629       return true;
 630
 631     case 63: // rec quantize / RED 6
 632       if (releaseEffect != null) {
 633         if (releaseEffect.isMomentary()) {
 634           releaseEffect.disable();
 635         }
 636       }
 637       return true;
 638
 639     case 98: // shift
 640       shiftOn = false;
 641       return true;
 642     }
 643
 644     return false;
 645   }
 646 }
 647
 648 class KorgNanoKontrolMidiInput extends GenericDeviceMidiInput {
 649
 650   KorgNanoKontrolMidiInput(MidiEngine midiEngine, MidiInputDevice d) {
 651     super(midiEngine, d);
 652   }
 653
 654   protected boolean handleControllerChange(rwmidi.Controller cc) {
 655     int number = cc.getCC();
 656     if (number >= 16 && number <= 23) {
 657       int parameterIndex = number - 16;
 658       List<LXParameter> parameters = midiEngine.getFocusedPattern().getParameters();
 659       if (parameterIndex < parameters.size()) {
 660         parameters.get(parameterIndex).setValue(cc.getValue() / 127.);
 661         return true;
 662       }
 663     }
 664
 665     if (cc.getValue() == 127) {
 666       switch (number) {
 667
 668       case 58: // Left track
 669         midiEngine.setFocusedDeck(GLucose.LEFT_DECK);
 670         return true;
 671
 672       case 59: // Right track
 673         midiEngine.setFocusedDeck(GLucose.RIGHT_DECK);
 674         return true;
 675
 676       case 43: // Left chevron
 677         midiEngine.getFocusedDeck().goPrev();
 678         return true;
 679
 680       case 44: // Right chevron
 681         midiEngine.getFocusedDeck().goNext();
 682         return true;
 683       }
 684     }
 685
 686     return false;
 687   }
 688 }
 689
 690 class APC40MidiOutput implements LXParameter.Listener, GridOutput {
 691
 692   private final MidiEngine midiEngine;
 693   private final MidiOutput output;
 694   private LXPattern focusedPattern = null;
 695   private LXEffect focusedEffect = null;
 696   private final LXDeck targetDeck;
 697
 698   APC40MidiOutput(MidiEngine midiEngine, MidiOutputDevice device) {
 699     this(midiEngine, device, -1);
 700   }
 701
 702   APC40MidiOutput(MidiEngine midiEngine, MidiOutputDevice device, int deckIndex) {
 703     this.midiEngine = midiEngine;
 704     output = device.createOutput();
 705     targetDeck = (deckIndex < 0) ? null : lx.engine.getDecks().get(deckIndex);
 706     setDPatternOutputs();
 707     if (targetDeck != null) {
 708       midiEngine.addListener(new MidiEngineListener() {
 709         public void onFocusedDeck(int deckIndex) {
 710           resetPatternParameters();
 711           for (int i = 0; i < 8; ++i) {
 712             output.sendNoteOn(i, 52, 0);
 713           }
 714         }
 715       });
 716     }
 717     glucose.addEffectListener(new GLucose.EffectListener() {
 718       public void effectSelected(LXEffect effect) {
 719         resetEffectParameters();
 720       }
 721     });
 722     LXDeck.Listener deckListener = new LXDeck.AbstractListener() {
 723       public void patternDidChange(LXDeck deck, LXPattern pattern) {
 724         if (deck == getTargetDeck()) {
 725           resetPatternParameters();
 726         }
 727       }
 728     };
 729     for (LXDeck d : lx.engine.getDecks()) {
 730       if (targetDeck == null || d == targetDeck) {
 731         d.addListener(deckListener);
 732       }
 733     }
 734     presetManager.addListener(new PresetListener() {
 735       public void onPresetSelected(LXDeck deck, Preset preset) {
 736         if (deck == getTargetDeck()) {
 737           for (int i = 0; i < 8; ++i) {
 738             output.sendNoteOn(i, 52, (preset.index == i) ? 1 : 0);
 739           }
 740         }
 741       }
 742       public void onPresetDirty(LXDeck deck, Preset preset) {
 743         if (deck == getTargetDeck()) {
 744           output.sendNoteOn(preset.index, 52, 2);
 745         }
 746       }
 747       public void onPresetStored(LXDeck deck, Preset preset) {
 748         onPresetSelected(deck, preset);
 749       }
 750     });
 751     resetParameters();
 752     midiEngine.grid.addOutput(this);
 753
 754     lx.cycleBaseHue(60000);
 755     output.sendNoteOn(6, 49, 127);
 756
 757     // Turn off the track selection lights and preset selectors
 758     for (int i = 0; i < 8; ++i) {
 759       output.sendNoteOn(i, 51, 0);
 760       output.sendNoteOn(i, 52, 0);
 761     }
 762
 763     // Turn off the MASTER selector
 764     output.sendNoteOn(0, 80, 0);
 765   }
 766
 767   private void setDPatternOutputs() {
 768     for (LXDeck deck : lx.engine.getDecks()) {
 769       if (targetDeck == null || deck == targetDeck) {
 770         for (LXPattern pattern : deck.getPatterns()) {
 771           if (pattern instanceof DPat) {
 772             ((DPat)pattern).setAPCOutput(output);
 773           }
 774         }
 775       }
 776     }
 777   }
 778
 779   protected LXDeck getTargetDeck() {
 780     return (targetDeck != null) ? targetDeck : midiEngine.getFocusedDeck();
 781   }
 782
 783   private void resetParameters() {
 784     resetPatternParameters();
 785     resetEffectParameters();
 786   }
 787
 788   private void resetPatternParameters() {
 789     LXPattern newPattern = getTargetDeck().getActivePattern();
 790     if (newPattern == focusedPattern) {
 791       return;
 792     }
 793     if (focusedPattern != null) {
 794       for (LXParameter p : focusedPattern.getParameters()) {
 795         ((LXListenableParameter) p).removeListener(this);
 796       }
 797     }
 798     focusedPattern = newPattern;
 799     int i = 0;
 800     for (LXParameter p : focusedPattern.getParameters()) {
 801       ((LXListenableParameter) p).addListener(this);
 802       sendKnob(i++, p);
 803     }
 804     while (i < 12) {
 805       sendKnob(i++, 0);
 806     }
 807     if (focusedPattern instanceof DPat) {
 808       ((DPat)focusedPattern).updateLights();
 809     } else {
 810       for (int j = 0; j < 8; ++j) {
 811         output.sendNoteOn(j, 48, 0);
 812       }
 813       for (int row = 0; row < 7; ++row) {
 814         for (int col = 0; col < 8; ++col) {
 815           setGridState(row, col, 0);
 816         }
 817       }
 818     }
 819   }
 820
 821   private void resetEffectParameters() {
 822     LXEffect newEffect = glucose.getSelectedEffect();
 823     if (newEffect == focusedEffect) {
 824       return;
 825     }
 826     if (focusedEffect != null) {
 827       for (LXParameter p : focusedPattern.getParameters()) {
 828         ((LXListenableParameter) p).removeListener(this);
 829       }
 830     }
 831     focusedEffect = newEffect;
 832     int i = 0;
 833     for (LXParameter p : focusedEffect.getParameters()) {
 834       ((LXListenableParameter) p).addListener(this);
 835       sendKnob(12 + i++, p);
 836     }
 837     while (i < 4) {
 838       sendKnob(12 + i++, 0);
 839     }
 840   }
 841
 842   private void sendKnob(int i, LXParameter p) {
 843     sendKnob(i, (int) (p.getValuef() * 127.));
 844   }
 845
 846   private void sendKnob(int i, int value) {
 847     if (i < 8) {
 848       output.sendController(0, 48+i, value);
 849     } else if (i < 16) {
 850       output.sendController(0, 8+i, value);
 851     }
 852   }
 853
 854   public void onParameterChanged(LXParameter parameter) {
 855     int i = 0;
 856     for (LXParameter p : focusedPattern.getParameters()) {
 857       if (p == parameter) {
 858         sendKnob(i, p);
 859         break;
 860       }
 861       ++i;
 862     }
 863     i = 12;
 864     for (LXParameter p : focusedEffect.getParameters()) {
 865       if (p == parameter) {
 866         sendKnob(i, p);
 867         break;
 868       }
 869       ++i;
 870     }
 871   }
 872
 873   public void setGridState(int row, int col, int state) {
 874     if (col < 8 && row < 5) {
 875       output.sendNoteOn(col, 53+row, state);
 876     }
 877   }
 878 }
 879
 880 class ArturiaMinilabMidiInput extends GenericDeviceMidiInput {
 881   ArturiaMinilabMidiInput(MidiEngine midiEngine, MidiInputDevice d) {
 882     super(midiEngine, d);
 883   }
 884
 885   protected boolean handleControllerChange(rwmidi.Controller cc) {
 886     int parameterIndex = -1;
 887     switch (cc.getCC()) {
 888       case 7:   parameterIndex = 0; break;
 889       case 74:  parameterIndex = 1; break;
 890       case 71:  parameterIndex = 2; break;
 891       case 76:  parameterIndex = 3; break;
 892       case 114: parameterIndex = 4; break;
 893       case 18:  parameterIndex = 5; break;
 894       case 19:  parameterIndex = 6; break;
 895       case 16:  parameterIndex = 7; break;
 896     }
 897     if (parameterIndex >= 0) {
 898       List<LXParameter> parameters = midiEngine.getFocusedPattern().getParameters();
 899       if (parameterIndex < parameters.size()) {
 900         LXParameter p = parameters.get(parameterIndex);
 901         float curVal = p.getValuef();
 902         curVal += (cc.getValue() - 64) / 127.;
 903         p.setValue(constrain(curVal, 0, 1));
 904       }
 905     }
 906     return false;
 907   }
 908 }
 909
 910 interface GridOutput {
 911   public static final int OFF = 0;
 912   public static final int GREEN = 1;
 913   public static final int GREEN_BLINK = 2;
 914   public static final int RED = 3;
 915   public static final int RED_BLINK = 4;
 916   public static final int YELLOW = 5;
 917   public static final int YELLOW_BLINK = 6;
 918   public static final int ON = 127;
 919
 920   public void setGridState(int row, int col, int state);
 921 }
 922
 923 class GridController {
 924   private final List<GridOutput> outputs = new ArrayList<GridOutput>();
 925
 926   private final MidiEngine midiEngine;
 927
 928   GridController(MidiEngine midiEngine) {
 929     this.midiEngine = midiEngine;
 930   }
 931
 932   public void addOutput(GridOutput output) {
 933     outputs.add(output);
 934   }
 935
 936   public boolean gridPressed(int row, int col) {
 937     return midiEngine.getFocusedPattern().gridPressed(row, col);
 938   }
 939
 940   public boolean gridReleased(int row, int col) {
 941     return midiEngine.getFocusedPattern().gridReleased(row, col);
 942   }
 943
 944   public void setState(int row, int col, int state) {
 945     for (GridOutput g : outputs) {
 946       g.setGridState(row, col, state);
 947     }
 948   }
 949 }
 950