_MIDI.pde

   1 /**
   2  *     DOUBLE BLACK DIAMOND        DOUBLE BLACK DIAMOND
   3  *
   4  *         //\\   //\\                 //\\   //\\
   5  *        ///\\\ ///\\\               ///\\\ ///\\\
   6  *        \\\/// \\\///               \\\/// \\\///
   7  *         \\//   \\//                 \\//   \\//
   8  *
   9  *        EXPERTS ONLY!!              EXPERTS ONLY!!
  10  *
  11  * This file defines the MIDI mapping interfaces. This shouldn't
  12  * need editing unless you're adding top level support for a
  13  * specific MIDI device of some sort. Generally, all MIDI devices
  14  * will just work with the default configuration, and you can
  15  * set your SCPattern class to respond to the controllers that you
  16  * care about.
  17  */
  18
  19 interface MidiEngineListener {
  20   public void onFocusedDeck(int deckIndex);
  21 }
  22
  23 class MidiEngine {
  24
  25   public final GridController grid;
  26   private final List<MidiEngineListener> listeners = new ArrayList<MidiEngineListener>();
  27   private final List<SCMidiInput> midiControllers = new ArrayList<SCMidiInput>();
  28
  29   public MidiEngine addListener(MidiEngineListener l) {
  30     listeners.add(l);
  31     return this;
  32   }
  33
  34   public MidiEngine removeListener(MidiEngineListener l) {
  35     listeners.remove(l);
  36     return this;
  37   }
  38
  39   private SCMidiInput midiQwertyKeys;
  40   private SCMidiInput midiQwertyAPC;
  41
  42   private int activeDeckIndex = 0;
  43
  44   public MidiEngine() {
  45     grid = new GridController(this);
  46     midiControllers.add(midiQwertyKeys = new VirtualKeyMidiInput(this, VirtualKeyMidiInput.KEYS));
  47     midiControllers.add(midiQwertyAPC = new VirtualKeyMidiInput(this, VirtualKeyMidiInput.APC));
  48     int apcCount = 0;
  49     for (MidiInputDevice device : RWMidi.getInputDevices()) {
  50       if (device.getName().contains("APC")) {
  51         ++apcCount;
  52       }
  53     }
  54
  55     int apcIndex = 0;
  56     for (MidiInputDevice device : RWMidi.getInputDevices()) {
  57       if (device.getName().contains("APC")) {
  58         int apcDeck = -1;
  59         if (apcCount > 1 && apcIndex < 2) {
  60           apcDeck = apcIndex++;
  61         }
  62         midiControllers.add(new APC40MidiInput(this, device, apcDeck).setEnabled(true));
  63       } else if (device.getName().contains("SLIDER/KNOB KORG")) {
  64         midiControllers.add(new KorgNanoKontrolMidiInput(this, device).setEnabled(true));
  65       } else if (device.getName().contains("Arturia MINILAB")) {
  66         midiControllers.add(new ArturiaMinilabMidiInput(this, device).setEnabled(true));
  67       } else {
  68         boolean enabled =
  69           device.getName().contains("KEYBOARD KORG") ||
  70           device.getName().contains("Bus 1 Apple");
  71         midiControllers.add(new GenericDeviceMidiInput(this, device).setEnabled(enabled));
  72       }
  73     }
  74
  75     apcIndex = 0;
  76     for (MidiOutputDevice device : RWMidi.getOutputDevices()) {
  77       if (device.getName().contains("APC")) {
  78         int apcDeck = -1;
  79         if (apcCount > 1 && apcIndex < 2) {
  80           apcDeck = apcIndex++;
  81         }
  82         new APC40MidiOutput(this, device, apcDeck);
  83       }
  84     }
  85   }
  86
  87   public List<SCMidiInput> getControllers() {
  88     return this.midiControllers;
  89   }
  90
  91   public LXDeck getFocusedDeck() {
  92     return lx.engine.getDeck(activeDeckIndex);
  93   }
  94
  95   public SCPattern getFocusedPattern() {
  96     return (SCPattern) getFocusedDeck().getActivePattern();
  97   }
  98
  99   public MidiEngine setFocusedDeck(int deckIndex) {
 100     if (this.activeDeckIndex != deckIndex) {
 101       this.activeDeckIndex = deckIndex;
 102       for (MidiEngineListener listener : listeners) {
 103         listener.onFocusedDeck(deckIndex);
 104       }
 105     }
 106     return this;
 107   }
 108
 109   public boolean isQwertyEnabled() {
 110     return midiQwertyKeys.isEnabled() || midiQwertyAPC.isEnabled();
 111   }
 112 }
 113
 114 public interface SCMidiInputListener {
 115   public void onEnabled(SCMidiInput controller, boolean enabled);
 116 }
 117
 118 public abstract class SCMidiInput extends AbstractScrollItem {
 119
 120   protected boolean enabled = false;
 121   private final String name;
 122
 123   protected final MidiEngine midiEngine;
 124
 125   final List<SCMidiInputListener> listeners = new ArrayList<SCMidiInputListener>();
 126
 127   protected SCMidiInput(MidiEngine midiEngine, String name) {
 128     this.midiEngine = midiEngine;
 129     this.name = name;
 130   }
 131
 132   public SCMidiInput addListener(SCMidiInputListener l) {
 133     listeners.add(l);
 134     return this;
 135   }
 136
 137   public SCMidiInput removeListener(SCMidiInputListener l) {
 138     listeners.remove(l);
 139     return this;
 140   }
 141
 142   public String getLabel() {
 143     return name;
 144   }
 145
 146   public boolean isEnabled() {
 147     return enabled;
 148   }
 149
 150   public boolean isSelected() {
 151     return enabled;
 152   }
 153
 154   public void onMousePressed() {
 155     setEnabled(!enabled);
 156   }
 157
 158   public SCMidiInput setEnabled(boolean enabled) {
 159     if (enabled != this.enabled) {
 160       this.enabled = enabled;
 161       for (SCMidiInputListener l : listeners) {
 162         l.onEnabled(this, enabled);
 163       }
 164     }
 165     return this;
 166   }
 167
 168   private boolean logMidi() {
 169     return (uiMidi != null) && uiMidi.logMidi();
 170   }
 171
 172   protected SCPattern getTargetPattern() {
 173     return midiEngine.getFocusedPattern();
 174   }
 175
 176   final void programChangeReceived(ProgramChange pc) {
 177     if (!enabled) {
 178       return;
 179     }
 180     if (logMidi()) {
 181       println(getLabel() + " :: Program Change :: " + pc.getNumber());
 182     }
 183     handleProgramChange(pc);
 184   }
 185
 186   final void controllerChangeReceived(rwmidi.Controller cc) {
 187     if (!enabled) {
 188       return;
 189     }
 190     if (logMidi()) {
 191       println(getLabel() + " :: Controller :: " + cc.getChannel() + " :: " + cc.getCC() + ":" + cc.getValue());
 192     }
 193     if (!handleControllerChange(cc)) {
 194       getTargetPattern().controllerChange(cc);
 195     }
 196   }
 197
 198   final void noteOnReceived(Note note) {
 199     if (!enabled) {
 200       return;
 201     }
 202     if (logMidi()) {
 203       println(getLabel() + " :: Note On  :: " + note.getChannel() + ":" + note.getPitch() + ":" + note.getVelocity());
 204     }
 205     if (!handleNoteOn(note)) {
 206       getTargetPattern().noteOn(note);
 207     }
 208   }
 209
 210   final void noteOffReceived(Note note) {
 211     if (!enabled) {
 212       return;
 213     }
 214     if (logMidi()) {
 215       println(getLabel() + " :: Note Off :: " + note.getChannel() + ":" + note.getPitch() + ":" + note.getVelocity());
 216     }
 217     if (!handleNoteOff(note)) {
 218       getTargetPattern().noteOff(note);
 219     }
 220   }
 221
 222   // Subclasses may implement these to map top-level functionality
 223   protected boolean handleProgramChange(ProgramChange pc) { return false; }
 224   protected boolean handleControllerChange(rwmidi.Controller cc) { return false; }
 225   protected boolean handleNoteOn(Note note) { return false; }
 226   protected boolean handleNoteOff(Note note) { return false; }
 227 }
 228
 229 public class VirtualKeyMidiInput extends SCMidiInput {
 230
 231   public static final int KEYS = 1;
 232   public static final int APC = 2;
 233
 234   private final int mode;
 235
 236   private int octaveShift = 0;
 237
 238   class NoteMeta {
 239     int channel;
 240     int number;
 241     NoteMeta(int channel, int number) {
 242       this.channel = channel;
 243       this.number = number;
 244     }
 245   }
 246
 247   final Map<Character, NoteMeta> keyToNote = new HashMap<Character, NoteMeta>();
 248
 249   VirtualKeyMidiInput(MidiEngine midiEngine, int mode) {
 250     super(midiEngine, "QWERTY (" + (mode == APC ? "APC" : "Key") + "  Mode)");
 251     this.mode = mode;
 252     if (mode == APC) {
 253       mapAPC();
 254     } else {
 255       mapKeys();
 256     }
 257     registerKeyEvent(this);
 258   }
 259
 260   private void mapAPC() {
 261     mapNote('1', 0, 53);
 262     mapNote('2', 1, 53);
 263     mapNote('3', 2, 53);
 264     mapNote('4', 3, 53);
 265     mapNote('5', 4, 53);
 266     mapNote('6', 5, 53);
 267     mapNote('q', 0, 54);
 268     mapNote('w', 1, 54);
 269     mapNote('e', 2, 54);
 270     mapNote('r', 3, 54);
 271     mapNote('t', 4, 54);
 272     mapNote('y', 5, 54);
 273     mapNote('a', 0, 55);
 274     mapNote('s', 1, 55);
 275     mapNote('d', 2, 55);
 276     mapNote('f', 3, 55);
 277     mapNote('g', 4, 55);
 278     mapNote('h', 5, 55);
 279     mapNote('z', 0, 56);
 280     mapNote('x', 1, 56);
 281     mapNote('c', 2, 56);
 282     mapNote('v', 3, 56);
 283     mapNote('b', 4, 56);
 284     mapNote('n', 5, 56);
 285   }
 286
 287   private void mapKeys() {
 288     int note = 48;
 289     mapNote('a', 1, note++);
 290     mapNote('w', 1, note++);
 291     mapNote('s', 1, note++);
 292     mapNote('e', 1, note++);
 293     mapNote('d', 1, note++);
 294     mapNote('f', 1, note++);
 295     mapNote('t', 1, note++);
 296     mapNote('g', 1, note++);
 297     mapNote('y', 1, note++);
 298     mapNote('h', 1, note++);
 299     mapNote('u', 1, note++);
 300     mapNote('j', 1, note++);
 301     mapNote('k', 1, note++);
 302     mapNote('o', 1, note++);
 303     mapNote('l', 1, note++);
 304   }
 305
 306   void mapNote(char ch, int channel, int number) {
 307     keyToNote.put(ch, new NoteMeta(channel, number));
 308   }
 309
 310   public void keyEvent(KeyEvent e) {
 311     if (!enabled) {
 312       return;
 313     }
 314     char c = Character.toLowerCase(e.getKeyChar());
 315     NoteMeta nm = keyToNote.get(c);
 316     if (nm != null) {
 317       switch (e.getID()) {
 318       case KeyEvent.KEY_PRESSED:
 319         noteOnReceived(new Note(Note.NOTE_ON, nm.channel, nm.number + octaveShift*12, 127));
 320         break;
 321       case KeyEvent.KEY_RELEASED:
 322         noteOffReceived(new Note(Note.NOTE_OFF, nm.channel, nm.number + octaveShift*12, 0));
 323         break;
 324       }
 325     }
 326     if ((mode == KEYS) && (e.getID() == KeyEvent.KEY_PRESSED)) {
 327       switch (c) {
 328       case 'z':
 329         octaveShift = constrain(octaveShift-1, -4, 4);
 330         break;
 331       case 'x':
 332         octaveShift = constrain(octaveShift+1, -4, 4);
 333         break;
 334       }
 335     }
 336   }
 337 }
 338
 339 public class GenericDeviceMidiInput extends SCMidiInput {
 340   GenericDeviceMidiInput(MidiEngine midiEngine, MidiInputDevice d) {
 341     super(midiEngine, d.getName().replace("Unknown vendor",""));
 342     d.createInput(this);
 343   }
 344 }
 345
 346 public class APC40MidiInput extends GenericDeviceMidiInput {
 347
 348   private boolean shiftOn = false;
 349   private LXEffect releaseEffect = null;
 350   final private LXDeck targetDeck;
 351
 352   APC40MidiInput(MidiEngine midiEngine, MidiInputDevice d) {
 353     this(midiEngine, d, -1);
 354   }
 355
 356   APC40MidiInput(MidiEngine midiEngine, MidiInputDevice d, int deckIndex) {
 357     super(midiEngine, d);
 358     targetDeck = (deckIndex < 0) ? null : lx.engine.getDecks().get(deckIndex);
 359   }
 360
 361   protected LXDeck getTargetDeck() {
 362     return (targetDeck != null) ? targetDeck : midiEngine.getFocusedDeck();
 363   }
 364
 365   protected SCPattern getTargetPattern() {
 366     if (targetDeck != null) {
 367       return (SCPattern) (targetDeck.getActivePattern());
 368     }
 369     return super.getTargetPattern();
 370   }
 371
 372   private class GridPosition {
 373     public final int row, col;
 374     GridPosition(int r, int c) {
 375       row = r;
 376       col = c;
 377     }
 378   }
 379
 380   private GridPosition getGridPosition(Note note) {
 381     int channel = note.getChannel();
 382     int pitch = note.getPitch();
 383     if (channel < 8) {
 384       if (pitch >= 53 && pitch <=57) return new GridPosition(pitch-53, channel);
 385     }
 386     return null;
 387   }
 388
 389   private boolean handleGridNoteOn(Note note) {
 390     GridPosition p = getGridPosition(note);
 391     if (p != null) {
 392       return midiEngine.grid.gridPressed(p.row, p.col);
 393     }
 394     return false;
 395   }
 396
 397   private boolean handleGridNoteOff(Note note) {
 398     GridPosition p = getGridPosition(note);
 399     if (p != null) {
 400       return midiEngine.grid.gridReleased(p.row, p.col);
 401     }
 402     return false;
 403   }
 404
 405   protected boolean handleControllerChange(rwmidi.Controller cc) {
 406     int channel = cc.getChannel();
 407     int number = cc.getCC();
 408     float value = cc.getValue() / 127.;
 409     switch (number) {
 410
 411     case 7:
 412      switch (channel) {
 413        case 0:
 414          effects.colorFucker.hueShift.setValue(value);
 415          return true;
 416        case 1:
 417          effects.colorFucker.desat.setValue(value);
 418          return true;
 419        case 2:
 420          effects.colorFucker.sharp.setValue(value);
 421          return true;
 422        case 3:
 423          effects.blur.amount.setValue(value);
 424          return true;
 425        case 4:
 426          effects.quantize.amount.setValue(value);
 427          return true;
 428      }
 429      break;
 430
 431     // Master bright
 432     case 14:
 433       effects.colorFucker.level.setValue(value);
 434       return true;
 435
 436     // Crossfader
 437     case 15:
 438       lx.engine.getDeck(GLucose.RIGHT_DECK).getFader().setValue(value);
 439       return true;
 440     }
 441
 442     int parameterIndex = -1;
 443     if (number >= 48 && number <= 55) {
 444       parameterIndex = number - 48;
 445     } else if (number >= 16 && number <= 19) {
 446       parameterIndex = 8 + (number-16);
 447     }
 448     if (parameterIndex >= 0) {
 449       List<LXParameter> parameters = getTargetPattern().getParameters();
 450       if (parameterIndex < parameters.size()) {
 451         parameters.get(parameterIndex).setValue(value);
 452         return true;
 453       }
 454     }
 455
 456     if (number >= 20 && number <= 23) {
 457       int effectIndex = number - 20;
 458       List<LXParameter> parameters = glucose.getSelectedEffect().getParameters();
 459       if (effectIndex < parameters.size()) {
 460         parameters.get(effectIndex).setValue(value);
 461         return true;
 462       }
 463     }
 464
 465     return false;
 466   }
 467
 468   private long tap1 = 0;
 469
 470   private boolean lbtwn(long a, long b, long c) {
 471     return a >= b && a <= c;
 472   }
 473
 474   protected boolean handleNoteOn(Note note) {
 475     if (handleGridNoteOn(note)) {
 476       return true;
 477     }
 478
 479     int nPitch = note.getPitch();
 480     int nChan = note.getChannel();
 481     switch (nPitch) {
 482
 483     case 49: // SOLO/CUE
 484       switch (nChan) {
 485         case 4:
 486           effects.colorFucker.mono.setValue(1);
 487           return true;
 488         case 5:
 489           effects.colorFucker.invert.setValue(1);
 490           return true;
 491         case 6:
 492           lx.cycleBaseHue(60000);
 493           return true;
 494       }
 495       break;
 496
 497     case 82: // scene 1
 498       effects.boom.trigger();
 499       return true;
 500
 501     case 83: // scene 2
 502       effects.flash.trigger();
 503       return true;
 504
 505     case 84: // scene 3
 506       getTargetPattern().reset();
 507       return true;
 508
 509     case 90:
 510       // dan's dirty tapping mechanism
 511       lx.tempo.trigger();
 512       tap1 = millis();
 513       return true;
 514
 515     case 91: // play
 516     case 97: // left bank
 517       midiEngine.setFocusedDeck(0);
 518       return true;
 519
 520     case 93: // rec
 521     case 96: // right bank
 522       midiEngine.setFocusedDeck(1);
 523       return true;
 524
 525     case 94: // up bank
 526       if (shiftOn) {
 527         glucose.incrementSelectedEffectBy(-1);
 528       } else {
 529         getTargetDeck().goPrev();
 530       }
 531       return true;
 532
 533     case 95: // down bank
 534       if (shiftOn) {
 535         glucose.incrementSelectedEffectBy(1);
 536       } else {
 537         getTargetDeck().goNext();
 538       }
 539       return true;
 540
 541     case 98: // shift
 542       shiftOn = true;
 543       return true;
 544
 545     case 99: // tap tempo
 546       lx.tempo.tap();
 547       return true;
 548
 549     case 100: // nudge+
 550       lx.tempo.setBpm(lx.tempo.bpm() + (shiftOn ? 1 : .1));
 551       return true;
 552
 553     case 101: // nudge-
 554       lx.tempo.setBpm(lx.tempo.bpm() - (shiftOn ? 1 : .1));
 555       return true;
 556
 557     case 62: // Detail View / red 5
 558       releaseEffect = glucose.getSelectedEffect();
 559       if (releaseEffect.isMomentary()) {
 560         releaseEffect.enable();
 561       } else {
 562         releaseEffect.toggle();
 563       }
 564       return true;
 565
 566     case 63: // rec quantize / red 6
 567       glucose.getSelectedEffect().disable();
 568       return true;
 569     }
 570
 571     return false;
 572   }
 573
 574   protected boolean handleNoteOff(Note note) {
 575     if (handleGridNoteOff(note)) {
 576       return true;
 577     }
 578
 579     int nPitch = note.getPitch();
 580     int nChan = note.getChannel();
 581
 582     switch (nPitch) {
 583
 584     case 49: // SOLO/CUE
 585       switch (nChan) {
 586         case 4:
 587           effects.colorFucker.mono.setValue(0);
 588           return true;
 589         case 5:
 590           effects.colorFucker.invert.setValue(0);
 591           return true;
 592         case 6:
 593           lx.setBaseHue(lx.getBaseHue());
 594           return true;
 595       }
 596       break;
 597
 598     case 52: // CLIP STOP
 599       if (nChan < PresetManager.NUM_PRESETS) {
 600         if (shiftOn) {
 601           presetManager.store(getTargetDeck(), nChan);
 602         } else {
 603           presetManager.select(getTargetDeck(), nChan);
 604         }
 605       }
 606       return true;
 607
 608     case 90: // SEND C
 609       long tapDelta = millis() - tap1;
 610       if (lbtwn(tapDelta,5000,300*1000)) {      // hackish tapping mechanism
 611         double bpm = 32.*60000./(tapDelta);
 612         while (bpm < 20) bpm*=2;
 613         while (bpm > 40) bpm/=2;
 614         lx.tempo.setBpm(bpm);
 615         lx.tempo.trigger();
 616         tap1 = 0;
 617         println("Tap Set - " + bpm + " bpm");
 618       }
 619       return true;
 620
 621     case 63: // rec quantize / RED 6
 622       if (releaseEffect != null) {
 623         if (releaseEffect.isMomentary()) {
 624           releaseEffect.disable();
 625         }
 626       }
 627       return true;
 628
 629     case 98: // shift
 630       shiftOn = false;
 631       return true;
 632     }
 633
 634     return false;
 635   }
 636 }
 637
 638 class KorgNanoKontrolMidiInput extends GenericDeviceMidiInput {
 639
 640   KorgNanoKontrolMidiInput(MidiEngine midiEngine, MidiInputDevice d) {
 641     super(midiEngine, d);
 642   }
 643
 644   protected boolean handleControllerChange(rwmidi.Controller cc) {
 645     int number = cc.getCC();
 646     if (number >= 16 && number <= 23) {
 647       int parameterIndex = number - 16;
 648       List<LXParameter> parameters = midiEngine.getFocusedPattern().getParameters();
 649       if (parameterIndex < parameters.size()) {
 650         parameters.get(parameterIndex).setValue(cc.getValue() / 127.);
 651         return true;
 652       }
 653     }
 654
 655     if (cc.getValue() == 127) {
 656       switch (number) {
 657
 658       case 58: // Left track
 659         midiEngine.setFocusedDeck(GLucose.LEFT_DECK);
 660         return true;
 661
 662       case 59: // Right track
 663         midiEngine.setFocusedDeck(GLucose.RIGHT_DECK);
 664         return true;
 665
 666       case 43: // Left chevron
 667         midiEngine.getFocusedDeck().goPrev();
 668         return true;
 669
 670       case 44: // Right chevron
 671         midiEngine.getFocusedDeck().goNext();
 672         return true;
 673       }
 674     }
 675
 676     return false;
 677   }
 678 }
 679
 680 class APC40MidiOutput implements LXParameter.Listener, GridOutput {
 681
 682   private final MidiEngine midiEngine;
 683   private final MidiOutput output;
 684   private LXPattern focusedPattern = null;
 685   private LXEffect focusedEffect = null;
 686   private final LXDeck targetDeck;
 687
 688   APC40MidiOutput(MidiEngine midiEngine, MidiOutputDevice device) {
 689     this(midiEngine, device, -1);
 690   }
 691
 692   APC40MidiOutput(MidiEngine midiEngine, MidiOutputDevice device, int deckIndex) {
 693     this.midiEngine = midiEngine;
 694     output = device.createOutput();
 695     targetDeck = (deckIndex < 0) ? null : lx.engine.getDecks().get(deckIndex);
 696     setDPatternOutputs();
 697     if (targetDeck != null) {
 698       midiEngine.addListener(new MidiEngineListener() {
 699         public void onFocusedDeck(int deckIndex) {
 700           resetPatternParameters();
 701           for (int i = 0; i < 8; ++i) {
 702             output.sendNoteOn(i, 52, 0);
 703           }
 704         }
 705       });
 706     }
 707     glucose.addEffectListener(new GLucose.EffectListener() {
 708       public void effectSelected(LXEffect effect) {
 709         resetEffectParameters();
 710       }
 711     });
 712     LXDeck.Listener deckListener = new LXDeck.AbstractListener() {
 713       public void patternDidChange(LXDeck deck, LXPattern pattern) {
 714         if (deck == getTargetDeck()) {
 715           resetPatternParameters();
 716         }
 717       }
 718     };
 719     for (LXDeck d : lx.engine.getDecks()) {
 720       if (targetDeck == null || d == targetDeck) {
 721         d.addListener(deckListener);
 722       }
 723     }
 724     presetManager.addListener(new PresetListener() {
 725       public void onPresetSelected(LXDeck deck, Preset preset) {
 726         if (deck == getTargetDeck()) {
 727           for (int i = 0; i < 8; ++i) {
 728             output.sendNoteOn(i, 52, (preset.index == i) ? 1 : 0);
 729           }
 730         }
 731       }
 732       public void onPresetDirty(LXDeck deck, Preset preset) {
 733         if (deck == getTargetDeck()) {
 734           output.sendNoteOn(preset.index, 52, 2);
 735         }
 736       }
 737       public void onPresetStored(LXDeck deck, Preset preset) {
 738         onPresetSelected(deck, preset);
 739       }
 740     });
 741     resetParameters();
 742     midiEngine.grid.addOutput(this);
 743
 744     lx.cycleBaseHue(60000);
 745     output.sendNoteOn(6, 49, 127);
 746
 747     // Turn off the track selection lights and preset selectors
 748     for (int i = 0; i < 8; ++i) {
 749       output.sendNoteOn(i, 51, 0);
 750       output.sendNoteOn(i, 52, 0);
 751     }
 752
 753     // Turn off the MASTER selector
 754     output.sendNoteOn(0, 80, 0);
 755   }
 756
 757   private void setDPatternOutputs() {
 758     for (LXDeck deck : lx.engine.getDecks()) {
 759       if (targetDeck == null || deck == targetDeck) {
 760         for (LXPattern pattern : deck.getPatterns()) {
 761           if (pattern instanceof DPat) {
 762             ((DPat)pattern).setAPCOutput(output);
 763           }
 764         }
 765       }
 766     }
 767   }
 768
 769   protected LXDeck getTargetDeck() {
 770     return (targetDeck != null) ? targetDeck : midiEngine.getFocusedDeck();
 771   }
 772
 773   private void resetParameters() {
 774     resetPatternParameters();
 775     resetEffectParameters();
 776   }
 777
 778   private void resetPatternParameters() {
 779     LXPattern newPattern = getTargetDeck().getActivePattern();
 780     if (newPattern == focusedPattern) {
 781       return;
 782     }
 783     if (focusedPattern != null) {
 784       for (LXParameter p : focusedPattern.getParameters()) {
 785         ((LXListenableParameter) p).removeListener(this);
 786       }
 787     }
 788     focusedPattern = newPattern;
 789     int i = 0;
 790     for (LXParameter p : focusedPattern.getParameters()) {
 791       ((LXListenableParameter) p).addListener(this);
 792       sendKnob(i++, p);
 793     }
 794     while (i < 12) {
 795       sendKnob(i++, 0);
 796     }
 797     if (focusedPattern instanceof DPat) {
 798       ((DPat)focusedPattern).updateLights();
 799     } else {
 800       for (int j = 0; j < 8; ++j) {
 801         output.sendNoteOn(j, 48, 0);
 802       }
 803       for (int row = 0; row < 7; ++row) {
 804         for (int col = 0; col < 8; ++col) {
 805           setGridState(row, col, 0);
 806         }
 807       }
 808     }
 809   }
 810
 811   private void resetEffectParameters() {
 812     LXEffect newEffect = glucose.getSelectedEffect();
 813     if (newEffect == focusedEffect) {
 814       return;
 815     }
 816     if (focusedEffect != null) {
 817       for (LXParameter p : focusedPattern.getParameters()) {
 818         ((LXListenableParameter) p).removeListener(this);
 819       }
 820     }
 821     focusedEffect = newEffect;
 822     int i = 0;
 823     for (LXParameter p : focusedEffect.getParameters()) {
 824       ((LXListenableParameter) p).addListener(this);
 825       sendKnob(12 + i++, p);
 826     }
 827     while (i < 4) {
 828       sendKnob(12 + i++, 0);
 829     }
 830   }
 831
 832   private void sendKnob(int i, LXParameter p) {
 833     sendKnob(i, (int) (p.getValuef() * 127.));
 834   }
 835
 836   private void sendKnob(int i, int value) {
 837     if (i < 8) {
 838       output.sendController(0, 48+i, value);
 839     } else if (i < 16) {
 840       output.sendController(0, 8+i, value);
 841     }
 842   }
 843
 844   public void onParameterChanged(LXParameter parameter) {
 845     int i = 0;
 846     for (LXParameter p : focusedPattern.getParameters()) {
 847       if (p == parameter) {
 848         sendKnob(i, p);
 849         break;
 850       }
 851       ++i;
 852     }
 853     i = 12;
 854     for (LXParameter p : focusedEffect.getParameters()) {
 855       if (p == parameter) {
 856         sendKnob(i, p);
 857         break;
 858       }
 859       ++i;
 860     }
 861   }
 862
 863   public void setGridState(int row, int col, int state) {
 864     if (col < 8 && row < 5) {
 865       output.sendNoteOn(col, 53+row, state);
 866     }
 867   }
 868 }
 869
 870 class ArturiaMinilabMidiInput extends GenericDeviceMidiInput {
 871   ArturiaMinilabMidiInput(MidiEngine midiEngine, MidiInputDevice d) {
 872     super(midiEngine, d);
 873   }
 874
 875   protected boolean handleControllerChange(rwmidi.Controller cc) {
 876     int parameterIndex = -1;
 877     switch (cc.getCC()) {
 878       case 7:   parameterIndex = 0; break;
 879       case 74:  parameterIndex = 1; break;
 880       case 71:  parameterIndex = 2; break;
 881       case 76:  parameterIndex = 3; break;
 882       case 114: parameterIndex = 4; break;
 883       case 18:  parameterIndex = 5; break;
 884       case 19:  parameterIndex = 6; break;
 885       case 16:  parameterIndex = 7; break;
 886     }
 887     if (parameterIndex >= 0) {
 888       List<LXParameter> parameters = midiEngine.getFocusedPattern().getParameters();
 889       if (parameterIndex < parameters.size()) {
 890         LXParameter p = parameters.get(parameterIndex);
 891         float curVal = p.getValuef();
 892         curVal += (cc.getValue() - 64) / 127.;
 893         p.setValue(constrain(curVal, 0, 1));
 894       }
 895     }
 896     return false;
 897   }
 898 }
 899
 900 interface GridOutput {
 901   public static final int OFF = 0;
 902   public static final int GREEN = 1;
 903   public static final int GREEN_BLINK = 2;
 904   public static final int RED = 3;
 905   public static final int RED_BLINK = 4;
 906   public static final int YELLOW = 5;
 907   public static final int YELLOW_BLINK = 6;
 908   public static final int ON = 127;
 909
 910   public void setGridState(int row, int col, int state);
 911 }
 912
 913 class GridController {
 914   private final List<GridOutput> outputs = new ArrayList<GridOutput>();
 915
 916   private final MidiEngine midiEngine;
 917
 918   GridController(MidiEngine midiEngine) {
 919     this.midiEngine = midiEngine;
 920   }
 921
 922   public void addOutput(GridOutput output) {
 923     outputs.add(output);
 924   }
 925
 926   public boolean gridPressed(int row, int col) {
 927     return midiEngine.getFocusedPattern().gridPressed(row, col);
 928   }
 929
 930   public boolean gridReleased(int row, int col) {
 931     return midiEngine.getFocusedPattern().gridReleased(row, col);
 932   }
 933
 934   public void setState(int row, int col, int state) {
 935     for (GridOutput g : outputs) {
 936       g.setGridState(row, col, state);
 937     }
 938   }
 939 }
 940